كيفية استخدام دالة الجمع إذا بمعيار واحد أو أكثر في Excel؟

في Excel، جمع القيم بناءً على معيار واحد أو أكثر هو مهمة شائعة بالنسبة لمعظم المستخدمين. يمكن أن تساعدنا دالة SUMIF في جمع القيم بسرعة بناءً على شرط واحد، وتساعدنا دالة SUMIFS في جمع القيم باستخدام معايير متعددة. في هذه المقالة، سأشرح كيفية الجمع باستخدام معيار واحد أو أكثر في Excel.

جمع قيم الخلايا باستخدام معيار واحد في Excel

جمع قيم الخلايا باستخدام معايير متعددة في Excel

جمع قيم الخلايا باستخدام معيار واحد في Excel

أولاً، سأقدم لك صيغة الدالة SUMIF كمرجع:

SUMIF(النطاق, المعيار, [نطاق_الجمع])

• النطاق: نطاق الخلايا الذي سيتم تقييمه حسب المعيار الخاص بك؛
• المعيار: الشرط الذي تريد استخدامه؛
• نطاق_الجمع: نطاق الخلايا المراد جمعها إذا تم استيفاء الشرط.

لتطبيق دالة SUMIF هذه، سأستخدم البيانات التالية كمثال:

(1.) مجموع الكمية عندما يكون المنتج “KTE”:

=SUMIF(A2:A12,E2,C2:C12) واضغط على مفتاح Enter للحصول على النتيجة، (A2:A12 هو نطاق الخلايا الذي يحتوي على المعيار، E2 هو المعيار الذي تريد جمع القيم بناءً عليه، C2:C12 يشير إلى النطاق الذي تريد جمعه) انظر إلى لقطة الشاشة:

(2.) جمع كمية جميع المنتجات باستثناء “KTE”:

=SUMIF(A2:A12,"<>KTE",C2:C12)، ثم اضغط على مفتاح Enter لجمع كمية جميع المنتجات باستثناء KTE، (A2:A12 هو نطاق الخلايا الذي يحتوي على المعيار، <>KTE هو المعيار الذي يستثني KTE، C2:C12 يشير إلى النطاق الذي تريد جمعه)، انظر إلى لقطة الشاشة:

(3.) جمع الكمية الأكبر من 250:

=SUMIF(C2:C12,">250")، واضغط على مفتاح Enter للحصول على النتيجة، (C2:C12 يشير إلى النطاق الذي تريد جمعه، >250 هو المعيار الذي تحتاجه، يمكنك أيضًا تغييره ليكون أقل من 250 حسب الحاجة)، انظر إلى لقطة الشاشة:

(4.) استخدام دالة SUMIF+SUMIF+... مع معايير OR متعددة، جمع كميات KTE و KTW:

=SUMIF(A2:A12,"KTE",C2:C12) + SUMIF(A2:A12,"KTW",C2:C12)( A2:A12 هو نطاق الخلايا الذي يحتوي على المعايير، KTE و KTW هما المعايير التي تريد جمع القيم بناءً عليها، C2:C12 يشير إلى النطاق الذي تريد جمعه)، ثم اضغط على مفتاح Enter للحصول على النتيجة:

جمع قيم الخلايا باستخدام معايير متعددة في Excel

صيغة دالة SUMIFS كما يلي:

SUMIFS(نطاق_الجمع, نطاق_المعيار1, المعيار1,[نطاق_المعيار2, المعيار2],...)

• نطاق_الجمع: نطاق الخلايا المراد جمعها؛
• نطاق_المعيار1: النطاق الأول الذي يحتوي على المعيار؛
• المعيار1: الشرط الأول الذي يجب استيفاؤه؛
• نطاق_المعيار2، المعيار2، ...: هذه هي النطاقات الإضافية والمعايير المرتبطة بها.

(1.) جمع الكمية حيث يكون المنتج KTE والاسم James:

يرجى إدخال هذه الصيغة: =SUMIFS(C2:C12,A2:A12,"KTE",B2:B12,"James"),(C2:C12 هو نطاق الخلايا الذي يحتاج إلى الجمع، A2:A12، KTE هما النطاق الأول والمعيار الأول، B2:B12، James، هما النطاق الثاني والمعيار الثاني)، ثم اضغط على مفتاح Enter، انظر إلى لقطة الشاشة:

هناك أيضًا صيغة صفيف يمكن أن تساعدك: =SUM((A2:A12="kte")*(B2:B12="James")*C2:C12)، وتحتاج إلى الضغط على Ctrl + Shift + Enter معًا بعد كتابة الصيغة.

(2.) جمع الكمية حيث يكون المنتج KTE والاسم ليس James

اكتب هذه الصيغة: =SUMIFS(C2:C12,A2:A12,"KTE",B2:B12,"<>James")(C2:C12 هو نطاق الخلايا الذي يحتاج إلى الجمع، A2:A12، KTE هما النطاق الأول والمعيار الأول، B2:B12، <>James، هما النطاق الثاني والمعيار الثاني)، ثم اضغط على مفتاح Enter للحصول على النتيجة، انظر إلى لقطة الشاشة:

صيغة صفيف أخرى يمكن أن تنجز هذه العملية أيضًا: =SUM((A2:A12="kte")*(B2:B12<>"James")*C2:C12)، ولكن يجب أن تضغط على Ctrl + Shift + Enter بعد كتابة هذه الصيغة.

(3.) جمع الكمية حيث يكون المنتج KTE والكمية أكبر من 150

يمكنك استخدام صيغة SUMIFS هذه: =SUMIFS(C2:C12,A2:A12,"KTE",C2:C12,">150")(C2:C12 هو نطاق الخلايا الذي يحتاج إلى الجمع، A2:A12، KTE هما النطاق الأول والمعيار الأول، C2:C12، >150، هما النطاق الثاني والمعيار الثاني)، ثم اضغط على مفتاح Enter للحصول على النتيجة.

يمكنك أيضًا استخدام صيغة الصفيف SUM للحصول على النتيجة التي تريدها، =SUM((A2:A12="kte")*(C2:C12>150)*C2:C12) يرجى تذكر الضغط على Ctrl + Shift + Enter بعد كتابة هذه الصيغة.

(4.) جمع الكمية التي تكون بين 100 و 200

لجمع القيم بين عددين، يرجى استخدام هذه الصيغة: =SUMIFS(C2:C12,C2:C12,">100",C2:C12,"<200")( C2:C12 هو نطاق الخلايا الذي يحتاج إلى الجمع، C2:C12، >100 هما النطاق الأول والمعيار الأول، C2:C12، <200، هما النطاق الثاني والمعيار الثاني)، ثم اضغط على مفتاح Enter للحصول على النتيجة كما يلي:

بالطبع، يمكن أن تساعدك صيغة الصفيف SUM أيضًا، =SUM((C2:C12>100)*(C2:C12<200)*C2:C12)، تذكر الضغط على Ctrl + Shift + Enter معًا للحصول على النتيجة الصحيحة.

مقالات ذات صلة:

كيفية جمع أعمدة متعددة بناءً على معيار واحد في Excel؟

كيفية جمع الخلايا التي تحتوي على نص وأرقام في Excel؟