Skip to main content

بيانات عشوائية في Excel: توليد أرقام ونصوص وتواريخ وأوقات عشوائية في Excel

Author: Xiaoyang Last Modified: 2025-05-30

بشكل عام، البيانات العشوائية هي سلسلة من الأرقام أو السلاسل النصية أو الرموز الأخرى التي تُستخدم في العينات الإحصائية أو تشفير البيانات أو اليانصيب أو الاختبار أو التدريب أو أي مجال آخر يتطلب نتائج غير متوقعة. في هذا المقال، سنستعرض طرقًا مختلفة لتوليد أرقام وسلاسل نصية وتواريخ وأوقات عشوائية في Excel العادي وExcel365.

جدول المحتويات:

1. توليد أرقام ونصوص وتواريخ وأوقات عشوائية في Excel

2. توليد أرقام ونصوص وتواريخ عشوائية في Excel365 /2021 والإصدارات الأحدث

3. منع تغيير النتائج العشوائية


توليد أرقام ونصوص وتواريخ وأوقات عشوائية في Excel

سيتناول هذا القسم حلولاً متنوعة لتوليد الأرقام والسلاسل النصية والتواريخ والأوقات في أدوات الورقة العمل في Excel.

1.1 توليد أرقام عشوائية في Excel

لتوليد أو إدراج عدة أرقام عشوائية في أدوات الورقة العمل، يمكنك الاعتماد بشكل كبير على دالتي RAND أو RANDBETWEEN. بالإضافة إلى الصيغ، هناك أكواد وأدوات سهلة أخرى يمكنها مساعدتك أيضاً.

 دالة RAND لتوليد أرقام عشوائية

توليد أرقام عشرية عشوائية بين رقمين

يمكن استخدام دالة RAND لتوليد أرقام عشرية عشوائية بين0 و1، أو بين0 وأي رقم آخر، أو بين رقمين محددين.

الصيغة الوصف
=RAND() توليد أرقام عشرية عشوائية بين0 و1.
=RAND()*N توليد أرقام عشرية عشوائية بين0 وN.
=RAND()*(B-A)+A توليد أرقام عشرية عشوائية بين أي رقمين تحددهما. (A هو الحد الأدنى وB هو الحد الأعلى للقيمة.)

يرجى نسخ الصيغة أعلاه التي تحتاجها، وتطبيقها على عدد الخلايا الذي تريده، وستحصل على النتائج كما هو موضح في لقطات الشاشة أدناه:

=RAND() =RAND()*50 =RAND()*(100-50)+50
A screenshot of the result from the formula =RAND() showing random decimal numbers between 0 and 1 in Excel A screenshot of the result from the formula =RAND()*50 showing random decimal numbers between 0 and 50 in Excel A screenshot of the result from the formula =RAND()*(100-50)+50 showing random decimal numbers between 50 and 100 in Excel

توليد أرقام صحيحة عشوائية بين رقمين

لتوليد بعض الأعداد الصحيحة العشوائية، يجب دمج دالتي RAND وINT كما هو موضح في الجدول أدناه:

الصيغة الوصف
=INT(RAND()*N) توليد أعداد صحيحة عشوائية بين0 وN.
=INT(RAND()*(B-A)+A) توليد أعداد صحيحة عشوائية بين أي رقمين تحددهما. (A هو الحد الأدنى وB هو الحد الأعلى للقيمة.)

يرجى تطبيق الصيغة أعلاه التي تحتاجها، ثم سحب ونسخ الصيغة إلى خلايا أخرى حسب الحاجة، وستحصل على النتائج كما هو موضح في لقطات الشاشة أدناه:

=INT(RAND()*100) =INT(RAND()*(500-200)+200)
A screenshot of the result from the formula =INT(RAND()*100) showing random integers between 0 and 100 in Excel A screenshot of the result from the formula =INT(RAND()*(500-200)+200) showing random integers between 200 and 500 in Excel

 دالة RANDBETWEEN لتوليد أرقام عشوائية

في Excel، توجد دالة RANDBETWEEN التي يمكنها أيضاً مساعدتك في إنشاء أرقام عشوائية بسرعة وسهولة.

توليد أعداد صحيحة عشوائية بين رقمين

=RANDBETWEEN(bottom, top)
  • bottom, top: أدنى وأعلى رقم في النطاق العشوائي الذي ترغب في الحصول عليه.

على سبيل المثال، إذا كنت تريد توليد أعداد صحيحة عشوائية بين100 و200، يرجى تطبيق الصيغة أدناه في خلية فارغة، ثم سحب ونسخ الصيغة إلى الخلايا الأخرى التي تريدها، كما هو موضح في لقطة الشاشة:

=RANDBETWEEN(100,200)

A screenshot of the result from the formula =RANDBETWEEN(100, 200) showing random integers between 100 and 200 in Excel

نصيحة: يمكن لدالة RANDBETWEEN أيضاً إنشاء أرقام موجبة وسالبة. لإدراج أرقام عشوائية بين -100 و100، فقط قم بتغيير قيمة bottom إلى -100، كما في الصيغة أدناه:

=RANDBETWEEN(-100,100)

A screenshot of the result from the formula =RANDBETWEEN(-100, 100) showing random integers between -100 and 100 in Excel


توليد أرقام عشوائية بعدد منازل عشرية محدد بين رقمين

لإنشاء أرقام عشوائية بعدد منازل عشرية محدد، يجب تعديل صيغة RANDBETWEEN كما يلي:

  • أرقام عشوائية بمنزل عشرية واحدة: =RANDBETWEEN(bottom*10, top*10)/10
  • أرقام عشوائية بمنزلتين عشريتين: =RANDBETWEEN(bottom*100, top*100)/100
  • أرقام عشوائية بثلاث منازل عشرية: =RANDBETWEEN(bottom*1000, top*1000)/1000
  • ...

هنا، أريد الحصول على قائمة من الأرقام العشوائية بين10 و50 بمنزلتين عشريتين، يرجى تطبيق الصيغة أدناه، ثم سحب ونسخ الصيغة إلى الخلايا الأخرى حسب الحاجة، كما هو موضح في لقطة الشاشة:

=RANDBETWEEN(10*100,50*100)/100

A screenshot of the result from the formula =RANDBETWEEN(10*100, 50*100)/100 showing random numbers with two decimal places between 10 and 50 in Excel


 دالة معرفة من قبل المستخدم لتوليد أرقام عشوائية بين قيمتين

الدالة المعرفة من قبل المستخدم التالية يمكنها أيضاً مساعدتك في توليد أعداد صحيحة عشوائية أو أرقام بعدد منازل عشرية محدد في النطاق. يرجى اتباع الخطوات التالية:

1. اضغط باستمرار على مفاتيح ALT + F11 لفتح نافذة Microsoft Visual Basic for Applications.

2. انقر على إدراج > وحدة نمطية، ثم الصق الكود التالي في نافذة الوحدة.

كود VBA: توليد أرقام عشوائية

Public Function RandomNumbers(Num1 As Long, Num2 As Long, Optional Decimals As Integer)
'Updateby Extendoffice
Application.Volatile
Randomize
If IsMissing(Decimals) Or Decimals = 0 Then
    RandomNumbers = Int((Num2 + 1 - Num1) * Rnd + Num1)
Else
    RandomNumbers = Round((Num2 - Num1) * Rnd + Num1, Decimals)
End If
End Function

3. بعد ذلك، أغلق الكود وارجع إلى أدوات الورقة العمل، وفي خلية فارغة، اكتب هذه الصيغة =RandomNumbers(X,Y,Z).

ملاحظة: في الصيغة أعلاه، X تشير إلى الحد الأدنى للأرقام، Y تشير إلى الحد الأعلى للأرقام، وZ هو عدد المنازل العشرية للأرقام العشوائية، يرجى تغييرها حسب حاجتك.

1.) لتوليد أعداد صحيحة عشوائية بين50 و200، يرجى استخدام هذه الصيغة:

=RandomNumbers(50,200,0)

2.) لإدراج أرقام عشوائية بين50 و200 بمنزلتين عشريتين، يرجى تطبيق الصيغة أدناه:

=RandomNumbers(50,200,2)

4. أخيراً، اسحب ونسخ الصيغة إلى الخلايا الأخرى حسب رغبتك، وستحصل على النتائج كما هو موضح في لقطات الشاشة أدناه:

A screenshot of the result from the custom VBA formula =RandomNumbers(50,200,0) showing random integers between 50 and 200 in Excel A screenshot of the result from the custom VBA formula =RandomNumbers(50,200,2) showing random numbers with two decimal places between 50 and 200 in Excel

 ميزة عملية لتوليد أرقام عشوائية بين رقمين

إذا كنت تجد صعوبة في تذكر وإدخال الصيغ، أوصي هنا بميزة مفيدة – إدراج بيانات عشوائية من Kutools لـ Excel. باستخدام هذه الميزة، يمكنك توليد أعداد صحيحة أو أرقام عشرية عشوائية دون الحاجة لأي صيغ.

Kutools لـ Excel - مزود بأكثر من 300 أدوات أساسية لبرنامج Excel. استمتع بميزات ذكاء اصطناعي مجانية بشكل دائم! قم بالتنزيل الآن!

1. حدد النطاق الذي تريد توليد الأرقام العشوائية فيه، ثم انقر Kutools > إدراج > إدراج بيانات عشوائية، كما هو موضح في لقطة الشاشة:

A screenshot of the Insert Random Data option in Kutools under the Insert tab on the Ribbon

2. في مربع حوار إدراج بيانات عشوائية:

1.) توليد أعداد صحيحة عشوائية:

ضمن علامة التبويب عدد صحيح، في مربعي من وإلى، أدخل نطاق الأرقام الذي ستولد بينه الأعداد الصحيحة العشوائية، ثم انقر موافق أو تطبيق للحصول على الأرقام كما هو موضح في لقطة الشاشة:

A screenshot of the Insert Random Data dialog box generating random whole numbers under the Integer tab

2.) توليد أرقام عشوائية بعدد منازل عشرية محدد:

ضمن علامة التبويب عشري، حدد رقمين في مربعي من وإلى لتوليد أرقام عشرية عشوائية بينهما. ثم اختر عدد المنازل العشرية في مربع النص الخاص بعدد المنازل العشرية العشرية وانقر على موافق أو تطبيق لتوليد الأرقام العشرية. انظر لقطة الشاشة:

A screenshot of the Insert Random Data dialog box generating random decimal numbers under the Decimal tab

نصيحة: لتوليد أرقام عشرية عشوائية بدون تكرار، يرجى تحديد خيار توليد قيم فريدة.


1.2 توليد أرقام عشوائية بدون تكرار (أرقام عشوائية فريدة)

عند استخدام الصيغ أو الكود لتوليد أرقام عشوائية، قد تظهر بعض الأرقام المكررة أيضاً. إذا كنت ترغب في إنشاء قائمة أرقام عشوائية بدون تكرار، سيعرض لك هذا القسم بعض الطرق لتحقيق ذلك.

 توليد أرقام عشوائية بدون تكرار باستخدام صيغة مصفوفة

على سبيل المثال، أريد توليد أرقام عشوائية بين100 و200 بدون تكرار، إليك صيغة مصفوفة معقدة يمكن أن تساعدك، يرجى اتباع الخطوات التالية:

1. حدد القيم الدنيا والقصوى في خليتين. في هذا المثال، سأدخل100 و200 في الخليتين B2 وB3، كما هو موضح في لقطة الشاشة:

A screenshot showing the input of lower and upper limits in cells B2 and B3 for generating random numbers in Excel

2. ثم، انسخ الصيغة التالية في خلية فارغة، مثل D3 (لا تضع الصيغة في الصف الأول)، ثم اضغط على مفاتيح Ctrl+ Shift + Enter معاً للحصول على الرقم الأول، كما هو موضح في لقطة الشاشة:

=IFERROR(LARGE(ROW(INDIRECT($B$1&":"&$B$2))*NOT(COUNTIF($D$2:D2,ROW(INDIRECT($B$1&":"&$B$2)))),RANDBETWEEN(1,$B$2-$B$1-ROW(A1)+2)),"")

ملاحظة: في الصيغة أعلاه، B1 هي القيمة الدنيا، وB2 هي القيمة العليا التي تريد توليد الأرقام العشوائية بينها. D2 هي الخلية فوق الصيغة.

A screenshot of the initial result of the array formula for generating unique random numbers in Excel

3. بعد ذلك، اسحب ونسخ هذه الصيغة إلى الخلايا الأخرى حسب رغبتك لتوليد الأرقام العشوائية بين100 و200:

A screenshot showing a list of unique random numbers generated between 100 and 200 using an array formula in Excel


 توليد أرقام عشوائية بدون تكرار باستخدام كود VBA

إذا كانت الصيغة أعلاه صعبة الفهم، يمكنك استخدام كود VBA أدناه، يرجى اتباع الخطوات التالية:

1. اضغط باستمرار على مفاتيح ALT + F11 لفتح نافذة Microsoft Visual Basic for Applications.

2. انقر على إدراج > وحدة نمطية، ثم الصق الكود التالي في نافذة الوحدة.

كود VBA: توليد أرقام عشوائية بدون تكرار

Sub Range_RandomNumber()
'Updateby Extendoffice
Dim xStrRange As String
Dim xRg, xCell, xRg1 As Range
Dim xArs As Areas
Dim xNum_Lowerbound As Integer
Dim xNum_Upperbound  As Integer
Dim xI, xJ, xS, xR As Integer
xStrRange = "A1:B20"
xNum_Lowerbound = 100
xNum_Upperbound = 200
Set xRg = Range(xStrRange)
Set xArs = xRg.Areas
xRgCount = 0
For xI = 1 To xArs.Count
    Set xCell = xArs.Item(xI)
    xRgCount = xCell.Count + xRgCount
Next xI
xS = (xNum_Upperbound - xNum_Lowerbound + 1)
If xRgCount > xS Then
    MsgBox ("Number of cells greater than the number of unique random numbers!")
    Exit Sub
End If
    xRg.Clear
For xI = 1 To xArs.Count
    Set xCell = xArs.Item(xI)
    For xJ = 1 To xCell.Count
        Set xRg1 = xCell.Item(xJ)
        xR = Int(xS * Rnd + xNum_Lowerbound)
        Do While Application.WorksheetFunction.CountIf(xRg, xR) >= 1
            xR = Int(xS * Rnd + xNum_Lowerbound)
        Loop
        xRg1.Value = xR
    Next
Next
End Sub

ملاحظة: في الكود أعلاه، xStrRange = "A1:B20" تعني أنك تريد توليد أرقام عشوائية في النطاق A1:B20. xNum_Lowerbound = 100 وxNum_Upperbound = 200 تعني أن القيم الدنيا والعليا لتوليد الأرقام العشوائية بين100 و200. يرجى تعديلها حسب حاجتك.

3. ثم اضغط على مفتاح F5 لتشغيل الكود، وسيتم إدراج الأرقام العشوائية الفريدة في النطاق المحدد.


 توليد أرقام عشوائية بدون تكرار باستخدام ميزة قوية

لإنشاء عدة أرقام عشوائية فريدة بسرعة، تدعم ميزة إدراج بيانات عشوائية في Kutools لـ Excel خياراً ذكياً – توليد قيم فريدة. بمجرد تحديد هذا الخيار، ستتمكن من تنفيذ هذه المهمة بسهولة.

Kutools لـ Excel يقدم أكثر من 300 ميزة متقدمة لتبسيط المهام المعقدة، مما يعزز الإبداع والكفاءة. بالتكامل مع قدرات الذكاء الاصطناعي، يقوم Kutools بأتمتة المهام بدقة، مما يجعل إدارة البيانات أمرًا سهلاً للغاية. معلومات تفصيلية عن Kutools لـ Excel... نسخة تجريبية مجانية...

1. حدد النطاق الذي تريد توليد الأرقام العشوائية فيه.

2. ثم انقر Kutools > إدراج > إدراج بيانات عشوائية. في مربع الحوار المنبثق، يرجى تنفيذ العمليات التالية:

  • ضمن علامة التبويب عدد صحيح، في مربعي من وإلى، أدخل نطاق الأرقام الذي ستولد بينه الأرقام العشوائية؛
  • حدد خيار توليد قيم فريدة؛
  • ثم انقر على موافق أو تطبيق للحصول على الأرقام العشوائية الفريدة كما هو موضح في لقطة الشاشة أدناه.

A screenshot showing the Insert Random Data dialog box with the Unique values option checked


1.3 توليد أرقام زوجية أو فردية عشوائية في Excel

إذا كنت ترغب في توليد بعض الأرقام الزوجية أو الفردية العشوائية في نطاق من الخلايا، فقط ضع دالة RANDBETWEEN داخل دالة EVEN أو ODD، والصيغ العامة هي:

الصيغة الوصف
=EVEN(RANDBETWEEN(bottom,top)) توليد أرقام زوجية عشوائية بين رقمين محددين.
=ODD(RANDBETWEEN(bottom,top)) توليد أرقام فردية عشوائية بين رقمين محددين.

على سبيل المثال، لتوليد أرقام زوجية أو فردية عشوائية من10 إلى100، يرجى تطبيق الصيغ التالية:

=EVEN(RANDBETWEEN(10,100))             (توليد أرقام زوجية عشوائية)
=ODD(RANDBETWEEN(10,100))             
 (توليد أرقام فردية عشوائية)

ثم، انسخ الصيغة إلى الخلايا الأخرى التي تريدها عن طريق سحب مقبض التعبئة، وستحصل على النتائج كما هو موضح في لقطات الشاشة أدناه:

A screenshot showing random even numbers generated between 10 and 100 in Excel A screenshot showing random odd numbers generated between 10 and 100 in Excel

1.4 توليد أرقام عشوائية مجموعها يساوي قيمة محددة

في بعض الأحيان، قد تحتاج إلى إنشاء مجموعة من الأرقام العشوائية يكون مجموعها يساوي قيمة محددة مسبقاً. على سبيل المثال، أريد توليد5 أو n أرقام عشوائية بين10 و50 يكون مجموعها100 كما هو موضح في لقطة الشاشة أدناه. لحل هذه المسألة في Excel، سأعرض لك طريقتين.

A screenshot showing the random numbers generated between 10 and 50 totaling 100 in Excel

 توليد أرقام عشوائية مجموعها يساوي قيمة محددة باستخدام الصيغ

هنا، يمكن أن تساعدك الصيغ التالية. يرجى اتباع التعليمات خطوة بخطوة لأنها معقدة قليلاً:

1. أولاً، يجب عليك إنشاء البيانات المطلوبة: القيمة الإجمالية المحددة، الرقم الأول، الرقم الأخير وعدد الأرقام العشوائية التي تريد توليدها كما هو موضح في لقطة الشاشة أدناه:

A screenshot showing the setup for generating random numbers that add up to a specific value in Excel, including bottom and top values and total

2. ثم، يرجى نسخ الصيغة أدناه في خلية فارغة حيث تريد توليد الأرقام. في هذا المثال، سأضع الصيغة في الخلية A4، واضغط على مفتاح Enter للحصول على الرقم العشوائي الأول، كما هو موضح في لقطة الشاشة:

=RANDBETWEEN(MAX($B$2,$A$2-(($D$2-ROWS($A$4:$A4))*$C$2)),MIN($C$2,$A$2-(($D$2-ROWS($A$4:$A4))*$B$2)))

ملاحظة: في الصيغة أعلاه: A2 هي القيمة الإجمالية المحددة؛ B2 وC2 هما القيمتان الدنيا والعليا التي تريد توليد الأرقام العشوائية بينهما؛ D2 يشير إلى عدد الأرقام العشوائية التي تريد توليدها؛ A4 هي الخلية التي تدخل فيها هذه الصيغة.

A screenshot showing the result of the first random number generated using a formula in Excel

3. تابع نسخ الصيغة التالية في الخلية A5، واضغط على مفتاح Enter للحصول على الرقم العشوائي الثاني، كما هو موضح في لقطة الشاشة:

=IF(ROW()=$D$2+3,$A$2-SUM($A$4:$A4),IF(ROW()>$D$2+3,"",RANDBETWEEN(MAX($B$2,$A$2-(SUM($A$4:$A4)+($D$2-ROWS($A$4:$A5))*$C$2)),MIN($C$2,$A$2-(SUM($A$4:$A4)+($D$2-ROWS($A$4:$A5))*$B$2)))))

ملاحظة: في الصيغة أعلاه: A2 هي القيمة الإجمالية المحددة؛ B2 و C2 هما القيمتان الدنيا والعليا التي تريد توليد الأرقام العشوائية بينهما؛ D2 يشير إلى عدد الأرقام العشوائية التي تريد توليدها؛ A4 هي الخلية التي تضع فيها الصيغة الأولى؛ وA5 هي الخلية التي تضع فيها الصيغة الثانية.

A screenshot showing the second random number generated using a formula and the updated result in Excel

4. ثم، حدد الرقم الثاني الذي تم توليده، واسحب لأسفل لنسخ هذه الصيغة إلى ثلاث خلايا أخرى. الآن، ستحصل على5 أرقام عشوائية كما هو موضح في لقطة الشاشة أدناه:

A screenshot showing the final set of random numbers generated that add up to a specific total in Excel

5. لاختبار النتيجة، يمكنك جمع هذه الأرقام للتحقق مما إذا كان المجموع يساوي100. اضغط على F9 لتحديث الأرقام العشوائية ديناميكياً، وسيظل مجموعها دائماً100.

A screenshot showing the sum of randomly generated numbers in Excel to verify their total


 توليد مجموعات أرقام عشوائية مجموعها يساوي قيمة محددة باستخدام ميزة مذهلة

يمكننا استخدام الصيغ أعلاه لتوليد أرقام عشوائية تلبي احتياجاتنا. ومع ذلك، إذا كنت ترغب في عرض جميع التركيبات الممكنة للأرقام التي حددتها بمجموع محدد، أوصي هنا بأداة سهلة – Kutools لـ Excel. من خلال ميزة إنشاء أرقام، يمكنك الحصول على جميع مجموعات الأرقام العشوائية التي يكون مجموعها مساوياً للقيمة المحددة.

Kutools لـ Excel يقدم أكثر من 300 ميزة متقدمة لتبسيط المهام المعقدة، مما يعزز الإبداع والكفاءة. بالتكامل مع قدرات الذكاء الاصطناعي، يقوم Kutools بأتمتة المهام بدقة، مما يجعل إدارة البيانات أمرًا سهلاً للغاية. معلومات تفصيلية عن Kutools لـ Excel... نسخة تجريبية مجانية...

1. أولاً، يجب عليك إدراج الأرقام التي حددتها. هنا، قمنا بإدراج جميع الأرقام بين10 و50 كما هو موضح في لقطة الشاشة أدناه:

A screenshot showing a list of numbers between 10 and 50 to find combinations that add up to a specific value in Excel

2. ثم، انقر Kutools > نص > إنشاء أرقام، كما هو موضح في لقطة الشاشة:

A screenshot of the Make Up A Number option under the Content group in Kutools tab in Excel

3. في مربع الحوار المنبثق إنشاء رقم، يرجى تنفيذ العمليات التالية:

  • في مربع نطاق المصدر، حدد قائمة الأرقام للبحث عن الأرقام التي يكون مجموعها100؛
  • ضمن الخيارات، أدخل القيمة الإجمالية في مربع نص المجموع. هنا أدخلنا100 في مربع النص؛
  • حدد خيار حفظ في ورقة جديدة إذا كنت ترغب في عرض النتائج في ورقة عمل جديدة؛
  • انقر على زر موافق. انظر لقطة الشاشة:

A screenshot of the Make Up A Number dialog box with settings to generate number combinations summing to 100

4. بعد المعالجة، سترى جميع مجموعات الأرقام العشوائية التي يكون مجموعها100، والمكونة من أرقام بين10 و50، مدرجة كما يلي.

A screenshot showing the results of all random number combinations summing to 100 generated using Kutools

نصيحة: يمكنك اختيارياً تحديد عدد التركيبات وعدد الأرقام العشوائية في كل تركيبة. على سبيل المثال، لتوليد10 تركيبات وكل تركيبة تحتوي على5 أرقام عشوائية، يمكنك ضبط الإعدادات في مربع الحوار ضمن الإعدادات المتقدمة كما يلي:

A screenshot of the Make Up A Number dialog box with advanced settings to specify the number of combinations and numbers per combination in Excel

وستحصل على النتائج كما يلي:

A screenshot showing results of random number combinations generated based on advanced settings


1.5 توليد أحرف وسلاسل نصية عشوائية باستخدام الصيغ

سيعرض هذا القسم كيفية توليد أحرف عشوائية في Excel، مثل الأحرف الكبيرة من A إلى Z، أو الأحرف الصغيرة من a إلى z أو بعض الرموز الخاصة (! " # $ % & ' ( ) * + , - . /).

 توليد أحرف وسلاسل نصية عشوائية باستخدام الصيغ

في Excel، يمكنك دمج دالتي CHAR وRANDBETWEEN مع بعض رموز الأحرف ANSI لإنشاء صيغ كما يلي:

الصيغة الوصف
=CHAR(RANDBETWEEN(65,90)) توليد أحرف كبيرة عشوائية بين A وZ.
=CHAR(RANDBETWEEN(97,122)) توليد أحرف صغيرة عشوائية بين a وz.
=CHAR(RANDBETWEEN(33,47)) توليد رموز خاصة عشوائية، مثل: ! " # $ % & ' ( ) * + , - . /

يرجى تطبيق أي من الصيغ أعلاه حسب حاجتك، ونسخ الصيغة إلى عدد الخلايا الذي تريده، وستحصل على النتائج كما هو موضح في لقطات الشاشة أدناه:

=CHAR(RANDBETWEEN(65,90)) =CHAR(RANDBETWEEN(97,122)) =CHAR(RANDBETWEEN(33,47))
A screenshot showing random uppercase letters generated using the formula =CHAR(RANDBETWEEN(65,90)) in Excel A screenshot showing random lowercase letters generated using the formula =CHAR(RANDBETWEEN(97,122)) in Excel A screenshot showing random special characters generated using the formula =CHAR(RANDBETWEEN(33,47)) in Excel

نصيحة: إذا كنت ترغب في توليد سلاسل نصية عشوائية بعدة أحرف، فقط استخدم الرمز & لربط الأحرف كما تريد.

1.) لتوليد سلاسل عشوائية بأربعة أحرف كبيرة، يرجى تطبيق الصيغة أدناه:

=CHAR(RANDBETWEEN(65,90))& CHAR(RANDBETWEEN(65,90)) & CHAR(RANDBETWEEN(65,90)) & CHAR(RANDBETWEEN(65,90))

A screenshot showing random strings with four uppercase letters generated using a combined formula in Excel

2.) لتوليد سلاسل عشوائية بأربعة أحرف صغيرة، يرجى تطبيق الصيغة أدناه:

=CHAR(RANDBETWEEN(97,122))& CHAR(RANDBETWEEN(97,122)) & CHAR(RANDBETWEEN(97,122)) & CHAR(RANDBETWEEN(97,122))

3.) لتوليد سلاسل عشوائية بحرفين كبيرين في البداية وحرفين صغيرين في النهاية، يرجى استخدام الصيغة التالية:

=CHAR(RANDBETWEEN(65,90))& CHAR(RANDBETWEEN(65,90)) & CHAR(RANDBETWEEN(97,122)) & CHAR(RANDBETWEEN(97,122))

يمكنك استخدام الصيغ البسيطة والرمز & لإنشاء تركيبات متنوعة تلبي احتياجاتك.


 توليد أحرف وسلاسل نصية عشوائية باستخدام ميزة عملية

إذا كان لديك Kutools لـ Excel مثبتاً، يمكنك توليد أحرف وسلاسل نصية عشوائية بسرعة وسهولة دون الحاجة لتذكر أي صيغ.

Kutools لـ Excel يقدم أكثر من 300 ميزة متقدمة لتبسيط المهام المعقدة، مما يعزز الإبداع والكفاءة. بالتكامل مع قدرات الذكاء الاصطناعي، يقوم Kutools بأتمتة المهام بدقة، مما يجعل إدارة البيانات أمرًا سهلاً للغاية. معلومات تفصيلية عن Kutools لـ Excel... نسخة تجريبية مجانية...

1. حدد نطاق الخلايا لإدراج الأحرف أو السلاسل النصية.

2. ثم انقر Kutools > إدراج > إدراج بيانات عشوائية، في مربع الحوار المنبثق، يرجى تنفيذ العمليات التالية:

  • انقر على علامة التبويب سلسلة؛
  • حدد a-z أو A-Z أو كليهما حسب ما تريد إدراجه؛
  • ثم، حدد طول السلسلة النصية التي تريدها في مربع نص الطول؛
  • أخيراً، انقر موافق أو تطبيق لإدراج السلاسل كما هو موضح في لقطة الشاشة أدناه.

A screenshot showing the Insert Random Data dialog box for generating random letters and strings in Excel


1.6 توليد كلمات مرور عشوائية بأحرف وأرقام في Excel

عند إنشاء كلمة مرور، يجب أن تتكون من8 أحرف على الأقل وتحتوي على مزيج من الأحرف الكبيرة والصغيرة والأرقام وبعض الرموز الخاصة. في هذا القسم، سأعرض بعض الحيل لتوليد كلمات مرور عشوائية في Excel.

 توليد كلمات مرور عشوائية بأحرف وأرقام باستخدام الصيغ

على سبيل المثال، هنا سأقوم بإنشاء كلمات مرور عشوائية بطول8 أحرف. فقط قم بدمج الصيغ الثلاثة المقدمة في قسم توليد أحرف وسلاسل نصية عشوائية باستخدام الصيغ.

يرجى نسخ الصيغة أدناه في خلية فارغة:

=CHAR(RANDBETWEEN(65,90))&CHAR(RANDBETWEEN(97,122))&CHAR(RANDBETWEEN(97,122))&CHAR(RANDBETWEEN(65,90))&RANDBETWEEN(100,999)&CHAR(RANDBETWEEN(33,47))

ملاحظة: في الصيغة أعلاه، تولد CHAR وRANDBETWEEN الأولى حرفاً كبيراً عشوائياً، والثانية والثالثة تولدان حرفين صغيرين، والتعبير الرابع يولد حرفاً كبيراً، والخامس يولد رقماً مكوناً من3 أرقام بين100 و999، والأخير يولد رمزاً خاصاً. يمكنك تعديل الترتيب حسب حاجتك.

A screenshot showing random passwords generated using the formula combining CHAR and RANDBETWEEN functions in Excel


 توليد كلمات مرور عشوائية بأحرف وأرقام باستخدام دالة معرفة من قبل المستخدم

لإدراج كلمات مرور عشوائية في Excel، يمكن أن تساعدك الدالة المعرفة من قبل المستخدم التالية، يرجى اتباع الخطوات التالية:

1. اضغط باستمرار على مفاتيح ALT + F11، وسيفتح نافذة Microsoft Visual Basic for Applications.

2. انقر على إدراج > وحدة نمطية، ثم الصق الماكرو التالي في نافذة الوحدة.

كود VBA: توليد كلمات مرور عشوائية في Excel

Function RandomizeF(Num1 As Integer, Num2 As Integer)
'Updateby Extendoffice
Dim Rand As String
Application.Volatile
getLen = Int((Num2 + 1 - Num1) * Rnd + Num1)
Do
    i = i + 1
    Randomize
    Rand = Rand & Chr(Int((85) * Rnd + 38))
Loop Until i = getLen
RandomizeF = Rand
End Function

3. ثم أغلق الكود وارجع إلى أدوات الورقة العمل. في خلية، أدخل هذه الصيغة =RandomizeF(8,10) لتوليد سلسلة نصية عشوائية بطول أدنى8 وأقصى10 أحرف.

4. ثم اسحب ونسخ الصيغة إلى الخلايا الأخرى حسب رغبتك. سيتم إنشاء سلاسل عشوائية بأحرف وأرقام ورموز خاصة بطول بين8 و10 كما هو موضح في لقطة الشاشة:

A screenshot showing random passwords generated using the VBA function RandomizeF


 توليد كلمات مرور عشوائية بأحرف وأرقام باستخدام ميزة سهلة

هل هناك طريقة سريعة وسهلة لتوليد عدة كلمات مرور عشوائية في Excel؟ يوفر Kutools لـ Excel ميزة ممتازة - إدراج بيانات عشوائية. باستخدام هذه الميزة، يمكنك إدراج كلمات مرور عشوائية بعدة نقرات فقط.

Kutools لـ Excel يقدم أكثر من 300 ميزة متقدمة لتبسيط المهام المعقدة، مما يعزز الإبداع والكفاءة. بالتكامل مع قدرات الذكاء الاصطناعي، يقوم Kutools بأتمتة المهام بدقة، مما يجعل إدارة البيانات أمرًا سهلاً للغاية. معلومات تفصيلية عن Kutools لـ Excel... نسخة تجريبية مجانية...

1. حدد نطاق الخلايا لإدراج كلمات المرور.

2. ثم انقر Kutools > إدراج > إدراج بيانات عشوائية. في مربع الحوار المنبثق، يرجى تنفيذ العمليات التالية:

  • انقر على علامة التبويب سلسلة؛
  • حدد نوع الأحرف حسب حاجتك؛
  • ثم، حدد طول كلمة المرور التي تريدها في مربع نص الطول؛
  • أخيراً، انقر موافق أو تطبيق لتوليد كلمات المرور كما هو موضح في لقطة الشاشة أدناه.

A screenshot showing random passwords generated using the Insert Random Data feature of Kutools


1.7 توليد نصوص محددة عشوائية في Excel

هل سبق لك أن حاولت عرض أو إدراج بعض القيم النصية المحددة بشكل عشوائي في Excel؟ على سبيل المثال، لإدراج بعض النصوص المعطاة (item1, item2, item3, item4, item5) بشكل عشوائي في قائمة من الخلايا، قد تساعدك الحيلتان التاليتان في حل هذه المهمة.

 توليد نصوص محددة عشوائية باستخدام صيغة

في Excel، يمكنك إنشاء صيغة تعتمد على دالتي CHOOSE وRANDBETWEEN لعرض النصوص المحددة بشكل عشوائي، والصيغة العامة هي:

=CHOOSE(RANDBETWEEN(1,n),"Value_1","Value_2","Value_3",…"Value_n")
  • Value_1, Value_2, Value_3, Value_n : تمثل القيم النصية التي ترغب في عرضها عشوائياً؛
  • n : عدد القيم النصية التي تريد استخدامها.

يرجى تطبيق الصيغة أدناه في خلية فارغة، ثم اسحب مقبض التعبئة لأسفل لملء الخلايا التي ترغب في عرض القيم المحددة فيها بشكل عشوائي، كما هو موضح في لقطة الشاشة:

=CHOOSE(RANDBETWEEN(1,5),"Chemistry","Physics","Geography","Biology","Economics")

A screenshot showing random specific texts generated using the CHOOSE and RANDBETWEEN functions in Excel


 توليد نصوص محددة عشوائية بطريقة سريعة

إذا كان لديك Kutools لـ Excel، يمكن لميزة إدراج بيانات عشوائية أيضاً مساعدتك في إدراج قيم نصية مخصصة بشكل عشوائي في نطاق من الخلايا.

Kutools لـ Excel يقدم أكثر من 300 ميزة متقدمة لتبسيط المهام المعقدة، مما يعزز الإبداع والكفاءة. بالتكامل مع قدرات الذكاء الاصطناعي، يقوم Kutools بأتمتة المهام بدقة، مما يجعل إدارة البيانات أمرًا سهلاً للغاية. معلومات تفصيلية عن Kutools لـ Excel... نسخة تجريبية مجانية...

1. حدد نطاق الخلايا لإدراج النصوص المحددة.

2. ثم انقر Kutools > إدراج > إدراج بيانات عشوائية، في مربع الحوار المنبثق، يرجى تنفيذ العمليات التالية:

  • انقر على علامة التبويب قائمة مخصصة؛
  • ثم، انقر Add button زر لفتح Kutools for Excel مربع حوار Kutools for Excel، أدخل أو حدد القيم النصية المخصصة التي ترغب في عرضها بشكل عشوائي. (يجب فصل الإدخالات بفاصلة عند إدخالها يدوياً.)

A screenshot of the Kutools for Excel prompt box for entering custom text values in the Insert Random Data dialog

3. ثم، انقر موافق للعودة إلى مربع حوار إدراج بيانات عشوائية، وستظهر قائمة النصوص المخصصة الخاصة بك في مربع القائمة. الآن، حدد عناصر القائمة الجديدة، وانقر موافق أو تطبيق لإدراج القيم في الخلايا المحددة بشكل عشوائي.

A screenshot showing custom random texts inserted into a range using the Kutools Insert Random Data feature in Excel

نصيحة: لعرض النصوص المحددة بشكل عشوائي بدون تكرار، يرجى تحديد خيار توليد قيم فريدة.


1.8 توليد أو اختيار قيم عشوائية من قائمة في Excel

افترض أن لديك قائمة طويلة من الأسماء، وتريد اختيار بعض الأسماء عشوائياً من تلك القائمة كأسماء محظوظة أو كعينات بحث كما هو موضح في لقطة الشاشة أدناه. كيف يمكنك حل هذه المشكلة في Excel؟

A screenshot showing a long list of names to be randomly selected in Excel

 توليد قيم عشوائية من قائمة باستخدام دوال INDEX وRANDBETWEEN وROWS

في Excel، لا توجد طريقة مباشرة لاستخراج قيم عشوائية من قائمة، ولكن يمكنك إنشاء صيغة تعتمد على دوال INDEX وRANDBETWEEN وROWS لاستخراج بعض القيم العشوائية.

1. يرجى نسخ الصيغة أدناه في خلية فارغة حيث تريد وضع القيمة المستخرجة:

=INDEX($A$2:$A$12,RANDBETWEEN(1,ROWS($A$2:$A$12)),1)

ملاحظة: في الصيغة أعلاه، A2:A12 هي قائمة القيم التي ترغب في اختيار القيم العشوائية منها.

2. ثم، اسحب مقبض التعبئة لأسفل إلى عدة خلايا حيث ترغب في عرض القيم العشوائية، وستحصل على النتيجة كما هو موضح في لقطة الشاشة التالية:

A screenshot showing random names extracted from a list using the INDEX, RANDBETWEEN, and ROWS functions in Excel


 توليد قيم عشوائية من قائمة بدون تكرار باستخدام دوال INDEX وRANK.EQ

