كيفية البحث عن النص واستبداله مع الحفاظ على التنسيق في Excel؟

وظيفة البحث والاستبدال قوية ومفيدة عندما نحتاج إلى العثور على قيمة محددة واستبدالها بأخرى. ولكن إذا كان هناك نطاق من الخلايا، وبعض هذه الخلايا تحتوي على قيم بتنسيقات مختلفة. في هذه الحالة، فإن استخدام وظيفة البحث والاستبدال لاستبدال القيم سيؤدي إلى كسر تنسيق القيم داخل الخلايا كما هو موضح في لقطة الشاشة أدناه. فكيف يمكننا الحفاظ على تنسيق القيم في كل خلية أثناء البحث والاستبدال في Excel؟

البحث والاستبدال مع الحفاظ على التنسيق باستخدام كود الماكرو

البحث والاستبدال مع الحفاظ على التنسيق باستخدام كود الماكرو

لا توجد طرق أخرى سوى كود الماكرو الذي يمكن أن يساعدك في العثور على النص واستبداله مع الحفاظ على التنسيق.

1. اضغط على مفاتيح Alt + F11 لفتح نافذة Microsoft Visual Basic for Application.

2. انقر فوق إدراج > وحدة، والصق الكود أدناه في البرنامج النصي.

VBA: البحث والاستبدال مع الحفاظ على التنسيق

Sub CharactersReplace(Rng As Range, FindText As String, ReplaceText As String, Optional MatchCase As Boolean = False)
  'UpdatebyExtendoffice20160711
    Dim I As Long
    Dim xLenFind As Long
    Dim xLenRep As Long
    Dim K As Long
    Dim xValue As String
    Dim M As Long
    Dim xCell As Range
    xLenFind = Len(FindText)
    xLenRep = Len(ReplaceText)
    If Not MatchCase Then M = 1
    For Each xCell In Rng
        If VarType(xCell) = vbString Then
            xValue = xCell.Value
            K = 0
            For I = 1 To Len(xValue)
              If StrComp(Mid$(xValue, I, xLenFind), FindText, M) = 0 Then
                xCell.Characters(I + K, xLenFind).Insert ReplaceText
                K = K + xLenRep - xLenFind
              End If
            Next
        End If
    Next
End Sub

Sub Test_CharactersReplace()
    Dim xRg As Range
    Dim xTxt As String
    Dim xCell As Range
    On Error Resume Next
    If ActiveWindow.RangeSelection.Count > 1 Then
      xTxt = ActiveWindow.RangeSelection.AddressLocal
    Else
      xTxt = ActiveSheet.UsedRange.AddressLocal
    End If
    Set xRg = Application.InputBox("Select a range:", "Kutools for Excel", xTxt, , , , , 8)
    If xRg Is Nothing Then Exit Sub
    Call CharactersReplace(xRg, "KK", "Kutools", True)
End Sub

تلميح: في الكود، KK هي السلسلة التي تريد البحث عنها، وKutools هي السلسلة التي تريد استبدالها بها، يمكنك تغييرها حسب الحاجة.

3. اضغط F5 مفتاح، ستظهر نافذة منبثقة لتختار نطاقًا للبحث والاستبدال، انظر إلى لقطة الشاشة:

4. انقر فوق موافق، وسيتم استبدال السلسلة المحددة في الخلية المختارة بأخرى مع الحفاظ على التنسيق.