كيفية إرسال ورقة العمل فقط عبر Outlook من Excel؟

إذا كنت ترغب في إرسال ورقة عمل واحدة من مصنف في Excel عبر Outlook، يمكنك إرسال الورقة كمرفق، أو كجزء من نص الرسالة، أو كملف PDF. ولكن هل هناك طرق أسرع للتعامل مع هذه المشكلة في Excel؟

إرسال ورقة عمل واحدة كنص من Excel باستخدام أمر إرسال إلى المستلمين بالبريد الإلكتروني

إرسال ورقة عمل واحدة كمرفق من Excel باستخدام كود VBA

إرسال ورقة عمل واحدة كملف PDF من Excel باستخدام كود VBA

إرسال ورقة عمل واحدة كنص من Excel باستخدام أمر إرسال إلى المستلمين بالبريد الإلكتروني

يدعم Excel إرسال ورقة العمل النشطة كجزء من نص الرسالة باستخدام أمر إرسال إلى المستلمين بالبريد الإلكتروني. يمكنك القيام بما يلي:

إذا كنت تستخدم Excel 2007 أو 2010 أو 2013، تحتاج أولاً إلى إضافة أمر إرسال إلى المستلمين بالبريد الإلكتروني إلى شريط الأدوات السريع.

1. انقر فوق أيقونة تخصيص شريط الأدوات السريع، واختر المزيد من الأوامر، انظر لقطة الشاشة:

2. وفي مربع الحوار خيارات Excel، اختر أوامر ليست في الشريط من قائمة اختيار الأوامر المنسدلة، ثم حدد خيار إرسال إلى المستلمين بالبريد الإلكتروني، وانقر فوق الزر إضافة >> لإضافة هذا الأمر، وأخيرًا انقر فوق موافق لحفظ هذا الإعداد. انظر لقطة الشاشة:

3. تم إدراج أمر إرسال إلى المستلمين بالبريد الإلكتروني في شريط الأدوات السريع، انظر لقطة الشاشة:

4. ثم انقر فوق زر أيقونة إرسال إلى المستلمين بالبريد الإلكتروني، وسيظهر مربع تنبيه، في مربع تنبيه البريد الإلكتروني، قم بتحديد إرسال الورقة الحالية كنص الرسالة، وانقر فوق موافق. انظر لقطة الشاشة:

5. ويتم عرض مربع تحرير البريد الإلكتروني أعلى بيانات ورقة العمل، يمكنك إدخال المستلمين والموضوع والمقدمة في مربعات النص المقابلة. انظر لقطة الشاشة:

6. ثم انقر فوق إرسال هذه الورقة لإرسال ورقة العمل النشطة كنص الرسالة إلى الشخص المحدد.

اكتشف سحر Excel مع Kutools AI

• التنفيذ الذكي: قم بعمليات الخلية، وتحليل البيانات، وإنشاء المخططات - كل ذلك يتم من خلال أوامر بسيطة.
• الصيغ المخصصة: قم بإنشاء صيغ مصممة خصيصًا لتسهيل سير عملك.
• برمجة VBA: كتابة وتطبيق أكواد VBA بسهولة.
• تفسير الصيغ: فهم الصيغ المعقدة بسهولة.
• ترجمة النصوص: تجاوز الحواجز اللغوية داخل جداول البيانات الخاصة بك.

عزز قدرات Excel لديك باستخدام أدوات تعمل بالذكاء الاصطناعي. قم بالتنزيل الآن وعش تجربة الكفاءة كما لم يحدث من قبل!

إرسال ورقة عمل واحدة كمرفق من Excel باستخدام كود VBA

إذا كنت ترغب في إرسال ورقة العمل النشطة كمرفق، يمكن أن يساعدك الكود التالي لـ VBA.

1. قم بتفعيل ورقة العمل التي تريد إرسالها.

2. اضغط باستمرار على مفتاحي ALT + F11، وسيفتح نافذة Microsoft Visual Basic for Applications.

3. انقر فوق إدراج > وحدة، والصق الكود التالي في نافذة الوحدة.

كود VBA: إرسال ورقة العمل الحالية كمرفق من Excel

Sub SendWorkSheet()
'Update 20131209
Dim xFile As String
Dim xFormat As Long
Dim Wb As Workbook
Dim Wb2 As Workbook
Dim FilePath As String
Dim FileName As String
Dim OutlookApp As Object
Dim OutlookMail As Object
On Error Resume Next
Application.ScreenUpdating = False
Set Wb = Application.ActiveWorkbook
ActiveSheet.Copy
Set Wb2 = Application.ActiveWorkbook
Select Case Wb.FileFormat
Case xlOpenXMLWorkbook:
    xFile = ".xlsx"
    xFormat = xlOpenXMLWorkbook
