دليل Excel: تقسيم الخلايا النصية والرقمية وخلايا التاريخ (فصلها إلى أعمدة متعددة)

عند استخدام Excel، قد تحتاج أحيانًا إلى تقسيم النص من خلية واحدة إلى عدة خلايا لأغراض معينة. ينقسم هذا الدليل إلى ثلاثة أجزاء: تقسيم الخلايا النصية، تقسيم الخلايا الرقمية، وتقسيم خلايا التاريخ. يوفر كل جزء أمثلة مختلفة لمساعدتك على معرفة كيفية التعامل مع مهمة التقسيم عند مواجهة نفس المشكلة.

1 تقسيم الخلايا النصية

يجمع هذا الجزء الحالات التي قد تواجهها عند تقسيم خلية نصية إلى أعمدة متعددة، ويوفر لك الطرق المناسبة لكل حالة.

مثال #1 تقسيم الخلايا حسب الفاصلة أو المسافة أو فواصل أخرى

لتقسيم خلية نصية إلى أعمدة متعددة باستخدام فاصل محدد مثل الفاصلة أو المسافة أو الشرطة وغيرها، يمكنك تطبيق إحدى الطرق التالية.

تقسيم الخلايا حسب الفاصل باستخدام ميزة تقسيم البيانات

تُعد ميزة تقسيم البيانات، كإحدى الأدوات المدمجة في Excel، من أكثر الأدوات استخدامًا لتقسيم الخلايا. كما هو موضح في الصورة أدناه، لتقسيم الخلايا في عمود النصوص حسب الفاصلة، يمكنك استخدام ميزة تقسيم البيانات كما يلي.

1. حدد النطاق الذي ترغب في تقسيمه حسب الفاصلة، ثم انقر على البيانات > تقسيم البيانات.

2. في مربع الحوار معالج تقسيم البيانات – الخطوة1 من3، اترك زر الراديو الفاصل محددًا، ثم انقر على زر التالي.

3. في مربع الحوار معالج تقسيم البيانات – الخطوة2 من3، حدد الفاصل المناسب حسب احتياجك (في هذا المثال، أضع علامة صح فقط على مربع الفاصلة)، ثم انقر على زر التالي.

4. في الخطوة الأخيرة من مربع الحوار، انقر على زر اختيار خلية لتحديد مكان إخراج النصوص المفصولة، ثم انقر على إنهاء زر.

بعد ذلك، سيتم تقسيم النصوص في النطاق المحدد حسب الفاصلة ووضعها في أعمدة مختلفة كما هو موضح أدناه.

تقسيم الخلايا حسب الفاصل باستخدام الصيغة

يمكنك تطبيق الصيغة التالية لتقسيم النصوص في الخلايا حسب فاصل محدد في Excel.

صيغة عامة

=TRIM(MID(SUBSTITUTE(A1,delim,REPT(" ",LEN(A1))),(N-1)*LEN(A1)+1,LEN(A1)))

المعاملات

بعد ذلك، تابع تطبيق هذه الصيغة.

1. كما هو موضح في الصورة أدناه، أولاً، تحتاج إلى إنشاء صف مساعد بالأرقام1،2،3... في خلايا مختلفة.

ملاحظة: هنا1،2،3... تمثل الترتيب الأول والثاني والثالث للسلسلة النصية.

2. حدد خلية أسفل خلية الرقم1، ثم انسخ أو أدخل الصيغة أدناه واضغط على مفتاح الإدخال للحصول على الجزء الأول من السلسلة النصية. حدد خلية النتيجة، واسحب مقبض التعبئة التلقائية إلى اليمين والأسفل للحصول على الأجزاء الأخرى. انظر الصورة:

=TRIM(MID(SUBSTITUTE($B5,",",REPT(" ",LEN($B5))),(D$4-1)*LEN($B5)+1,LEN($B5)))

ملاحظة: في الصيغة، "," هو الفاصل المستخدم لتقسيم السلسلة النصية في B5. يمكنك تغييره حسب احتياجك.

تقسيم الخلايا حسب الفاصل باستخدام أداة مذهلة

هنا، نوصي باستخدام ميزة تقسيم الخلايا في Kutools لـ Excel لمساعدتك على تقسيم الخلايا بسهولة إلى أعمدة أو صفوف منفصلة حسب فاصل معين في Excel.

1. بعد تثبيت Kutools لـ Excel، حدد النطاق الذي تريد تقسيم السلاسل النصية فيه، ثم انقر على Kutools > دمج & تقسيم > تقسيم الخلايا.

2. في مربع حوار تقسيم الخلايا، تحتاج إلى ضبط الإعدادات كما يلي.

3. في مربع حوار تقسيم الخلايا التالي، حدد خلية لإخراج الأجزاء، ثم انقر موافق.

بعد ذلك، يتم تقسيم الأجزاء إلى أعمدة أو صفوف مختلفة بناءً على ما حددته في الخطوة2 أعلاه.

تقسيم البيانات:

تقسيم إلى صفوف:

مثال #2 تقسيم الخلايا حسب طول معين

لتقسيم السلسلة النصية حسب طول معين، يمكن للطرق التالية مساعدتك.

تقسيم الخلايا حسب طول معين باستخدام ميزة تقسيم البيانات

توفر ميزة تقسيم البيانات خيار العرض الثابت لمساعدتك على تقسيم السلاسل النصية في الخلايا المحددة حسب طول معين في Excel.

كما هو موضح في الصورة أدناه، لتقسيم النصوص في النطاق B5:B9 إلى أعمدة كل3 أحرف، يمكنك اتباع الخطوات التالية.

1. حدد الخلايا التي ترغب في تقسيم السلاسل النصية فيها.

2. انقر على البيانات > تقسيم البيانات.

3. في مربع الحوار معالج تقسيم البيانات – الخطوة1 من3، اختر زر الراديو العرض الثابت ثم انقر التالي.

4. ستظهر نافذة الخطوة2 من3. في قسم معاينة البيانات، انقر في الموضع المطلوب على المحور لإنشاء خط فاصل (خط مع سهم). بعد إنشاء جميع الخطوط الفاصلة، انقر على زر التالي للمتابعة.

في هذا المثال، أنشئ خطوط فاصلة كل3 أحرف في السلسلة النصية.

5. في الخطوة الأخيرة من المعالج، حدد خلية لإخراج النصوص المفصولة، ثم انقر على زر إنهاء.