عند استخدام الصيغة أعلاه، قد تظهر بعض القيم المكررة. لتخطي القيم المكررة، يجب عليك أولاً إنشاء عمود مساعد، ثم تطبيق صيغة تعتمد على دالتي INDEX وRANK.EQ. يرجى اتباع الخطوات التالية:

1. أدخل الصيغة أدناه في خلية فارغة للحصول على قائمة من الأرقام العشوائية، كما هو موضح في لقطة الشاشة:

=RAND()

A screenshot showing a list of random numbers generated as a helper column for unique selection in Excel

2. ثم، انسخ الصيغة أدناه في خلية من عمود آخر حيث ترغب في استخراج بعض القيم العشوائية، ثم اسحب ونسخ هذه الصيغة إلى الخلايا أدناه لعرض بعض القيم العشوائية غير المكررة، كما هو موضح في لقطة الشاشة:

=INDEX($A$2:$A$12,RANK.EQ($B2,$B$2:$B$12))

ملاحظة: في الصيغة أعلاه، A2:A12 هي قائمة القيم التي ترغب في توليد بعض القيم العشوائية منها، B2 هي أول خلية من العمود المساعد، B2:B12 هي خلايا الصيغة المساعدة التي أنشأتها في الخطوة1.

A screenshot showing random unique names selected using the INDEX and RANK.EQ functions in Excel


 تحديد خلايا أو صفوف أو أعمدة عشوائية من النطاق باستخدام ميزة رائعة

هنا أوصي بميزة مفيدة – فرز أو اختيار أو عشوائي من Kutools لـ Excel. باستخدام هذه الميزة، يمكنك تحديد بعض الخلايا أو الصفوف أو الأعمدة العشوائية حسب حاجتك.

Kutools لـ Excel يقدم أكثر من 300 ميزة متقدمة لتبسيط المهام المعقدة، مما يعزز الإبداع والكفاءة. بالتكامل مع قدرات الذكاء الاصطناعي، يقوم Kutools بأتمتة المهام بدقة، مما يجعل إدارة البيانات أمرًا سهلاً للغاية. معلومات تفصيلية عن Kutools لـ Excel... نسخة تجريبية مجانية...

1. حدد قائمة الخلايا التي ترغب في اختيار بعض القيم العشوائية منها.

2. ثم، انقر Kutools > النطاق > فرز أو اختيار أو عشوائي، كما هو موضح في لقطة الشاشة:

A screenshot showing the Sort/Select Range Randomly feature in Kutools tab in Excel

3. في مربع حوار فرز أو اختيار أو عشوائي، يرجى تنفيذ العمليات التالية:

  • انقر على علامة التبويب تحديد؛
  • ثم، أدخل عدد الخلايا التي ترغب في تحديدها عشوائياً في مربع عدد الخلايا المراد تحديدها؛
  • في قسم نوع التحديد، اختر العملية التي تريدها. في هذا المثال، سأختار خيار خلية.
  • ثم، انقر على موافق أو تطبيق، وسيتم تحديد خمس خلايا عشوائياً دفعة واحدة، كما هو موضح في لقطات الشاشة:

A screenshot showing the result of randomly selected cells using the Kutools Sort/Select Range Randomly feature

4. بعد تحديد الخلايا، يمكنك نسخها ولصقها في خلايا أخرى حسب حاجتك.


1.9 توزيع البيانات على مجموعات بشكل عشوائي في Excel

افترض أن لديك قائمة من الأسماء، وتريد الآن تقسيم الأسماء إلى ثلاث مجموعات (المجموعة A، المجموعة B، المجموعة C) بشكل عشوائي كما هو موضح في لقطة الشاشة أدناه. في هذا القسم، سأناقش بعض الصيغ لحل هذه المهمة في Excel.

A screenshot showing names divided into three groups randomly in Excel

 توزيع البيانات على مجموعة بشكل عشوائي باستخدام صيغة

لتوزيع الأشخاص عشوائياً على مجموعات محددة، يمكنك استخدام دالة CHOOSE مع دالة RANDBETWEEN.

1. يرجى نسخ أو إدخال الصيغة التالية في خلية حيث ترغب في توليد المجموعة:

=CHOOSE(RANDBETWEEN(1,3),"Group A","Group B","Group C")

ملاحظة: في الصيغة أعلاه، Group A وGroup B وGroup C تشير إلى أسماء المجموعات التي ترغب في توزيعها، والرقم3 يشير إلى عدد المجموعات التي ترغب في التوزيع عليها.

2. ثم، اسحب مقبض التعبئة لتطبيق هذه الصيغة على الخلايا الأخرى، وسيتم تقسيم الأسماء إلى ثلاث مجموعات كما هو موضح في لقطة الشاشة أدناه:

A screenshot showing random group assignments using CHOOSE and RANDBETWEEN functions in Excel


 توزيع البيانات على مجموعات بعدد متساوٍ بشكل عشوائي باستخدام صيغة

إذا كنت ترغب في أن تحتوي جميع المجموعات على عدد متساوٍ من الأسماء، فلن تعمل الصيغة أعلاه بشكل صحيح. في هذه الحالة، يمكنك إنشاء عمود مساعد بقيم عشوائية باستخدام دالة RAND، ثم تطبيق صيغة تعتمد على دوال INDEX وRANK وROUNDUP.

على سبيل المثال، أدرجت أسماء المجموعات التي ترغب في التوزيع بناءً عليها في الخلايا F2:F4. لتوزيع الأشخاص على المجموعات (Group A، Group B، Group C)، وكل مجموعة تحتوي على4 مشاركين، يرجى اتباع الخطوات التالية:

1. أدخل هذه الصيغة: =RAND() في خلية فارغة للحصول على قائمة من الأرقام العشوائية، كما هو موضح في لقطة الشاشة:

A screenshot showing random numbers generated as a helper column for dividing data into equal groups in Excel

2. ثم، في العمود التالي، على سبيل المثال في الخلية D2، انسخ أو اكتب الصيغة أدناه:

=INDEX($F$2:$F$4, ROUNDUP(RANK(C2,$C$2:$C$13)/4,0))

ملاحظة: في الصيغة أعلاه، C2 هي أول خلية من العمود المساعد، C2:C13 هي خلايا الصيغة المساعدة التي أنشأتها في الخطوة1، الرقم4 يشير إلى عدد الأسماء التي ترغب في أن تحتوي عليها كل مجموعة، F2:F4 هو نطاق الخلايا الذي يحتوي على أسماء المجموعات التي ترغب في توزيع البيانات عليها.

3. اسحب مقبض التعبئة لأسفل لتوليد مجموعات عشوائية لقائمة البيانات، وسيتم تقسيم الأسماء إلى مجموعات متساوية، كما هو موضح في لقطة الشاشة:

A screenshot showing names evenly divided into three groups using formulas in Excel


1.10 توليد تواريخ عشوائية في Excel

لتوليد تواريخ عشوائية بين تاريخين محددين، سأعرض لك بعض الطرق لتحقيق ذلك.

 توليد تواريخ عشوائية بين تاريخين محددين باستخدام الصيغ

على سبيل المثال، أريد توليد بعض التواريخ بين2021-5-1 و2021-10-15 بشكل عشوائي. عادةً، في Excel، يمكنك إنجاز هذه المهمة باستخدام دمج دالتي RANDBETWEEN وDATE، يرجى اتباع الخطوات التالية:

1. حدد خلية حيث ترغب في إدراج تاريخ عشوائي، ثم أدخل الصيغة التالية:

=RANDBETWEEN(DATE(2021,5,1),DATE(2021,10,15))

ملاحظة: في هذه الصيغة،2021,5,1 هو تاريخ البدء، و2021,10,15 هو تاريخ الانتهاء، يمكنك استبدالهما حسب حاجتك.

2. ثم، اسحب ونسخ هذه الصيغة إلى الخلايا الأخرى التي ترغب في تعبئتها، وستظهر أرقام مكونة من خمسة أرقام في الخلايا كما هو موضح في لقطة الشاشة أدناه:

A screenshot showing five-digit numbers generated by the RANDBETWEEN function for random dates

3. بعد ذلك، يجب عليك تنسيق الأرقام إلى تنسيق التاريخ. يرجى تحديد خلايا الصيغة، ثم انقر بزر الماوس الأيمن واختر تنسيق الخلايا من القائمة السياقية.

4. في مربع حوار تنسيق الخلايا، انقر على علامة التبويب رقم، وحدد تاريخ من جزء الفئة، ثم اختر تنسيق التاريخ الذي تريده من قائمة النوع. انظر لقطة الشاشة:

A screenshot of the Format Cells dialog box used to format numbers as dates in Excel

5. انقر موافق لإغلاق مربع الحوار. الآن، تم تحويل الأرقام إلى تواريخ عادية. انظر لقطة الشاشة:

A screenshot showing random dates generated between 2021-5-1 and 2021-10-15 in Excel after formatting

نصيحة: إذا كنت ترغب في توليد أيام عمل عشوائية باستثناء عطلات نهاية الأسبوع، قد تساعدك الصيغة أدناه:

=WORKDAY(RANDBETWEEN(DATE(2021,5,1),DATE(2021,10,15))-1,1)

 توليد تواريخ عشوائية بين تاريخين محددين باستخدام ميزة مذهلة

توفر ميزة إدراج بيانات عشوائية في Kutools لـ Excel أيضاً خياراً لمساعدتك في توليد تواريخ عشوائية أو أيام عمل أو عطلات نهاية الأسبوع بين تاريخين محددين.

Kutools لـ Excel يقدم أكثر من 300 ميزة متقدمة لتبسيط المهام المعقدة، مما يعزز الإبداع والكفاءة. بالتكامل مع قدرات الذكاء الاصطناعي، يقوم Kutools بأتمتة المهام بدقة، مما يجعل إدارة البيانات أمرًا سهلاً للغاية. معلومات تفصيلية عن Kutools لـ Excel... نسخة تجريبية مجانية...

