كيفية توليد أو سرد جميع التباديل الممكنة في Excel؟

على سبيل المثال، لدي ثلاثة أحرف XYZ، الآن أريد سرد جميع التباديل الممكنة بناءً على هذه الأحرف الثلاثة للحصول على ستة نتائج مختلفة مثل: XYZ، XZY، YXZ، YZX، ZXY و ZYX. في Excel، كيف يمكنك بسرعة توليد أو سرد جميع التباديل بناءً على عدد مختلف من الأحرف؟

توليد أو سرد جميع التباديل الممكنة بناءً على الأحرف باستخدام كود VBA

توليد أو سرد جميع التباديل الممكنة بناءً على الأحرف باستخدام كود VBA

قد يساعدك الكود التالي لـ VBA في سرد جميع التباديل بناءً على عدد معين من الحروف الخاص بك، يرجى القيام بما يلي:

1. اضغط باستمرار على مفتاحي ALT + F11 لفتح نافذة Microsoft Visual Basic for Applications.

2. انقر فوق إدراج > وحدة، والصق الكود التالي في نافذة الوحدة.

كود VBA: سرد جميع التباديل الممكنة في Excel

Sub GetString()
'Updateby Extendoffice
    Dim xStr As String
    Dim FRow As Long
    Dim xScreen As Boolean
    xScreen = Application.ScreenUpdating
    Application.ScreenUpdating = False
    xStr = Application.InputBox("Enter text to permute:", "Kutools for Excel", , , , , , 2)
    If Len(xStr) < 2 Then Exit Sub
    If Len(xStr) >= 8 Then
        MsgBox "Too many permutations!", vbInformation, "Kutools for Excel"
        Exit Sub
    Else
        ActiveSheet.Columns(1).Clear
        FRow = 1
        Call GetPermutation("", xStr, FRow)
    End If
    Application.ScreenUpdating = xScreen
End Sub
Sub GetPermutation(Str1 As String, Str2 As String, ByRef xRow As Long)
    Dim i As Integer, xLen As Integer
    xLen = Len(Str2)
    If xLen < 2 Then
        Range("A" & xRow) = Str1 & Str2
        xRow = xRow + 1
    Else
        For i = 1 To xLen
            Call GetPermutation(Str1 + Mid(Str2, i, 1), Left(Str2, i - 1) + Right(Str2, xLen - i), xRow)
        Next
    End If
End Sub

3. ثم اضغط على مفتاح F5 لتشغيل هذا الكود، وسيظهر مربع تنبيه لتذكيرك بإدخال الأحرف التي تريد سرد جميع التباديل لها، انظر إلى لقطة الشاشة:

4. بعد إدخال الأحرف، ثم انقر على زر موافق، سيتم عرض جميع التباديل الممكنة في العمود A من ورقة العمل النشطة. انظر إلى لقطة الشاشة:

ملاحظة: إذا كان طول الأحرف المدخلة يساوي أو أكبر من 8 أحرف، فلن يعمل هذا الكود لأن هناك الكثير من التباديل.