الآن تم تقسيم السلاسل النصية في الخلايا المحددة كل3 أحرف كما هو موضح في الصورة أدناه.

تقسيم الخلايا حسب طول معين باستخدام أداة مذهلة

لتقسيم الخلايا حسب طول معين في Excel، يمكنك استخدام ميزة تقسيم الخلايا في Kutools لـ Excel لإنجاز ذلك بسهولة.

1. حدد الخلايا النصية التي ترغب في تقسيمها حسب طول معين، ثم انقر Kutools > دمج & تقسيم > تقسيم الخلايا.

2. في مربع حوار تقسيم الخلايا، تحتاج إلى ضبط الإعدادات كما يلي.

3. في مربع حوار تقسيم الخلايا التالي، حدد خلية لوضع النصوص المقسمة ثم انقر موافق.

بعد ذلك، يتم تقسيم السلاسل النصية في الخلايا المحددة حسب طول معين وتوضع في أعمدة مختلفة.

مثال #3 تقسيم الخلايا حسب كلمة معينة

كما هو موضح في الصورة أدناه، لتقسيم السلاسل النصية في النطاق B5:B9 حسب الكلمة الكاملة "sales"، يمكنك تطبيق الصيغ المقدمة في هذا القسم.

الحصول على الجزء قبل كلمة معينة في الخلية

يمكنك تطبيق صيغة تعتمد على دالتي LEFT وFIND للحصول على الجزء قبل كلمة معينة في السلسلة النصية.

صيغة عامة

=LEFT(A1,FIND("certain_word", A1)-1)

المعاملات

1. حدد خلية فارغة، ثم انسخ أو أدخل الصيغة أدناه واضغط على مفتاح الإدخال للحصول على الجزء قبل الكلمة المعينة. حدد خلية النتيجة، ثم اسحب مقبض التعبئة التلقائية للأسفل لتطبيق الصيغة على الخلايا الأخرى.

=LEFT(B5,FIND("sales",B5)-1)

الحصول على الجزء بعد الكلمة في الخلية

بعد الحصول على الجزء قبل الكلمة، تحتاج إلى تطبيق الصيغة أدناه للحصول على الجزء بعدها.

صيغة عامة

=TRIM(MID(A1,SEARCH("certain_word",A1)+LEN("certain_word"),255))

المعاملات

1. حدد خلية فارغة بجوار خلية النتيجة الأولى (D5).

2. انسخ أو أدخل الصيغة أدناه واضغط على مفتاح الإدخال. حدد خلية النتيجة، واسحب مقبض التعبئة التلقائية للأسفل للحصول على النتائج الأخرى.

=TRIM(MID(B5,SEARCH("sales",B5)+LEN("sales"),255))

الآن قمت بتقسيم السلاسل النصية إلى أعمدة مختلفة حسب كلمة كاملة.

مثال #4 تقسيم الخلايا حسب بدء سطر جديد

يوضح هذا القسم طرقًا مختلفة لمساعدتك على تقسيم الخلايا النصية حسب بدء سطر جديد في Excel.

تقسيم الخلايا حسب بدء سطر جديد باستخدام ميزة تقسيم البيانات

يمكن تطبيق ميزة تقسيم البيانات لتقسيم الخلايا حسب بدء سطر جديد في Excel. يمكنك اتباع الخطوات التالية.

1. حدد نطاق الخلايا التي ترغب في تقسيم النصوص فيها حسب بدء سطر جديد.

2. انقر على البيانات > تقسيم البيانات.

3. في مربع الحوار معالج تقسيم البيانات – الخطوة1 من3، اختر زر الراديو الفاصل ثم انقر التالي؛

4. في مربع الحوار الخطوة2 من3، قم بإلغاء تحديد أي فواصل موجودة، ثم ضع علامة صح على مربع آخر، واضغط على اختصار Ctrl + J. ستلاحظ ظهور نقطة صغيرة في مربع النص، وفي مربع معاينة البيانات، يتم تقسيم النصوص حسب بدء سطر جديد. انقر على زر التالي.

5. في الخطوة الأخيرة من المعالج، حدد خلية وجهة لإخراج النصوص المفصولة، ثم انقر على زر إنهاء.

بعد ذلك، يتم تقسيم النصوص في الخلايا المحددة إلى أعمدة مختلفة حسب بدء سطر جديد.

تقسيم الخلايا حسب بدء سطر جديد باستخدام الصيغة

يمكن أن تساعدك الصيغ التالية أيضًا في تقسيم الخلايا حسب بدء سطر جديد في Excel.

باستخدام نفس المثال أعلاه، بعد التقسيم، ستحصل على ثلاثة أجزاء في أعمدة مختلفة.

الحصول على الجزء قبل أول بدء سطر جديد

أولاً، يمكننا تطبيق صيغة تعتمد على دالتي LEFT وSEARCH لتقسيم الجزء قبل أول بدء سطر جديد في الخلية.

صيغة عامة

=LEFT(cell, SEARCH(CHAR(10),cell,1)-1)

المعاملات

1. حدد خلية فارغة (D5 في هذا المثال)، ثم انسخ أو أدخل الصيغة أدناه واضغط على مفتاح الإدخال. حدد خلية النتيجة واسحب مقبض التعبئة التلقائية للأسفل للحصول على الأجزاء قبل أول بدء سطر جديد في الخلايا الأخرى.

=LEFT(B5, SEARCH(CHAR(10),B5,1)-1)

الحصول على الجزء بين أول وثاني بدء سطر جديد

للحصول على الجزء بين أول وثاني بدء سطر جديد في الخلية، يمكن للصيغة التالية مساعدتك.

صيغة عامة

=MID(cell,SEARCH(CHAR(10),cell)+1,SEARCH(CHAR(10),cell,SEARCH(CHAR(10),cell)+1)-SEARCH(CHAR(10),cell)-1)

المعاملات

1. حدد خلية (E5) بجوار D5، ثم انسخ أو أدخل الصيغة أدناه واضغط على مفتاح الإدخال. حدد خلية النتيجة واسحب مقبض التعبئة التلقائية للأسفل للحصول على الأجزاء بين أول وثاني بدء سطر جديد في الخلايا الأخرى.

=MID(B5, SEARCH(CHAR(10),B5) +1, SEARCH(CHAR(10),B5,SEARCH(CHAR(10),B5)+1) - SEARCH(CHAR(10),B5) -1)