1. حدد نطاق الخلايا لإدراج التواريخ العشوائية.

2. ثم انقر Kutools > إدراج > إدراج بيانات عشوائية، في مربع الحوار المنبثق، يرجى تنفيذ العمليات التالية:

  • انقر على علامة التبويب تاريخ؛
  • ثم، حدد نطاق التاريخ. في هذا المثال، سأختار من5/1/2021 إلى10/15/2021.
  • ثم، اختر نوع التاريخ - يوم عمل، عطلة نهاية الأسبوع أو كليهما حسب حاجتك.
  • أخيراً، انقر موافق أو تطبيق لتوليد التواريخ عشوائياً كما هو موضح في لقطة الشاشة أدناه.

A screenshot showing random workdays generated between two dates using Kutools

نصيحة: لتوليد بعض التواريخ العشوائية الفريدة، يرجى تحديد خيار توليد قيم فريدة.


1.11 توليد أوقات عشوائية في Excel

بعد إدراج أرقام وسلاسل نصية وتواريخ عشوائية، سأتحدث في هذا القسم عن بعض الحيل لتوليد أوقات عشوائية في Excel.

 توليد أوقات عشوائية باستخدام الصيغ

توليد أوقات عشوائية باستخدام صيغة

لتوليد أوقات عشوائية في نطاق من الخلايا، يمكن لصيغة تعتمد على دالتي TEXT وRAND مساعدتك.

يرجى إدخال الصيغة أدناه في خلية فارغة، ثم اسحب ونسخ الصيغة إلى الخلايا الأخرى حيث ترغب في الحصول على الأوقات، كما هو موضح في لقطة الشاشة:

=TEXT(RAND(),"HH:MM:SS")

A screenshot showing the result of using the TEXT and RAND functions to generate random times in Excel


توليد أوقات عشوائية بين وقتين محددين باستخدام صيغة

إذا كنت بحاجة إلى إدراج بعض الأوقات عشوائياً بين وقتين محددين، مثل الأوقات من الساعة10 صباحاً إلى18 مساءً، يرجى تطبيق الصيغة أدناه:

=TEXT(RAND()*(18-10)/24+10/24,”HH:MM:SS”)

ملاحظة: في الصيغة أعلاه، الرقم18 هو وقت الانتهاء، و10 هو وقت البدء. يمكنك تغييرهما حسب متطلباتك.

ثم، اسحب ونسخ الصيغة إلى الخلايا الأخرى حيث ترغب في توليد الأوقات العشوائية بين النطاقين، كما هو موضح في لقطة الشاشة:

A screenshot showing random times generated between 10 AM and 6 PM using a formula


توليد أوقات عشوائية بفواصل زمنية محددة باستخدام صيغة

على سبيل المثال، إذا كنت ترغب في توليد أوقات عشوائية بفاصل زمني محدد في Excel، مثل إدراج أوقات عشوائية بفاصل15 دقيقة. للتعامل مع هذه المهمة، يمكنك استخدام دالتي RAND وFLOOR ضمن دالة TEXT.

انسخ أو أدخل الصيغة أدناه في خلية فارغة، ثم اسحب ونسخ هذه الصيغة إلى الخلايا التي ترغب في الحصول على الأوقات العشوائية فيها، كما هو موضح في لقطة الشاشة:

=TEXT(FLOOR(RAND(),"0:15"),"HH:MM:SS")

ملاحظة: في الصيغة، الرقم15 هو الفاصل الزمني، إذا كنت بحاجة إلى أوقات عشوائية بفاصل30 دقيقة، فقط استبدل15 بـ30.

A screenshot showing random times generated at 15-minute intervals using a formula in Excel


 توليد أوقات عشوائية بين وقتين محددين باستخدام ميزة عملية

إذا كان لديك Kutools لـ Excel، يمكن لميزة إدراج بيانات عشوائية أيضاً مساعدتك في توليد أوقات عشوائية بين أوقات محددة في أدوات الورقة العمل.

Kutools لـ Excel يقدم أكثر من 300 ميزة متقدمة لتبسيط المهام المعقدة، مما يعزز الإبداع والكفاءة. بالتكامل مع قدرات الذكاء الاصطناعي، يقوم Kutools بأتمتة المهام بدقة، مما يجعل إدارة البيانات أمرًا سهلاً للغاية. معلومات تفصيلية عن Kutools لـ Excel... نسخة تجريبية مجانية...

1. حدد نطاق الخلايا الذي ترغب في توليد الأوقات فيه.

2. ثم انقر Kutools > إدراج > إدراج بيانات عشوائية، في مربع الحوار المنبثق، يرجى تنفيذ العمليات التالية:

  • انقر على علامة التبويب وقت؛
  • ثم، حدد نطاق الوقت. في هذا المثال، سأختار من9:00 صباحاً إلى16:30 مساءً.
  • أخيراً، انقر موافق أو تطبيق لتوليد الأوقات العشوائية كما هو موضح في لقطة الشاشة أدناه.

A screenshot of Kutools for Excel generating random times between 9:00 AM and 4:30 PM using the Insert Random Data tool


 توليد تواريخ وأوقات عشوائية بين تاريخين ووقتين باستخدام صيغة

إذا كنت ترغب في توليد تواريخ وأوقات عشوائية معاً، يمكن أن تساعدك الصيغة أدناه.

1. أدخل أو انسخ الصيغة التالية في خلية حيث ترغب في توليد التواريخ والأوقات العشوائية:

=TEXT(RAND()*("2021-10-1512:00:00"-"2021-1-19:00")+"2021-1-19:00:00","YYYY-MM-DD HH:MM:SS")

ملاحظة: في هذه الصيغة،2021-10-1512:00:00 هو تاريخ ووقت الانتهاء، و2021-1-19:00:00 هو تاريخ ووقت البدء، يمكنك تعديلهما حسب حاجتك.

2. ثم، اسحب ونسخ هذه الصيغة إلى الخلايا الأخرى حيث ترغب في عرض التواريخ والأوقات العشوائية، كما هو موضح في لقطة الشاشة:

A screenshot showing random date-time values generated using a formula in Excel between 2021-01-01 9:00:00 and 2021-10-15 12:00:00


توليد أرقام ونصوص وتواريخ عشوائية في Excel365 /2021 والإصدارات الأحدث

سيعرض هذا القسم كيفية توليد أرقام وتواريخ عشوائية، والحصول على اختيارات عشوائية وتوزيع البيانات على مجموعات بشكل عشوائي في Excel365 وExcel2021 والإصدارات المستقبلية باستخدام دالة المصفوفة الديناميكية الجديدة - RANDARRAY.

تُستخدم دالة RANDARRAY لإرجاع مصفوفة من الأرقام العشوائية بين أي رقمين تحددهما.

بنية دالة RANDARRAY هي:

=RANDARRAY([rows],[columns],[min],[max],[integer])
  • rows (اختياري): عدد الصفوف من الأرقام العشوائية التي سيتم إرجاعها؛ (إذا تم تجاهله، الافتراضي =1)
  • columns (اختياري): عدد الأعمدة من الأرقام العشوائية التي سيتم إرجاعها؛ (إذا تم تجاهله، الافتراضي =1)
  • min (اختياري): الحد الأدنى للرقم الذي سيتم إرجاعه؛ (إذا تم تجاهله، الافتراضي =0)
  • max (اختياري): الحد الأقصى للرقم الذي سيتم إرجاعه؛ (إذا تم تجاهله، الافتراضي =1)
  • integer (اختياري): إرجاع عدد صحيح أو قيمة عشرية. TRUE لعدد صحيح، FALSE لعدد عشري. (إذا تم تجاهله، الافتراضي =FALSE)
ملاحظات:
  • 1. هناك خمسة معطيات في دالة RANDARRAY، جميعها اختيارية، إذا لم يتم تحديد أي معطى، ستعيد RANDARRAY قيمة عشرية بين0 و1.
  • 2. إذا كانت معطيات الصفوف أو الأعمدة أرقام عشرية، سيتم اقتطاعها إلى أقرب عدد صحيح قبل الفاصلة العشرية (مثلاً3.9 ستُعامل كـ3).
  • 3. يجب أن يكون الحد الأدنى أقل من الحد الأقصى، وإلا ستعيد الدالة خطأ #VALUE!.
  • 4. تُرجع دالة RANDARRAY مصفوفة، وعند إرجاع نتائج متعددة في أدوات الورقة العمل، ستنسكب النتائج في الخلايا المجاورة.

2.1 توليد أرقام عشوائية في Excel365 /2021 والإصدارات الأحدث

لتوليد أعداد صحيحة أو عشرية عشوائية في Excel365 وExcel2021 والإصدارات المستقبلية، يمكنك استخدام دالة RANDARRAY الجديدة هذه.

 توليد أرقام عشوائية بين رقمين باستخدام صيغة

لإنشاء قائمة من الأرقام العشوائية ضمن نطاق محدد، يرجى تطبيق الصيغ التالية:

يرجى إدخال أي من الصيغ أدناه حسب حاجتك، ثم اضغط على مفتاح Enter للحصول على النتائج، كما هو موضح في لقطات الشاشة:

=RANDARRAY(6,4,50,200, TRUE)               (توليد أعداد صحيحة عشوائية بين50 و200)
=RANDARRAY(6,4,50,200, FALSE)           
 (توليد أرقام عشرية عشوائية بين50 و200)
ملاحظة: في الصيغ أعلاه:
  • 6: يشير إلى إرجاع6 صفوف من الأرقام العشوائية؛
  • 4: يشير إلى إرجاع4 أعمدة من الأرقام العشوائية؛
  • 50،200: القيم الدنيا والقصوى التي ترغب في توليد الأرقام بينها؛
  • TRUE: يشير إلى إرجاع أعداد صحيحة؛
  • FALSE: يشير إلى إرجاع أرقام عشرية.
A screenshot showing random integers generated between 50 and 200 using the RANDARRAY function A screenshot showing random decimals generated between 50 and 200 using the RANDARRAY function in Excel

 توليد أرقام عشوائية بدون تكرار باستخدام الصيغ

عند استخدام دالة RANDARRAY العادية لتوليد أرقام عشوائية، قد يتم توليد بعض الأرقام المكررة أيضاً. لتجنب التكرار، سأعرض لك بعض الصيغ لحل هذه المهمة.

توليد قائمة من الأرقام العشوائية غير المكررة

لتوليد عمود أو قائمة من الأرقام الفريدة عشوائياً، الصيغ العامة هي:

أعداد صحيحة عشوائية بدون تكرار:

=INDEX(UNIQUE(RANDARRAY(n^2,1, min, max, TRUE)), SEQUENCE(n))

أرقام عشرية عشوائية بدون تكرار:

=INDEX(UNIQUE(RANDARRAY(n^2,1, min, max, FALSE)), SEQUENCE(n))
  • n: عدد القيم التي ترغب في توليدها؛
  • min: القيمة الدنيا؛
  • max: القيمة القصوى.

على سبيل المثال، هنا سأدرج قائمة من8 أرقام عشوائية من50 إلى100 بدون تكرار، يرجى تطبيق أي من الصيغ أدناه حسب حاجتك، ثم اضغط على مفتاح Enter للحصول على النتائج:

=INDEX(UNIQUE(RANDARRAY(8^2,1,50,100, TRUE)), SEQUENCE(8))          (أعداد صحيحة عشوائية فريدة)
=INDEX(UNIQUE(RANDARRAY(8^2,1,50,100, FALSE)), SEQUENCE(8))         
(أرقام عشرية عشوائية فريدة)
ملاحظة: في الصيغ أعلاه:
  • 8: يشير إلى إرجاع8 أرقام عشوائية؛
  • 50،100: القيم الدنيا والقصوى التي ترغب في توليد الأرقام بينها.
  • TRUE: يشير إلى إرجاع أعداد صحيحة؛
  • FALSE: يشير إلى إرجاع أرقام عشرية.
A screenshot showing a list of unique random integers generated using the UNIQUE and RANDARRAY functions in Excel A screenshot showing a list of unique random decimals generated using the UNIQUE and RANDARRAY functions in Excel

توليد نطاق من الأرقام العشوائية غير المكررة

إذا كنت ترغب في توليد أرقام عشوائية غير مكررة في نطاق من الخلايا، فقط حدد عدد الصفوف والأعمدة في دالة SEQUENCE، الصيغ العامة هي:

لتوليد عمود أو قائمة من الأرقام الفريدة عشوائياً، الصيغ العامة هي:

أعداد صحيحة عشوائية بدون تكرار:

=INDEX(UNIQUE(RANDARRAY(n^2,1, min, max, TRUE)), SEQUENCE(rows, columns))

أرقام عشرية عشوائية بدون تكرار:

=INDEX(UNIQUE(RANDARRAY(n^2,1, min, max, FALSE)), SEQUENCE(rows, columns))
  • n: عدد الخلايا لإدراج الأرقام، يمكنك تحديده كعدد الصفوف * عدد الأعمدة؛ على سبيل المثال، لملء8 صفوف و3 أعمدة، استخدم24^2.
  • rows: عدد الصفوف للملء؛
  • columns: عدد الأعمدة للملء؛
  • min: أقل قيمة؛
  • max: أعلى قيمة.

هنا، سأملأ نطاقاً من8 صفوف و3 أعمدة بأرقام عشوائية فريدة من50 إلى100، يرجى تطبيق أي من الصيغ أدناه حسب حاجتك:

=INDEX(UNIQUE(RANDARRAY(24^2,1,50,100, TRUE)), SEQUENCE(8,3))          (أعداد صحيحة عشوائية فريدة)
=INDEX(UNIQUE(RANDARRAY(24^2,1,50,100, FALSE)), SEQUENCE(8,3))         
(أرقام عشرية عشوائية فريدة)
ملاحظة: في الصيغ أعلاه:
  • 24: يشير إلى إرجاع24 رقماً عشوائياً، حاصل ضرب8 في3 (صفوف*أعمدة)؛
  • 50،100: القيم الدنيا والقصوى التي ترغب في توليد الأرقام بينها؛
  • TRUE: يشير إلى إرجاع أعداد صحيحة؛
  • FALSE: يشير إلى إرجاع أرقام عشرية.
A screenshot showing a grid of unique random integers generated in 8 rows and 3 columns using Excel's RANDARRAY function A screenshot showing a grid of unique random decimals generated in 8 rows and 3 columns using Excel's RANDARRAY function

2.2 توليد تواريخ عشوائية في Excel365 /2021 والإصدارات الأحدث

باستخدام دالة RANDARRAY الجديدة هذه، يمكنك أيضاً توليد عدة تواريخ عشوائية أو أيام عمل في Excel بسرعة وسهولة.

 توليد تواريخ عشوائية بين تاريخين باستخدام صيغة

لإنشاء قائمة من التواريخ العشوائية بين تاريخين محددين، يمكنك تطبيق الصيغة أدناه:

1. أدخل الصيغة التالية في خلية فارغة لتوليد التواريخ العشوائية، واضغط على مفتاح Enter للحصول على قائمة من الأرقام المكونة من خمسة أرقام، كما هو موضح في لقطة الشاشة:

=RANDARRAY(10,1, B1, B2, TRUE)
ملاحظة: في الصيغ أعلاه:
  • 10: يشير إلى إرجاع10 صفوف من التواريخ العشوائية؛
  • 1: يشير إلى إرجاع عمود واحد من التواريخ العشوائية؛
  • B1، B2: الخلايا التي تحتوي على تاريخ البدء والانتهاء الذي ترغب في توليد التواريخ بينهما.

A screenshot showing five-digit random dates generated using RANDARRAY between two dates in Excel

2. بعد ذلك، يجب عليك تنسيق الأرقام إلى تنسيق التاريخ العادي: حدد الأرقام، ثم انقر بزر الماوس الأيمن، ثم اختر تنسيق الخلايا من القائمة السياقية. في مربع حوار تنسيق الخلايا التالي، يرجى تنفيذ ما يلي:

  • انقر على علامة التبويب رقم؛
  • ثم انقر على تاريخ من جزء الفئة؛
  • ثم، اختر تنسيق التاريخ الذي تفضله من قائمة النوع.

A screenshot of the Format Cells dialog box used to format random numbers as dates in Excel

3. بعد ذلك، انقر على زر موافق، وسيتم تنسيق الأرقام بالتاريخ الذي حددته، كما هو موضح في لقطة الشاشة:

A screenshot showing formatted random dates between May 1, 2021, and December 31, 2021, using Excel

نصيحة: بالطبع، يمكنك أيضاً إدخال تاريخ البدء والانتهاء مباشرة في الصيغة كما يلي:

=RANDARRAY(10,1, "5/1/2021", "12/31/2021", TRUE)

 توليد أيام عمل عشوائية بين تاريخين باستخدام صيغة

لإنتاج أيام عمل عشوائية في نطاق من الخلايا، قم بتضمين دالة RANDARRAY داخل دالة WORKDAY.

1. أدخل أو انسخ الصيغة أدناه في خلية فارغة، ثم اضغط على مفتاح Enter للحصول على قائمة من الأرقام كما هو موضح في لقطة الشاشة أدناه:

=WORKDAY(RANDARRAY(10,1, B1, B2, TRUE),1)

A screenshot showing random workday numbers generated using RANDARRAY and WORKDAY functions in Excel

2. بعد ذلك، قم بتنسيق الأرقام إلى تنسيق تاريخ محدد حسب حاجتك في مربع حوار تنسيق الخلايا، وستحصل على تنسيق التاريخ كما هو موضح في لقطة الشاشة أدناه:

A screenshot showing random workdays formatted as dates in Excel

نصيحة: يمكنك أيضاً إدخال تاريخ البدء والانتهاء مباشرة في الصيغة كما يلي:

=WORKDAY(RANDARRAY(10,1, "5/1/2021", "12/31/2021", TRUE),1)

2.3 توليد أو الحصول على قيم عشوائية من قائمة في Excel365 /2021 والإصدارات الأحدث

في Excel365 وExcel2021 والإصدارات المستقبلية (مثل Excel2024)، إذا كنت ترغب في توليد أو إرجاع بعض القيم العشوائية من قائمة من الخلايا، سيعرض لك هذا القسم بعض الصيغ لتحقيق ذلك.

 توليد أو الحصول على قيم عشوائية من قائمة باستخدام صيغة

لاستخراج قيم عشوائية من قائمة من الخلايا، يمكن لدالة RANDARRAY مع دالة INDEX مساعدتك. الصيغة العامة هي:

=INDEX(data, RANDARRAY(n,1,1, ROWS(data), TRUE))
  • data: قائمة القيم التي ترغب في استخراج العناصر العشوائية منها؛
  • n: عدد العناصر العشوائية التي ترغب في استخراجها.

على سبيل المثال، لاستخراج3 أسماء من قائمة الأسماء A2:A12، يرجى استخدام الصيغ أدناه:

=INDEX(A2:A12, RANDARRAY(C2,1,1, ROWS(A2:A12), TRUE))             (استخدام مرجع خلية)
=INDEX(A2:A12, RANDARRAY(3,1,1, ROWS(A2:A12), TRUE))                 
(إدخال رقم مباشرة)

ثم، اضغط على مفتاح Enter، وستحصل على3 أسماء عشوائياً دفعة واحدة، كما هو موضح في لقطة الشاشة:

A screenshot of random names extracted from a list in Excel


 توليد أو الحصول على قيم عشوائية من قائمة بدون تكرار باستخدام صيغة

مع الصيغة أعلاه، قد تلاحظ وجود تكرار في النتائج. لاختيار عشوائي من قائمة بدون تكرار، الصيغة العامة هي:

=INDEX(SORTBY(data, RANDARRAY(ROWS(data))), SEQUENCE(n))
  • data: قائمة القيم التي ترغب في استخراج العناصر العشوائية منها؛
  • n: عدد العناصر العشوائية التي ترغب في استخراجها.

إذا كنت بحاجة لإرجاع5 أسماء من قائمة الأسماء A2:A12 عشوائياً، يرجى إدخال أو نسخ إحدى الصيغ أدناه:

=INDEX(SORTBY(A2:A12, RANDARRAY(ROWS(A2:A12))), SEQUENCE(C2))             (استخدام مرجع خلية)
=INDEX(SORTBY(A2:A12, RANDARRAY(ROWS(A2:A12))), SEQUENCE(5))             
(إدخال رقم مباشرة)

ثم، اضغط على مفتاح Enter للحصول على5 أسماء عشوائية من القائمة A2:A12 بدون تكرار، كما هو موضح في لقطة الشاشة:

A screenshot of random names extracted from a list in Excel without duplicates


2.4 توليد أو اختيار صفوف عشوائية من نطاق في Excel365 /2021 والإصدارات الأحدث

في بعض الأحيان، قد تحتاج إلى اختيار بعض الصفوف عشوائياً من نطاق من الخلايا في Excel. لتحقيق هذه المهمة، سأعرض لك بعض الصيغ.

 توليد أو اختيار صفوف عشوائية من نطاق باستخدام صيغة

الصيغة العامة لتوليد صفوف عشوائية من نطاق من الخلايا هي:

=INDEX(data, RANDARRAY(n,1,1, ROWS(data), TRUE), {1,2,3…})
  • data: نطاق الخلايا الذي ترغب في استخراج الصفوف العشوائية منه؛
  • n: عدد الصفوف العشوائية التي ترغب في استخراجها؛
  • {1,2,3…}: أرقام الأعمدة المراد استخراجها.

لاستخراج3 صفوف من البيانات من النطاق A2:C12، يرجى استخدام أي من الصيغ التالية:

=INDEX(A2:C12, RANDARRAY(E2,1,1, ROWS(A2:C12), TRUE), {1,2,3})             (استخدام مرجع خلية)
=INDEX(A2:C12, RANDARRAY(3,1,1, ROWS(A2:C12), TRUE), {1,2,3})                 
(إدخال رقم مباشرة)

ثم، اضغط على مفتاح Enter للحصول على3 صفوف عشوائية من البيانات من النطاق A2:C12، كما هو موضح في لقطة الشاشة:

A screenshot of 3 random rows extracted from a range in Excel


 توليد أو اختيار صفوف عشوائية من نطاق بدون تكرار باستخدام صيغة

وبالمثل، قد تنتج الصيغة أعلاه بيانات مكررة أيضاً. لمنع تكرار الصفوف، يمكنك استخدام الصيغة العامة أدناه:

=INDEX(SORTBY(data, RANDARRAY(ROWS(data))), SEQUENCE(n), {1,2,3…})
  • data: نطاق الخلايا الذي ترغب في استخراج الصفوف العشوائية منه؛
  • n: عدد الصفوف العشوائية التي ترغب في استخراجها؛
  • {1,2,3…}: أرقام الأعمدة المراد استخراجها.

على سبيل المثال، لاختيار5 صفوف من البيانات من النطاق A2:C12، يرجى استخدام أي من الصيغ أدناه:

=INDEX(SORTBY(A2:C12, RANDARRAY(ROWS(A2:C12))), SEQUENCE(E2), {1,2,3})           (استخدام مرجع خلية)
=INDEX(SORTBY(A2:C12, RANDARRAY(ROWS(A2:C12))), SEQUENCE(5), {1,2,3})             
(إدخال رقم مباشرة)

ثم، اضغط على مفتاح Enter، وسيتم استخراج5 صفوف عشوائية بدون تكرار من النطاق A2:C12 كما هو موضح في لقطة الشاشة أدناه:

A screenshot of 5 random rows extracted from a range in Excel without duplicates


منع تغيير النتائج العشوائية

ربما لاحظت أن جميع الدوال العشوائية في هذا المقال، مثل RAND وRANDBETWEEN وRANDARRAY، هي دوال متطايرة. سيتم إعادة حساب النتائج في كل مرة يتم فيها تغيير الورقة، وسيتم إنتاج قيم عشوائية جديدة بعد ذلك. لإيقاف تغيير القيم العشوائية تلقائياً، إليك طريقتان سريعتان لك.

 منع تغيير النتائج العشوائية باستخدام النسخ واللصق

عادةً، يمكنك استخدام ميزة النسخ واللصق لنسخ الصيغ الديناميكية ولصقها كقيم، يرجى اتباع الخطوات التالية:

1. حدد الخلايا التي تحتوي على الصيغة العشوائية، ثم اضغط على Ctrl + C لنسخها.

2. ثم، انقر بزر الماوس الأيمن على النطاق المحدد، وانقر على خيار القيم من قسم خيارات اللصق، كما هو موضح في لقطة الشاشة:

نصيحة: يمكنك أيضاً الضغط على Shift + F10 ثم V لتفعيل هذا الخيار.

A screenshot of the 'Values' option in Excel's Paste Options menu

3. وستتحول جميع خلايا الصيغة إلى قيم، ولن تتغير القيم العشوائية بعد الآن.


 منع تغيير النتائج العشوائية باستخدام ميزة عملية

إذا كان لديك Kutools لـ Excel مثبتاً، يمكن لميزة إلى القيم الفعلية مساعدتك في تحويل جميع خلايا الصيغ المحددة إلى قيم بنقرة واحدة فقط.

Kutools لـ Excel يقدم أكثر من 300 ميزة متقدمة لتبسيط المهام المعقدة، مما يعزز الإبداع والكفاءة. بالتكامل مع قدرات الذكاء الاصطناعي، يقوم Kutools بأتمتة المهام بدقة، مما يجعل إدارة البيانات أمرًا سهلاً للغاية. معلومات تفصيلية عن Kutools لـ Excel... نسخة تجريبية مجانية...

1. حدد الخلايا التي تحتوي على الصيغة العشوائية، ثم انقر Kutools > إلى القيم الفعلية، كما هو موضح في لقطة الشاشة:

A screenshot of the Kutools 'To Actual' feature in Excel

2. الآن، تم تحويل جميع الصيغ المحددة إلى قيم.

أفضل أدوات الإنتاجية لمكتب العمل

🤖 Kutools AI Aide: أحدث ثورة في تحليل البيانات من خلال: التنفيذ الذكي |توليد الشيفرة |إنشاء الصيغ المخصصة |تحليل البيانات وتوليد الرسوم البيانية |استدعاء الوظائف المحسنة
الميزات الشائعة: البحث، تمييز أو وضع علامة على المكررات | حذف الصفوف الفارغة | دمج الأعمدة أو العنوان دون فقدان البيانات | تقريب ...
بحث متقدم: بحث V متعدد المعايير | بحث V متعدد القيم | بحث في عدة ورقات | مطابقة غامضة ....
قائمة منسدلة متقدمة: إنشاء قائمة منسدلة بسرعة | قائمة منسدلة تابعة | قائمة منسدلة متعددة الاختيار ....
إدارة الأعمدة: إضافة عدد محدد من الأعمدة | نقل الأعمدة | تبديل حالة إظهار الأعمدة المخفية | مقارنة النطاق والأعمدة ...
ميزات مميزة: التركيز على الشبكة | عرض التصميم | شريط الصيغ المحسن | أدوات المصنف & أدوات الورقة العمل | مكتبة النص التلقائي (Auto Text) | منتقي التاريخ | دمج البيانات | تشفير/فك تشفير الخلايا | إرسال البريد الإلكتروني حسب القائمة | مرشح متقدم | تصفية خاصة (تصفية الخلايا التي تحتوي على خط عريض/مائل/يتوسطه خط...) ...
أفضل15 مجموعة أدوات:12 أداة نصية (إضافة نص، حذف الأحرف المحددة، ...) | أكثر من50 نوع من الرسوم البيانية (مخطط جانت، ...) | أكثر من40 صيغة عملية (حساب العمر بناءً على تاريخ الميلاد، ...) |19 أداة إدراج (إدراج رمز الاستجابة السريعة، إدراج صورة من المسار، ...) |12 أداة تحويل (تحويل إلى كلمات، تحويل العملة، ...) |7 أدوات دمج وتقسيم (دمج متقدم للصفوف، تقسيم الخلايا، ...) | ... والمزيد

عزز مهاراتك في Excel مع Kutools لـ Excel، واختبر الكفاءة كما لم يحدث من قبل. Kutools لـ Excel يقدم أكثر من300 ميزة متقدمة لزيادة الإنتاجية وتوفير وقت الحفظ. انقر هنا للحصول على الميزة التي تحتاجها أكثر...


Office Tab يقدم واجهة التبويب لـ Office، ويجعل عملك أسهل بكثير

  • تمكين تحرير وقراءة المستندات عبر التبويبات في Word وExcel وPowerPoint.
  • افتح وأنشئ عدة مستندات في تبويبات جديدة ضمن نفس النافذة، بدلاً من فتحها في نوافذ منفصلة.
  • يزيد إنتاجيتك بنسبة50%، ويقلل مئات النقرات بالماوس يومياً!