Case xlOpenXMLWorkbookMacroEnabled:
    If Wb2.HasVBProject Then
        xFile = ".xlsm"
        xFormat = xlOpenXMLWorkbookMacroEnabled
    Else
        xFile = ".xlsx"
        xFormat = xlOpenXMLWorkbook
    End If
Case Excel8:
    xFile = ".xls"
    xFormat = Excel8
Case xlExcel12:
    xFile = ".xlsb"
    xFormat = xlExcel12
End Select
FilePath = Environ$("temp") & "\"
FileName = Wb.Name & Format(Now, "dd-mmm-yy h-mm-ss")
Set OutlookApp = CreateObject("Outlook.Application")
Set OutlookMail = OutlookApp.CreateItem(0)
Wb2.SaveAs FilePath & FileName & xFile, FileFormat:=xFormat
With OutlookMail
    .To = "skyyang@extendoffice.com"
    .CC = ""
    .BCC = ""
    .Subject = "kte features"
    .Body = "Please check and read this document."
    .Attachments.Add Wb2.FullName
    .Send
End With
Wb2.Close
Kill FilePath & FileName & xFile
Set OutlookMail = Nothing
Set OutlookApp = Nothing
Application.ScreenUpdating = True
End Sub

ملاحظة: في الكود أعلاه، يمكنك تغيير المعلومات التالية حسب حاجتك.

• .To = "skyyang@extendoffice.com"
• .CC = ""
• .BCC = ""
• .Subject = "kte features"
• .Body = "Please check and read this document."

4. ثم اضغط على مفتاح F5 لتشغيل هذا الكود، وسيظهر مربع تنبيه، انقر فوق سماح عند انتهاء شريط التقدم، وبعد ذلك سيتم إرسال ورقة العمل الحالية إلى المستلم كمرفق.

إرسال ورقة عمل واحدة كملف PDF من Excel باستخدام كود VBA

في بعض الأحيان، تحتاج إلى إرسال تقرير ورقة العمل الخاصة بك إلى الآخرين ولكن لا تريد للآخرين تعديله. في هذه الحالة، يمكنك إرسال ورقة العمل كملف PDF من Excel.

1. قم بتفعيل ورقة العمل التي تريد إرسالها.

2. اضغط باستمرار على مفتاحي ALT + F11، وسيفتح نافذة Microsoft Visual Basic for Applications.

3. انقر فوق إدراج > وحدة، والصق الكود التالي في نافذة الوحدة.

كود VBA: إرسال ورقة العمل الحالية كملف PDF من Excel

Sub SendWorkSheetToPDF()
'Update 20131209
Dim Wb As Workbook
Dim FileName As String
Dim OutlookApp As Object
Dim OutlookMail As Object
On Error Resume Next
Set Wb = Application.ActiveWorkbook
FileName = Wb.FullName
xIndex = VBA.InStrRev(FileName, ".")
If xIndex > 1 Then FileName = VBA.Left(FileName, xIndex - 1)
FileName = FileName & "_" + ActiveSheet.Name & ".pdf"
ActiveSheet.ExportAsFixedFormat Type:=xlTypePDF, FileName:=FileName
Set OutlookApp = CreateObject("Outlook.Application")
Set OutlookMail = OutlookApp.CreateItem(0)
With OutlookMail
    .To = "skyyang@extendoffice.com"
    .CC = ""
    .BCC = ""
    .Subject = "kte features"
    .Body = "Please check and read this document."
    .Attachments.Add FileName
    .Send
End With
Kill FileName
Set OutlookMail = Nothing
Set OutlookApp = Nothing
End Sub

ملاحظة: في الكود أعلاه، يمكنك تغيير المعلومات التالية حسب حاجتك.

• .To = "skyyang@extendoffice.com"
• .CC = ""
• .BCC = ""
• .Subject = "kte features"
• .Body = "Please check and read this document."

4. ثم اضغط على مفتاح F5، وسيظهر مربع تنبيه، انقر فوق سماح بعد انتهاء شريط التقدم، ثم يتم إرسال ورقة العمل النشطة إلى الشخص المحدد كملف PDF.

ملاحظات:

1. هذه الطرق متاحة فقط عندما تستخدم Outlook كبرنامج بريدك.

2. بعد إرسال ورقة العمل الحالية، يمكنك الانتقال إلى Outlook للتأكد من أن البريد الإلكتروني قد تم إرساله بنجاح.

إنشاء قائمة بريدية ثم إرسال رسائل البريد الإلكتروني

الأدوات Kutools لـ Excel لإنشاء قائمة بريدية وإرسال رسائل البريد الإلكتروني يمكنها بسرعة إنشاء قائمة بريدية في ورقة عمل، ثم إرسال نفس الموضوع، نفس المحتويات ونفس المرفقات إلى عناوين بريد إلكتروني متعددة.

انتقل إلى التنزيل

مقالات ذات صلة:

كيفية إرسال المصنف الحالي عبر Outlook من Excel؟

كيفية إرسال / إيميل نطاق الخلايا عبر Outlook من Excel؟