الحصول على الجزء بعد ثاني بدء سطر جديد

الخطوة الأولى هي الحصول على الجزء بعد ثاني بدء سطر جديد باستخدام الصيغة أدناه.

صيغة عامة

=RIGHT(cell,LEN(cell) - SEARCH(CHAR(10),cell, SEARCH(CHAR(10), cell) +1))

المعاملات

1. حدد خلية (F5 في هذا المثال)، ثم انسخ أو أدخل الصيغة أدناه واضغط على مفتاح الإدخال. حدد خلية النتيجة واسحب مقبض التعبئة التلقائية للأسفل للحصول على الأجزاء بعد ثاني بدء سطر جديد في الخلايا الأخرى.

=RIGHT(B5,LEN(B5) - SEARCH(CHAR(10), B5, SEARCH(CHAR(10), B5) +1))

تقسيم الخلايا حسب بدء سطر جديد باستخدام VBA

يوفر هذا القسم كود VBA لمساعدتك على تقسيم النصوص بسهولة في الخلايا المحددة حسب بدء سطر جديد في Excel.

1. اضغط على مفاتيح Alt + F11 لفتح نافذة Microsoft Visual Basic for Applications.

2. في نافذة Microsoft Visual Basic for Applications، انقر على إدراج > وحدة نمطية. ثم انسخ كود VBA أدناه إلى نافذة الكود.

كود VBA: تقسيم الخلايا حسب بدء سطر جديد في Excel

Sub ExtendOffice_SplitRangeTex()
'Updated by Extendoffice 20211116
Dim xStr() As String
Dim xRg As Range
Dim xCell As Range
Dim xI As Integer
Set xRg = Application.InputBox("Please select the range of cells where you want to split by line break:", "Kutools for Excel", "", , , , , 8)
If xRg Is Nothing Then Exit Sub
For xI = 1 To xRg.Count
    Set xCell = xRg.Item(xI)
    xStr = VBA.Split(xCell.Value, vbLf)
    xCell.Resize(1, UBound(xStr) + 1).Offset(0, 1) = xStr
Next
End Sub

3. اضغط على مفتاح F5 لتشغيل الكود. ستظهر نافذة Kutools لـ Excel، تحتاج إلى تحديد نطاق الخلايا التي ترغب في تقسيمها حسب بدء سطر جديد، وأخيرًا انقر على زر موافق.

بعد ذلك، يتم تقسيم النصوص في الخلايا المحددة إلى أعمدة مختلفة دفعة واحدة حسب بدء سطر جديد.

تقسيم الخلايا حسب بدء سطر جديد باستخدام أداة مذهلة

هنا، نقدم أداة عملية – أداة تقسيم الخلايا في Kutools لـ Excel. باستخدام هذه الأداة، يمكنك تقسيم النصوص في الخلايا المحددة دفعة واحدة حسب بدء سطر جديد بعدة نقرات فقط.

1. حدد نطاق الخلايا التي ترغب في تقسيم النصوص فيها حسب بدء سطر جديد.

2. انقر Kutools > دمج & تقسيم > تقسيم الخلايا لتفعيل الميزة.

3. في مربع حوار تقسيم الخلايا، تحتاج إلى ضبط الإعدادات التالية.

4. في مربع حوار تقسيم الخلايا التالي، حدد خلية فارغة لوضع النصوص المفصولة، ثم انقر موافق.

بعد ذلك، يتم تقسيم النصوص في الخلايا المحددة إلى أعمدة مختلفة حسب بدء سطر جديد كما هو موضح في الصورة أدناه.

مثال #5 تقسيم الخلايا حسب أول أو آخر فاصل فقط

أحيانًا، قد تحتاج إلى تقسيم الخلية إلى جزئين حسب أول أو آخر فاصل فقط، يمكنك تجربة الصيغ أدناه.

تقسيم الخلايا حسب أول فاصل باستخدام الصيغ

كما هو موضح في الصورة أدناه، لتقسيم كل خلية في النطاق B5:B9 إلى جزئين حسب أول مسافة، تحتاج إلى تطبيق صيغتين.

تقسيم الجزء قبل أول مسافة

لتقسيم الجزء قبل أول مسافة، يمكنك استخدام صيغة تعتمد على دالتي LEFT وFIND.

صيغة عامة

=LEFT(cell,FIND("delimiter",cell)-1)

المعاملات

1. حدد خلية (D5 في هذا المثال) لإخراج الجزء، ثم انسخ أو أدخل الصيغة أدناه واضغط على مفتاح الإدخال. حدد خلية النتيجة ثم اسحب مقبض التعبئة التلقائية للأسفل للحصول على أجزاء الخلايا الأخرى.

=LEFT(B5,FIND(" ",B5)-1)

تقسيم الجزء بعد أول مسافة

ثم طبق الصيغة أدناه للحصول على الجزء بعد أول مسافة في الخلية.

صيغة عامة

=RIGHT(cell,LEN(cell)-FIND("delimiter",cell))

المعاملات

1. انسخ أو أدخل الصيغة أدناه في الخلية E5 واضغط على مفتاح الإدخال للحصول على النتيجة. حدد خلية النتيجة هذه واسحب مقبض التعبئة التلقائية للأسفل للحصول على الجزء بعد آخر مسافة في الخلايا الأخرى.

=RIGHT(B5,LEN(B5)-FIND(" ",B5))

ملاحظة: في الصيغ، يمكنك تغيير مرجع الخلية والسلسلة النصية والفاصل حسب احتياجك.

تقسيم الخلايا حسب آخر فاصل باستخدام الصيغ

لتقسيم النصوص في نطاق الخلايا (B5:B9) إلى جزئين حسب آخر مسافة كما هو موضح في الصورة، يمكن للصيغتين المقدمتين في هذا القسم مساعدتك في ذلك.

الحصول على النص إلى يسار آخر فاصل

للحصول على النص إلى يسار آخر فاصل في الخلية، يمكنك تطبيق الصيغة أدناه.

صيغة عامة

=LEFT(B5,SEARCH("^",SUBSTITUTE(cell,"delimiter","^",LEN(cell)-LEN(SUBSTITUTE(cell,"delimiter",""))))-1)

المعاملات

1. حدد خلية لوضع الجزء الأيسر، ثم انسخ أو أدخل الصيغة أدناه واضغط على مفتاح الإدخال. حدد خلية النتيجة واسحب مقبض التعبئة التلقائية للأسفل لتطبيق الصيغة على الخلايا الأخرى.

