كيفية طباعة ورقة العمل مع دوائر التحقق من الصحة في إكسيل؟

في حالة معينة ، قد نقوم بوضع دائرة حول بعض البيانات غير الصالحة لجعلها بارزة ، ولكن عندما تحتاج إلى طباعة ورقة العمل مع دوائر التحقق من الصحة ، فلن تتم طباعة الدوائر. هل سبق لك أن عانيت من هذه المشكلة في Excel؟ اليوم ، سأريكم بعض الحيل السريعة لحل هذه الوظيفة.

اطبع ورقة العمل بدوائر تحقق من خلال لصقها كصورة

اطبع ورقة العمل مع دوائر التحقق من الصحة باستخدام كود VBA

---

اطبع ورقة العمل بدوائر تحقق من خلال لصقها كصورة

في Excel ، لا يمكننا طباعة دوائر التحقق من الصحة مباشرةً ، ولكن يمكننا نسخ نطاق البيانات ولصقه مع دوائر التحقق كصورة ، ثم طباعته.

1. حدد نطاق البيانات الذي تريد طباعة الدوائر.

2. صحافة CTRL + C على لوحة المفاتيح لنسخها ، ثم انتقل إلى ورقة عمل جديدة ، وانقر فوق خلية واحدة ، وانقر بزر الماوس الأيمن ، واختر لصق خاص > صورة، انظر لقطة الشاشة:

3. ثم تم لصق التحديد كصورة ، والآن عند طباعة ورقة العمل الجديدة ، ستتم طباعة الدوائر بنجاح.

---

اطبع ورقة العمل مع دوائر التحقق من الصحة باستخدام كود VBA

إذا كنت لا ترغب في لصق نطاق البيانات كصورة ، فيمكن أن يساعدك رمز VBA التالي أيضًا.

1. بعد ضبط التحقق من صحة البيانات ، يرجى الضغط باستمرار على ALT + F11 في Excel لفتح ملف نافذة ميكروسوفت فيسوال باسيك للتطبيقات.

2. ثم اضغط إدراج > وحدة، ولصق الماكرو التالي في ملف نافذة الوحدة.

كود فبا: أدخل دوائر حمراء على البيانات غير الصالحة

Sub AddValidationCirclesForPrinting()
'Update 20140724
Dim Rng As Range
Dim WorkRng As Range
Dim xCount As Integer
Dim xShape As Shape
On Error Resume Next
Set WorkRng = Application.ActiveSheet.Cells.SpecialCells(xlCellTypeAllValidation)
If WorkRng Is Nothing Then
    Exit Sub
End If
xCount = 0
For Each Rng In WorkRng
   If Not Rng.Validation.Value Then
       Set xShape = Application.ActiveSheet.Shapes.AddShape(msoShapeOval, Rng.Left - 2, Rng.Top - 2, Rng.Width + 4, Rng.Height + 4)
       xShape.Fill.Visible = msoFalse
       xShape.Line.ForeColor.SchemeColor = 10
       xShape.Line.Weight = 1.25
       xCount = xCount + 1
       xShape.Name = "InvalidData_" & xCount
   End If
Next
Exit Sub
End Sub

3. ثم اضغط F5 مفتاح لتنفيذ هذا الرمز ، وقد تم وضع دائرة حول البيانات غير الصالحة بالشكل البيضاوي الأحمر ، انظر الصورة:

4. عندما تذهب لطباعة ورقة العمل هذه التي تحتوي على الدوائر الحمراء ، ستتم طباعة الدوائر أيضًا.

ملاحظة:

باستخدام رمز VBA هذا ، لن تتم إزالة الدوائر باستخدام ملف Excel مسح دوائر التحقق من الصحة الميزة ، إذا كنت تريد حذف الدوائر ، يرجى تطبيق الكود أدناه.

كود فبا: إزالة دوائر التحقق من الصحة في ورقة العمل

Sub RemoveValidationCircles()
'Update 20140724
Dim xShape As Shape
For Each xShape In Application.ActiveSheet.Shapes
    If xShape.Name Like "InvalidData_*" Then
        xShape.Delete
    End If
Next
End Sub

---

مقالة ذات صلة:

كيفية وضع دائرة على البيانات غير الصالحة في Excel؟