كيفية السماح بتحديد خانة اختيار واحدة فقط في مجموعة في Excel؟

كما هو موضح في لقطة الشاشة أدناه، بالنسبة لمجموعة من خانات الاختيار المدرجة في الصف 2، عند تحديد أو وضع علامة على خانة اختيار واحدة، يتم تعطيل جميع الخانات الأخرى تلقائيًا. كيف يمكن تحقيق ذلك؟ يمكن أن يساعدك كود VBA في هذه المقالة.

السماح بتحديد خانة اختيار واحدة فقط باستخدام كود VBA

السماح بتحديد خانة اختيار واحدة فقط باستخدام كود VBA

يمكنك تشغيل أكواد VBA التالية لتحديد خانة اختيار واحدة فقط في مجموعة خانات الاختيار في كل مرة. الرجاء القيام بما يلي.

1. أولاً، يرجى إدراج خانات الاختيار حسب الحاجة. هنا، يجب عليك إدراج خانات اختيار ActiveX Control كما هو موضح في لقطة الشاشة التالية:

2. ثم اضغط على مفتاحي Alt + F11 معًا لفتح نافذة Microsoft Visual Basic for Applications.

3. في نافذة Microsoft Visual Basic for Applications المفتوحة، انقر فوق إدراج > وحدة تصنيف.

4. قم بتغيير اسم الفئة إلى ClsChk في مربع (الاسم) في جزء الخصائص، ثم انسخ والصق الكود التالي في نافذة الكود المقابلة. انظر لقطة الشاشة:

كود VBA 1: تحديد خانة اختيار واحدة فقط في كل مرة

Option Explicit
Public WithEvents Chk As MSForms.CheckBox
Private Sub Chk_Click()
Call SelOneCheckBox(Chk)
End Sub

Sub SelOneCheckBox(Target As Object)
Dim xObj As Object
Dim I As String
Dim n As Integer
If Target.Object.Value = True Then

    I = Right(Target.Name, Len(Target.Name) - 8)
    For n = 1 To ActiveSheet.OLEObjects.Count
      If n <> Int(I) Then
        Set xObj = ActiveSheet.OLEObjects.Item(n)
        xObj.Object.Value = False
        xObj.Object.Enabled = False
      End If
    Next
Else
    I = Right(Target.Name, Len(Target.Name) - 8)
    For n = 1 To ActiveSheet.OLEObjects.Count
      If n <> Int(I) Then
        Set xObj = ActiveSheet.OLEObjects.Item(n)
        xObj.Object.Enabled = True
      End If
    Next
End If
End Sub

5. الآن انقر فوق إدراج > وحدة، ثم انسخ والصق الكود التالي في نافذة الوحدة.

كود VBA 2: تحديد خانة اختيار واحدة فقط في كل مرة

Dim xCollection As New Collection
Public Sub ClsChk_Init()
Dim xSht As Worksheet
Dim xObj As Object
Dim xChk As ClsChk
   Set xSht = ActiveSheet
   Set xCollection = Nothing
    For Each xObj In xSht.OLEObjects
        If xObj.Name Like "CheckBox**" Then
            Set xChk = New ClsChk
            Set xChk.Chk = CallByName(xSht, xObj.Name, VbGet)
            xCollection.Add xChk
        End If
    Next
    Set xChk = Nothing
End Sub

6. اضغط على مفتاح F5 لتشغيل الكود.

من الآن فصاعدًا، عند تحديد أي خانة اختيار واحدة في ورقة العمل، سيتم تعطيل جميع خانات الاختيار الأخرى تلقائيًا، ويمكنك إلغاء تحديدها لتفعيل جميع خانات الاختيار مرة أخرى.

ملاحظة: إذا تم إضافة خانة اختيار جديدة إلى مجموعة خانات الاختيار، يرجى إعادة تشغيل كود VBA لتفعيل جميع خانات الاختيار مرة أخرى. حذف خانة اختيار من مجموعة خانات الاختيار يتطلب أيضًا إعادة تشغيل الكود.

مقالات ذات صلة:

• كيفية تصفية البيانات بناءً على خانة اختيار في Excel؟
• كيفية إخفاء خانة اختيار عند إخفاء صف في Excel؟
• كيفية تمييز الخلية أو الصف باستخدام خانة اختيار في Excel؟
• كيفية إنشاء قائمة منسدلة تحتوي على خانات اختيار متعددة في Excel؟
• كيفية إدخال ختم تاريخ في خلية عند وضع علامة على خانة اختيار في Excel؟