=LEFT(B5,SEARCH("^",SUBSTITUTE(B5," ","^",LEN(B5)-LEN(SUBSTITUTE(B5," ",""))))-1)

الحصول على النص إلى يمين آخر فاصل

الآن نحتاج إلى الحصول على النص إلى يمين آخر مسافة في هذا المثال.

صيغة عامة

=TRIM(RIGHT(SUBSTITUTE(cell,"delimiter",REPT("delimiter",LEN(cell))),LEN(cell)))

المعاملات

1. حدد خلية لوضع الجزء الأيمن، ثم انسخ أو أدخل الصيغة أدناه واضغط على مفتاح الإدخال. حدد خلية النتيجة واسحب مقبض التعبئة التلقائية للأسفل لتطبيق الصيغة على الخلايا الأخرى.

=TRIM(RIGHT(SUBSTITUTE(B5," ",REPT(" ",LEN(B5))),LEN(B5)))

ملاحظة: في الصيغ، يمكنك تغيير مرجع الخلية والسلسلة النصية والفاصل حسب احتياجك.

مثال #6 تقسيم الخلايا حسب الحرف الكبير

يقدم هذا القسم دالة معرفة من قبل المستخدم لتقسيم الكلمات في الخلايا حسب الحرف الكبير.

1. اضغط على مفاتيح Alt + F11 لفتح نافذة Microsoft Visual Basic for Applications.

2. في نافذة Microsoft Visual Basic for Applications، انقر على إدراج > وحدة نمطية، ثم انسخ كود VBA أدناه إلى نافذة الكود.

كود VBA: تقسيم الخلايا حسب الحرف الكبير في Excel

Function GetName(s As String, Num As Long) As String
'Updated by Extendoffice 20211116
  With CreateObject("VBSCript.RegExp")
    .Global = True
    .Pattern = "[A-Z][a-z]+|[A-Z]"
    GetName = .Execute(s).Item(Num - 1)
  End With
End Function

3. اضغط على مفاتيح Alt + Q لإغلاق نافذة Microsoft Visual Basic for Applications.

4. حدد خلية (D5 في هذا المثال) لإخراج الكلمة إلى يسار أول حرف كبير، ثم أدخل الصيغة أدناه واضغط على مفتاح الإدخال. حدد خلية النتيجة هذه واسحب مقبض التعبئة التلقائية إلى اليمين ثم للأسفل للحصول على الكلمات الأخرى.

=IFERROR(GetName($B5,COLUMNS($D:D)),"")

ملاحظة: في الكود، $B5 هي الخلية التي ستقوم بتقسيمها، $D:D هو عمود خلية النتيجة. يرجى تغييرها حسب بياناتك.

مثال #7 تقسيم الأسماء في الخلايا

افترض أن لديك ورقة عمل تحتوي على عمود من الأسماء الكاملة، وترغب في تقسيم الاسم الكامل إلى أعمدة منفصلة مثل تقسيم الاسم الأول والاسم الأخير من الاسم الكامل، أو تقسيم الاسم الأول أو الأوسط أو الأخير من الاسم الكامل. يسرد هذا القسم خطوات مفصلة لمساعدتك في حل هذه المشكلات.

تقسيم الاسم الكامل إلى الاسم الأول والاسم الأخير

كما هو موضح في الصورة أدناه، يتم فصل الاسم الأول والاسم الأوسط والاسم الأخير بمسافة واحدة، لتقسيم الاسم الأول والاسم الأخير فقط من الاسم الكامل ووضعهما في أعمدة مختلفة، يمكنك تطبيق إحدى الطرق التالية.

1) تقسيم الاسم الكامل إلى الاسم الأول والاسم الأخير باستخدام الصيغ

تحتاج إلى تطبيق صيغتين منفصلتين لتقسيم الاسم الكامل إلى الاسم الأول والاسم الأخير.

تقسيم الاسم الأول من الاسم الكامل

يمكنك تطبيق صيغة تعتمد على دالتي LEFT وSEARCH لتقسيم الاسم الأول من الاسم الكامل.

صيغة عامة

=LEFT(cell, SEARCH(" ", cell) -1)

1. حدد خلية لإخراج الاسم الأول.

2. انسخ أو أدخل الصيغة أدناه واضغط على مفتاح الإدخال. حدد خلية النتيجة هذه واسحب مقبض التعبئة التلقائية للأسفل لتقسيم الأسماء الأولى من الأسماء الكاملة الأخرى.

=LEFT(B5, SEARCH(" ", B5) -1)

الآن قمت بتقسيم جميع الأسماء الأولى من الأسماء الكاملة في النطاق المحدد، تابع تطبيق الصيغة أدناه لتقسيم الأسماء الأخيرة.

تقسيم الاسم الأخير من الاسم الكامل

صيغة عامة

=RIGHT(cell, LEN(cell) - SEARCH("^", SUBSTITUTE(cell," ", "^", LEN(cell) - LEN(SUBSTITUTE(cell, " ", "")))))

1. حدد خلية بجوار خلية الاسم الأول.

2. انسخ أو أدخل الصيغة أدناه واضغط على مفتاح الإدخال. حدد خلية النتيجة هذه واسحب مقبض التعبئة التلقائية للأسفل للحصول على الأسماء الأخيرة من الأسماء الكاملة الأخرى.

=RIGHT(B5, LEN(B5) - SEARCH("^", SUBSTITUTE(B5," ", "^", LEN(B5) - LEN(SUBSTITUTE(B5, " ", "")))))

ملاحظة: في الصيغ، B5 هي خلية الاسم الكامل التي ترغب في تقسيمها. يمكنك تغييرها حسب الحاجة.

2) تقسيم الاسم الكامل إلى الاسم الأول والاسم الأخير باستخدام أداة مذهلة

قد يكون من الصعب تذكر الصيغ للعديد من مستخدمي Excel. هنا، نوصي باستخدام ميزة تقسيم الأسماء في Kutools لـ Excel. باستخدام هذه الميزة، يمكنك بسهولة تقسيم الاسم الكامل إلى الاسم الأول والاسم الأخير بعدة نقرات فقط.

1. حدد نطاق خلايا الأسماء الكاملة، ثم انقر Kutools > دمج & تقسيم > تقسيم الأسماء.

2. في مربع حوار تقسيم الأسماء، ضع علامة فقط على مربعي الاسم الأول و الاسم الأخير في قسم نوع التقسيم، ثم انقر موافق.

نصيحة: يظهر النطاق المحدد في مربع نطاق التقسيم، ويمكنك تغييره حسب الحاجة.

3. ثم يظهر مربع حوار تقسيم الأسماء آخر، حدد خلية وجهة وانقر موافق.

بعد ذلك، سيتم تقسيم الاسم الكامل في الخلايا المحددة إلى الاسم الأول والاسم الأخير دفعة واحدة كما هو موضح في الصورة أدناه.

تقسيم الاسم الكامل إلى الاسم الأول والاسم الأوسط والاسم الأخير

كما هو موضح في الصورة أدناه، يوجد عمود أسماء كاملة مفصول بين الاسم الأول والاسم الأوسط والاسم الأخير بمسافة واحدة. لتقسيم الاسم الكامل إلى الاسم الأول والاسم الأوسط والاسم الأخير ووضعهم في أعمدة مختلفة، يمكن للطرق أدناه مساعدتك.

1) تقسيم الاسم الكامل إلى الاسم الأول والاسم الأوسط والاسم الأخير باستخدام تقسيم البيانات

الميزة المدمجة – تقسيم البيانات يمكن أن تساعدك بسهولة على تقسيم الاسم الكامل إلى الاسم الأول والاسم الأوسط والاسم الأخير في Excel.

يمكنك اتباع الخطوات المذكورة أعلاه لتطبيق ميزة تقسيم البيانات.

ملاحظة: في الخطوة2 من3 في المعالج، ضع علامة فقط على مربع المسافة.

2) تقسيم الاسم الكامل إلى الاسم الأول والاسم الأوسط والاسم الأخير باستخدام الصيغ

يمكنك أيضًا تطبيق الصيغ لتقسيم الاسم الكامل إلى الاسم الأول والاسم الأوسط والاسم الأخير في Excel.

الصيغ العامة المستخدمة لتقسيم الاسم الكامل

تقسيم الاسم الأول

=LEFT(cell,SEARCH(" ", cell)-1)

تقسيم الاسم الأوسط

=MID(cell, SEARCH(" ", cell) +1, SEARCH(" ", cell, SEARCH(" ", cell)+1) - SEARCH(" ", cell)-1)

تقسيم الاسم الأخير

=RIGHT(cell,LEN(cell) - SEARCH(" ",cell, SEARCH(" ",cell,1)+1))

ثم طبق الصيغ في خلايا مختلفة للحصول على الاسم الأول والاسم الأوسط والاسم الأخير.

1. في الخلية D5، أدخل الصيغة أدناه واضغط على مفتاح الإدخال. حدد خلية النتيجة هذه واسحب مقبض التعبئة التلقائية للأسفل للحصول على الاسم الأول للأسماء الكاملة الأخرى.

=LEFT(B5,SEARCH(" ", B5)-1)

2. أدخل الصيغة أدناه في الخلية E5 واضغط على مفتاح الإدخال للحصول على الاسم الأوسط الأول. حدد خلية النتيجة واسحب مقبض التعبئة التلقائية للأسفل للحصول على الأسماء الوسطى الأخرى.

=MID(B5, SEARCH(" ", B5) +1, SEARCH(" ", B5, SEARCH(" ", B5)+1) - SEARCH(" ", B5)-1)

3. للحصول على الأسماء الأخيرة، أدخل الصيغة أدناه في الخلية F5 واضغط إدخال، ثم حدد خلية النتيجة واسحب مقبض التعبئة التلقائية على الخلايا التي تحتاجها.

=RIGHT(B5,LEN(B5) - SEARCH(" ",B5, SEARCH(" ",B5,1)+1))

3) تقسيم الاسم الكامل إلى الاسم الأول والاسم الأوسط والاسم الأخير باستخدام أداة مذهلة

هنا نقدم ميزة تقسيم الأسماء في Kutools لـ Excel، والتي تتيح لك تقسيم الاسم الكامل إلى الاسم الأول والاسم الأوسط والاسم الأخير دفعة واحدة بعدة نقرات فقط.

1. حدد خلايا الأسماء الكاملة التي ترغب في تقسيمها، ثم انقر Kutools > دمج & تقسيم > تقسيم الأسماء.

2. في مربع حوار تقسيم الأسماء، تحتاج إلى ضبط الإعدادات كما يلي.

3. في مربع حوار تقسيم الأسماء التالي، حدد خلية وجهة لإخراج النصوص المفصولة، ثم انقر موافق. انظر العرض أدناه.

مثال #8 تقسيم النصوص والأرقام في الخلايا

افترض أن هناك قائمة من السلاسل النصية تحتوي على نصوص وأرقام مختلطة كما هو موضح في الصورة أدناه، لفصل النصوص والأرقام ووضعها في أعمدة مختلفة، نقدم لك أربع طرق.

تقسيم النصوص والأرقام باستخدام الصيغ

باستخدام الصيغ التالية، يمكنك تقسيم النصوص والأرقام من خلية واحدة إلى خليتين منفصلتين.

صيغ عامة

الحصول على النص من الخلية

=LEFT(cell,MIN(FIND({0,1,2,3,4,5,6,7,8,9},cell&"0123456789"))-1)

الحصول على الأرقام من الخلية

=RIGHT(cell,LEN(B5)-MIN(FIND({0,1,2,3,4,5,6,7,8,9},cell&"0123456789"))+1)

ثم طبق هاتين الصيغتين في خلايا مختلفة للحصول على النصوص والأرقام منفصلة.

1. حدد خلية فارغة لوضع نص أول سلسلة نصية في القائمة، ثم انسخ أو أدخل الصيغة أدناه واضغط على مفتاح الإدخال. حدد خلية النتيجة واسحب مقبض التعبئة التلقائية للأسفل للحصول على نص السلاسل النصية الأخرى في القائمة.

=LEFT(B5,MIN(FIND({0,1,2,3,4,5,6,7,8,9},B5&"0123456789"))-1)

2. حدد خلية (E5) بجوار خلية النتيجة الأولى (D5)، ثم انسخ أو أدخل الصيغة أدناه واضغط إدخال. حدد خلية النتيجة واسحب مقبض التعبئة التلقائية للأسفل للحصول على أرقام السلاسل النصية الأخرى في القائمة.

=RIGHT(B5,LEN(B5)-MIN(FIND({0,1,2,3,4,5,6,7,8,9},B5&"0123456789"))+1)

تقسيم النصوص والأرقام باستخدام التعبئة السريعة (إصدار2013 وما بعده)

إذا كنت تستخدم Excel2013 أو الإصدارات الأحدث، يمكنك تطبيق ميزة التعبئة السريعة المدمجة لتقسيم النصوص والأرقام من خلية واحدة إلى عمودين.

ملاحظة: لجعل ميزة التعبئة السريعة تعمل، يجب وضع أعمدة النتائج بجوار عمود السلسلة النصية الأصلية. على سبيل المثال، إذا كانت السلاسل النصية الأصلية في العمود B، يجب وضع النصوص والأرقام المفصولة في العمودين C وD. انظر الصورة:

1. اكتب يدويًا نص أول خلية سلسلة نصية (D5) في الخلية C5.

2. استمر في كتابة نص الخلية الثانية (D6) في الخلية C6.

3. فعّل الخلية C7، ثم انقر البيانات > التعبئة السريعة.

بعد ذلك، يتم ملء نصوص السلاسل النصية الأخرى تلقائيًا في الخلايا كما هو موضح في الصورة أدناه.

4. كرر الخطوات من1 إلى3 للحصول على الأرقام في العمود D.

ملاحظات:

تقسيم النصوص والأرقام باستخدام دالة معرفة من قبل المستخدم

إذا لم تكن السلاسل النصية في القائمة منتظمة، فقد تعطي الطريقتان السابقتان نتائج خاطئة كما هو موضح في الصورة أدناه.

هنا، نقدم دالة معرفة من قبل المستخدم لمساعدتك على تقسيم النصوص والأرقام من خلية إلى عمودين بغض النظر عن مكان وجود الأرقام في السلسلة النصية. انظر الصورة:

1. اضغط على مفاتيح Alt + F11.

2. في نافذة Microsoft Visual Basic for Applications المفتوحة، انقر إدراج > وحدة نمطية، ثم انسخ كود VBA أدناه إلى نافذة الكود.

كود VBA: تقسيم النصوص والأرقام من خلية إلى عمودين

Public Function SplitText(pWorkRng As Range, pIsNumber As Boolean) As String
'Update by Extendoffice 20211105
Dim xLen As Long
Dim xStr As String
xLen = VBA.Len(pWorkRng.Value)
For i = 1 To xLen
    xStr = VBA.Mid(pWorkRng.Value, i, 1)
    If ((VBA.IsNumeric(xStr) And pIsNumber) Or (Not (VBA.IsNumeric(xStr)) And Not (pIsNumber))) Then
        SplitText = SplitText + xStr
    End If
Next
End Function

3. اضغط على مفاتيح Alt + Q لإغلاق نافذة Microsoft Visual Basic for Applications.

4. حدد خلية لإخراج نص أول سلسلة نصية، ثم أدخل الصيغة أدناه واضغط على مفتاح الإدخال. حدد خلية النتيجة واسحب مقبض التعبئة التلقائية للأسفل للحصول على نص السلاسل النصية الأخرى في نفس القائمة.

=SplitText(B5,FALSE)

5. حدد خلية بجوار خلية نتيجة النص الأولى لإخراج الأرقام، ثم أدخل الصيغة أدناه واضغط على مفتاح الإدخال. حدد خلية النتيجة واسحب مقبض التعبئة التلقائية للأسفل للحصول على أرقام السلاسل النصية الأخرى.

=SplitText(B5,TRUE)

تقسيم النصوص والأرقام باستخدام أداة مذهلة

هنا، نوصي بأسهل طريقة لتقسيم النصوص والأرقام دفعة واحدة من خلية إلى عمودين. تطبيق ميزة تقسيم الخلايا في Kutools لـ Excel يساعدك على معالجة هذه المشكلة بعدة نقرات فقط.

1. حدد خلايا السلاسل النصية التي ترغب في تقسيم النصوص والأرقام فيها إلى عمودين.

2. انقر Kutools > دمج & تقسيم > تقسيم الخلايا.

3. في مربع حوار تقسيم الخلايا، تحتاج إلى ضبط الإعدادات التالية.

3.1) النطاق المحدد يظهر في نطاق التقسيم المربع، ويمكنك النقر على زر لتحديد نطاق جديد حسب الحاجة؛

3.2) في قسم النوع، اختر تقسيم إلى صفوف أو تقسيم البيانات؛

3.3) في قسم الفاصل، اختر زر الراديو تقسيم حسب النص والرقم؛

3.4) انقر على زر موافق.

4. في مربع حوار تقسيم الخلايا التالي، حدد خلية لإخراج النصوص والأرقام المفصولة، ثم انقر على زر موافق.

بعد ذلك، يمكنك رؤية النصوص والأرقام في الخلايا المحددة تم تقسيمها إلى عمودين دفعة واحدة كما هو موضح في الصورة أدناه.

2. تقسيم الخلايا الرقمية

يصف هذا الجزء كيفية تقسيم الخلايا الرقمية في حالتين: تقسيم رقم مكون من أكثر من رقم إلى أرقام فردية وتقسيم الرقم عند العلامة العشرية لفصل الجزء الصحيح عن الجزء العشري.

مثال #1: تقسيم الخلايا حسب الأرقام

إذا كنت ترغب في تقسيم رقم مكون من أكثر من رقم إلى أرقام فردية في أعمدة مختلفة، جرب إحدى الطرق أدناه.

تقسيم الرقم في خلية إلى أرقام فردية باستخدام الصيغة

يمكن أن تساعدك الصيغة أدناه على تقسيم الرقم إلى أرقام فردية ووضعها في أعمدة مختلفة.

صيغة عامة

=MID($A1, COLUMNS($A$1:A$1),1)

المعامل

1. حدد خلية فارغة لإخراج الرقم الأول، ثم أدخل الصيغة أدناه واضغط على مفتاح الإدخال.

=MID($B3, COLUMNS($B$3:B$3),1)

2. حدد خلية النتيجة هذه واسحب مقبض التعبئة التلقائية إلى اليمين للحصول على الأرقام الأخرى. احتفظ بجميع خلايا النتائج محددة، ثم اسحب مقبض التعبئة التلقائية للأسفل للحصول على الأرقام الفردية للأرقام الأخرى.

ملاحظة: في هذه الصيغة، B3 هي الخلية التي تحتوي على الرقم المراد تقسيمه إلى أرقام فردية، ويمكنك تغييرها حسب الحاجة.

تقسيم الرقم في خلية إلى أرقام فردية باستخدام VBA

يمكن أن يساعدك كود VBA أدناه أيضًا على تقسيم الرقم في خلية إلى أرقام فردية في Excel. يمكنك اتباع الخطوات التالية.

1. اضغط على مفاتيح Alt + F11 لفتح نافذة Microsoft Visual Basic for Applications.

2. في نافذة Microsoft Visual Basic for Applications، انقر إدراج > وحدة نمطية، ثم انسخ كود VBA أدناه إلى نافذة الكود.

كود VBA: تقسيم الرقم إلى أرقام فردية في Excel

Sub SplitNumberIntoDigits()
'Updateby Extendoffice 2021118
Dim Rng As Range
Dim InputRng As Range, OutRng As Range
xTitleId = "Kutools for Excel"
Set InputRng = Application.Selection
Set InputRng = Application.InputBox("Range :", xTitleId, InputRng.Address, Type:=8)
Set OutRng = Application.InputBox("Out put to (single cell):", xTitleId, Type:=8)
 xInt = InputRng.Row

Application.ScreenUpdating = False

For Each Rng In InputRng
    xValue = Rng.Value
    xRow = (Rng.Row - xInt) + 1
    For I = 1 To VBA.Len(xValue)
        OutRng.Cells(xRow, I).Value = VBA.Mid(xValue, I, 1)
    Next
Next
Application.ScreenUpdating = True
End Sub

3. اضغط على مفتاح F5 لتشغيل الكود، ثم تظهر نافذة Kutools لـ Excel، تحتاج إلى تحديد نطاق الخلايا الرقمية التي ستقوم بتقسيمها ثم انقر على زر موافق.

4. تظهر نافذة Kutools لـ Excel ثانية، تحتاج إلى تحديد خلية لإخراج الأرقام الفردية، ثم انقر موافق.

ملاحظة: يمكن لهذا الكود أيضًا تقسيم الكلمة إلى أحرف فردية.

بعد ذلك، يتم تقسيم الأرقام في الخلايا المحددة إلى أرقام فردية وتوضع في أعمدة مختلفة.

تقسيم الرقم بسهولة إلى أرقام فردية باستخدام أداة مذهلة

تعد ميزة تقسيم الخلايا في Kutools لـ Excel أداة عملية لمساعدتك على تقسيم الرقم بسهولة إلى أرقام فردية في Excel.

1. بعد تثبيت Kutools لـ Excel، حدد نطاق الخلايا الرقمية التي ستقوم بتقسيمها، ثم انقر Kutools > دمج & تقسيم > تقسيم الخلايا.

2. في مربع حوار تقسيم الخلايا، قم بالإعدادات التالية.

2.1) في نطاق التقسيم القسم، يمكنك رؤية النطاق الذي حددته معروضًا في مربع النص. يمكنك النقر على زر لتغيير النطاق حسب الحاجة؛

2.2) في قسم النوع، اختر تقسيم إلى صفوف أو تقسيم البيانات حسب احتياجك؛

2.3) في قسم الفاصل، اختر زر الراديو تحديد العرض، ثم أدخل الرقم1 في مربع النص؛

2.4) انقر على زر موافق.

3. في مربع حوار تقسيم الخلايا المفتوح، حدد خلية فارغة لإخراج الأرقام، ثم انقر على زر موافق.

بعد ذلك، يتم تقسيم الأرقام في الخلايا المحددة إلى أرقام فردية دفعة واحدة.

مثال #2 تقسيم الرقم عند العلامة العشرية

يناقش هذا القسم عدة طرق لتقسيم الرقم إلى جزء صحيح وجزء عشري في Excel.

تقسيم الرقم عند العلامة العشرية باستخدام الصيغ

يمكن تطبيق دالة TRUNC لتقسيم الرقم عند العلامة العشرية في Excel. يمكنك اتباع الخطوات التالية.

صيغ عامة

الحصول على الجزء الصحيح

=TRUNC(A1)

الحصول على الجزء العشري

=A1-TRUNC(A1)

المعامل

الآن يمكنك تطبيق هاتين الصيغتين لتقسيم الأرقام في نطاق محدد من الخلايا عند العلامة العشرية في Excel.

1. حدد خلية لوضع الجزء الصحيح لأول خلية رقمية، ثم أدخل الصيغة أدناه واضغط على مفتاح الإدخال. حدد خلية النتيجة واسحب مقبض التعبئة التلقائية للأسفل للحصول على الأجزاء الصحيحة للخلايا الرقمية الأخرى.

=TRUNC(B5)

2. حدد خلية بجوار خلية النتيجة الأولى لوضع الجزء العشري، ثم أدخل الصيغة أدناه واضغط على مفتاح الإدخال. حدد خلية النتيجة هذه واسحب مقبض التعبئة التلقائية للأسفل للحصول على الأجزاء العشرية للخلايا الرقمية الأخرى.

=B5-TRUNC(B5)

تقسيم الرقم عند العلامة العشرية باستخدام تقسيم البيانات

يمكنك تطبيق ميزة تقسيم البيانات لتقسيم الرقم عند العلامة العشرية في Excel.

1. حدد نطاق الخلايا الرقمية التي ستقوم بتقسيمها عند العلامة العشرية، ثم انقر البيانات > تقسيم البيانات.

2. في مربع الحوار معالج تقسيم البيانات – الخطوة1 من3، اختر زر الراديو الفاصل وانقر على زر التالي.

3. في مربع الحوار الخطوة2 من3، ضع علامة فقط على مربع آخر، ثم أدخل نقطة في مربع النص، ثم انقر على زر التالي.

4. في الخطوة3 من3 مربع الحوار، انقر على زر لتحديد خلية وجهة لإخراج الأجزاء الصحيحة والعشرية، وأخيرًا انقر على إنهاء زر. انظر الصورة:

بعد ذلك، يمكنك رؤية أن الأجزاء الصحيحة والعشرية تم تقسيمها من الخلايا المحددة كما هو موضح في الصورة أدناه. ومع ذلك، يفقد الجزء العشري إشارته السالبة والتي قد تكون ضرورية للمستخدم.

تقسيم الرقم عند العلامة العشرية باستخدام التعبئة السريعة (إصدار2013 وما بعده)

في المثال أعلاه قدمنا استخدام وظيفة التعبئة السريعة لتقسيم النصوص والأرقام في الخلايا، وهنا سنقدم نفس الطريقة لتقسيم الرقم عند العلامة العشرية.

1. أدخل بعض الأمثلة. في هذا المثال، أدخل الجزء الصحيح من B5 في C5، وأدخل الجزء الصحيح من B6 في C6. انظر الصورة:

ملاحظة: بالنسبة للأرقام السالبة، لا تنس إدخال إشارة السالب معها.

3. حدد الخلايا بما في ذلك الأمثلة في العمود الذي ترغب في تعبئته، ثم انقر البيانات > التعبئة السريعة.

بعد ذلك، يتم استخراج الأجزاء الصحيحة من الخلايا الرقمية المحددة كما هو موضح في الصورة أدناه.

4. كرر الخطوات أعلاه لتقسيم الأجزاء العشرية من نفس الخلايا الرقمية.

3. تقسيم خلايا التاريخ

حالة أخرى شائعة هي تقسيم خلايا التاريخ. إذا كنت بحاجة إلى تقسيم خلايا التاريخ إلى يوم، شهر وسنة منفصلة، أو تقسيم خلايا التاريخ إلى تاريخ ووقت منفصلين، استخدم الحل التالي حسب احتياجك.

مثال #1 تقسيم خلايا التاريخ إلى يوم، شهر وسنة منفصلة

افترض أن لديك قائمة تواريخ في النطاق B5:B9، وترغب في تقسيم كل قيمة تاريخ إلى ثلاثة أعمدة منفصلة لليوم والشهر والسنة. إليك ثلاث طرق لمساعدتك على تحقيق نتيجة تقسيم التواريخ.

تقسيم خلايا التاريخ إلى يوم، شهر وسنة باستخدام الصيغ

يمكنك تطبيق ثلاث صيغ تعتمد على دالة التاريخ، ودالة الشهر، ودالة السنة لتقسيم التاريخ إلى يوم، شهر وسنة منفصلة في Excel.

صيغ عامة

=DATE(A1)

=MONTH(A1)

=YEAR(A1)

المعامل

1. أنشئ ثلاثة أعمدة لوضع اليوم والشهر والسنة منفصلين.

2. حدد أول خلية في عمود اليوم، ثم أدخل الصيغة أدناه واضغط على مفتاح الإدخال للحصول على يوم أول خلية تاريخ (B5). حدد خلية النتيجة هذه واسحب مقبض التعبئة التلقائية للأسفل للحصول على الأيام للخلايا الأخرى.

=DAY(B5)

3. قم بنفس العملية كما في الخطوة1 لتطبيق الصيغ التالية في عمودي الشهر والسنة للحصول على الشهر والسنة منفصلين من خلايا التاريخ.

الحصول على شهر التاريخ

=MONTH(B5)

الحصول على سنة التاريخ

=YEAR(B5)

تقسيم خلايا التاريخ إلى يوم، شهر وسنة باستخدام تقسيم البيانات

يمكنك اتباع الخطوات أعلاه لتطبيق ميزة تقسيم البيانات لتقسيم خلايا التاريخ إلى يوم، شهر وسنة منفصلة في Excel.

ملاحظة: في مربع الحوار الخطوة2 من3، ضع علامة فقط على مربع آخر، وأدخل رمز / في مربع النص.

تقسيم خلايا التاريخ إلى يوم، شهر وسنة باستخدام أداة مذهلة

يوضح العرض أدناه كيفية تقسيم التاريخ إلى شهر ويوم وسنة منفصلة باستخدام ميزة تقسيم الخلايا في Kutools لـ Excel.

تساعدك هذه الميزة على تحقيق نتيجة تقسيم التواريخ دفعة واحدة بعدة نقرات فقط.

انقر لمعرفة المزيد عن هذه الميزة.

مثال #2 تقسيم التاريخ والوقت في خلية واحدة

افترض أن هناك قائمة تواريخ وأوقات في B5:B9، وترغب في تقسيم التواريخ والأوقات إلى أعمدة منفصلة، سيعرض هذا القسم طرقًا مختلفة لمساعدتك على إنجاز ذلك.

تقسيم التاريخ والوقت في خلية واحدة باستخدام الصيغة

يمكنك تطبيق الصيغ التالية لتقسيم التاريخ والوقت إلى أعمدة مختلفة في Excel.

1. جهز عمودين لوضع التواريخ والأوقات.

2. تحتاج إلى تعيين خلايا عمود التاريخ إلى تنسيق التاريخ، وخلايا عمود الوقت إلى تنسيق الوقت.

3. حدد أول خلية في عمود التاريخ، ثم أدخل الصيغة أدناه واضغط على مفتاح الإدخال للحصول على تاريخ B5. حدد خلية النتيجة هذه واسحب مقبض التعبئة التلقائية للأسفل للحصول على التواريخ الأخرى.

=INT(B5)

4. طبق الصيغة التالية في عمود الوقت للحصول على الأوقات في B5:B9.

=B5-D5

تقسيم التاريخ والوقت في خلية واحدة باستخدام التعبئة السريعة (إصدار2013 وما بعده)

إذا كنت تستخدم Excel2013 أو الإصدارات الأحدث، يمكنك تطبيق ميزة التعبئة السريعة المدمجة لتقسيم التاريخ والوقت إلى أعمدة مختلفة.

1. أنشئ عمودي التاريخ والوقت وأدخل بعض الأمثلة التي ترغب في إخراجها. في عمود التاريخ، أدخل تاريخ B5 في C5، وأدخل تاريخ B6 في C6. في عمود الوقت، أدخل وقت B5 في D5 ووقت B6 في D6. انظر الصورة:

2. حدد عمود التاريخ (بما في ذلك الأمثلة) الذي ترغب في تعبئته، ثم انقر البيانات > التعبئة السريعة.

3. حدد عمود الوقت (بما في ذلك الأمثلة) الذي ترغب في تعبئته، ثم فعّل ميزة التعبئة السريعة أيضًا. بعد ذلك، يتم تقسيم التواريخ والأوقات في B5:B9 إلى أعمدة منفصلة كما هو موضح في العرض أدناه.

الآن، تعلمت كيفية تقسيم الخلايا في Excel بطرق مختلفة وفي مواقف مختلفة. ستتمكن من اتخاذ القرار الأفضل لتحديد الطريقة الأنسب حسب السيناريو الخاص بك.