كيفية تتبع التغييرات دون مشاركة المصنف؟

عادةً، عند تطبيق ميزة تتبع التغييرات في Excel، سيتم مشاركة المصنف في نفس الوقت، مما قد يكون مزعجًا لأن بعض الميزات في Excel ستكون معطلة. فكيف يمكنك تتبع التغييرات دون مشاركة المصنف؟ هنا، سأوصي باستخدام كود VBA.

تتبع التغييرات دون مشاركة المصنف باستخدام كود VBA

تحويل النص إلى جدول في Outlook

لا توجد طريقة مباشرة لحل هذه المشكلة، لكن يمكنك استخدام كود VBA مرنة. يرجى اتباع الخطوات التالية:

1. انقر بزر الماوس الأيمن على تبويب الورقة التي تريد تتبع الخلايا المعدلة فيها، واختر عرض الكود من قائمة السياق، في نافذة Microsoft Visual Basic for Applications المنبثقة، يرجى نسخ ولصق الكود التالي في وحدة فارغة:

كود VBA: تتبع التغييرات دون مشاركة المصنف:

Private Sub Worksheet_Change(ByVal Target As Range)
  'Updateby Extendoffice
    Const xRg As String = "A1:Z1000"
    Dim strOld As String
    Dim strNew As String
    Dim strCmt As String
    Dim xLen As Long
    With Target(1)
        If Intersect(.Cells, Range(xRg)) Is Nothing Then Exit Sub
        strNew = .Text
        Application.EnableEvents = False
        Application.Undo
        strOld = .Text
        .Value = strNew
        Application.EnableEvents = True
        strCmt = "Edit: " & Format$(Now, "dd Mmm YYYY hh:nn:ss") & " by " & _
        Application.UserName & Chr(10) & "Previous Text :- " & strOld
        If Target(1).Comment Is Nothing Then
            .AddComment
        Else
            xLen = Len(.Comment.Shape.TextFrame.Characters.Text)
        End If
        With .Comment.Shape.TextFrame
            .AutoSize = True
            .Characters(Start:=xLen + 1).Insert IIf(xLen, vbLf, "") & strCmt
        End With
    End With
End Sub

ملاحظة: في الكود أعلاه، A1:Z1000 هو نطاق البيانات الذي تريد تتبع التغييرات فيه.

2. ثم احفظ وأغلق نافذة الكود هذه. الآن، عندما تقوم بتغيير القيم في أي خلايا ضمن النطاق المحدد، سيتم تتبع التغييرات دون مشاركة المصنف. شاهد لقطة الشاشة: