كيف يمكنك حساب عدد صفحات الملفات بصيغة PDF باستخدام Excel؟

إذا كان لديك عدة ملفات PDF في مجلد وتحتاج إلى سرد أسماء هذه الملفات مع عدد صفحاتها في Excel، يمكنك القيام بذلك بسهولة باستخدام ماكرو VBA بسيط. سيرشدك هذا البرنامج التعليمي خلال الخطوات اللازمة لاستخراج وعرض أسماء ملفات PDF وأرقام صفحاتها المقابلة في ورقة عمل Excel.

عرض أسماء ملفات PDF وأرقام صفحاتها في Excel باستخدام VBA

عرض أسماء ملفات PDF وأرقام صفحاتها في Excel باستخدام VBA

قد يساعدك الكود التالي من VBA في عرض جميع أسماء ملفات PDF وأرقام صفحاتها في ورقة العمل. يرجى اتباع الخطوات التالية:

1. افتح ورقة العمل حيث تريد الحصول على ملفات PDF وأرقام الصفحات.

2. اضغط باستمرار على مفتاحي "ALT" + "F11"، وسيتم فتح نافذة "Microsoft Visual Basic for Applications".

3. انقر على "إدراج" > "وحدة"، والصق الماكرو التالي في نافذة "الوحدة".

كود VBA: سرد جميع أسماء ملفات PDF وأرقام صفحاتها في ورقة العمل:

Sub Test()
    Dim I As Long
    Dim xRg As Range
    Dim xStr As String
    Dim xFd As FileDialog
    Dim xFdItem As Variant
    Dim xFileName As String
    Dim xFileNum As Long
    Dim RegExp As Object
    Set xFd = Application.FileDialog(msoFileDialogFolderPicker)
    If xFd.Show = -1 Then
        xFdItem = xFd.SelectedItems(1) & Application.PathSeparator
        xFileName = Dir(xFdItem & "*.pdf", vbDirectory)
        Set xRg = Range("A1")
        Range("A:B").ClearContents
        Range("A1:B1").Font.Bold = True
        xRg = "File Name"
        xRg.Offset(0, 1) = "Pages"
        I = 2
        xStr = ""
        Do While xFileName <> ""
            Cells(I, 1) = xFileName
            Set RegExp = CreateObject("VBscript.RegExp")
            RegExp.Global = True
            RegExp.Pattern = "/Type\s*/Page[^s]"
            xFileNum = FreeFile
            Open (xFdItem & xFileName) For Binary As #xFileNum
                xStr = Space(LOF(xFileNum))
                Get #xFileNum, , xStr
            Close #xFileNum
            Cells(I, 2) = RegExp.Execute(xStr).Count
            I = I + 1
            xFileName = Dir
        Loop
        Columns("A:B").AutoFit
    End If
End Sub

4. بعد لصق الكود، اضغط على مفتاح "F5" لتشغيل هذا الكود، ستظهر نافذة "تصفح"، يرجى تحديد المجلد الذي يحتوي على ملفات PDF التي تريد سردها وحساب عدد صفحاتها، انظر إلى الصورة:

5. وبعد ذلك، انقر على زر "موافق"، سيتم سرد جميع أسماء ملفات PDF وأرقام صفحاتها في ورقة العمل الحالية، انظر إلى الصورة: