برنامج تعليمي لـ Excel – استخراج النص أو رقم حسب موضع معيّن

في العديد من الحالات، قد تحتاج فقط إلى استخراج المحتوى المفيد من جملة أو سلسلة نصية موجودة في خلية—مثل استخراج اسم المقاطعة من عنوان، أو عنوان البريد الإلكتروني من جملة، أو رقم فاتورة الشحن من محادثة، وغير ذلك. ويُركّز هذا البرنامج التعليمي على الاستخراج من موضع معيّن داخل الخلية، ويجمع بين طرق مختلفة تساعدك على استخراج النصوص أو الأرقام من خلية وفقًا لموقعها المحدّد في Excel.

استخراج النص حسب الموضع

يجمع هذا القسم أكثر المواضع شيوعًا التي يمكن استخراج النص منها من خلية، ويقدّم الطرق المثلى للتعامل معها خطوة بخطوة. تصفّح المزيد من التفاصيل الآن!

1. استخراج الأرقام من اليسار أو اليمين حسب عدد الأحرف المحدَّد

لاستخراج الأرقام أو عدد الأحرف من الجانب الأيسر أو الأيمن لسلسلة نصية، جرّب إحدى الطرق أدناه.

1.1 استخراج أول N أحرف أو آخر N أحرف باستخدام الصيغ

افترض أن لديك قائمةً من السلاسل النصية في العمود B، كما هو موضح في لقطة الشاشة أدناه. وللاستخراج الأول حرفين والآخر حرفين من كل سلسلة، يمكنك تطبيق الصيغ التالية.

استخراج أول N أحرف من سلسلة نصية

تُمكّنك دالة LEFT من استخراج أول N أحرف من سلسلة نصية في Excel بسهولة تامة.

الصيغة العامة

=LEFT(text_string,[num_chars])

المعاملات

الآن يمكنك تطبيق هذه الصيغة لاستخراج أول حرفين من الخلايا في العمود B.

1. حدد خلية فارغة، ثم انسخ أو أدخل الصيغة أدناه واضغط مفتاح «Enter» للحصول على النتيجة الأولى. بعد ذلك، حدد خلية النتيجة واسحب مقبض التعبئة التلقائي (AutoFill Handle) لأسفل لتطبيق الصيغة على الخلايا الأخرى.

=LEFT(B5,2)

الآن، قمت باستخراج أول حرفين من كل خلية ضمن النطاق المحدد.

استخراج آخر N أحرف من سلسلة نصية

هنا نستخدم دالة RIGHT لاستخراج آخر N حرفًا من سلسلة نصية في Excel.

الصيغة العامة

=RIGHT(text_string,[num_chars])

المعاملات

حدد خلية فارغة، ثم انْسخ أو أدخِل الصيغة أدناه واضغط مفتاح «Enter» للحصول على النتيجة. بعد ذلك، حدد خلية النتيجة واسحب مقبض التعبئة التلقائي لأسفل لعرض باقي النتائج.

=RIGHT(B5,2)

1.2 استخراج أول N أحرف أو آخر N أحرف باستخدام أداة رائعة

رغم أن الصيغ أعلاه بسيطة، إلا أنه عند استخراج أول N أحرف أو آخر N أحرف من قائمة طويلة من السلاسل النصية، لا يزال عليك سحب مقبض التعبئة التلقائي من الأعلى إلى الأسفل — وهو أمر قد يستغرق وقتًا طويلاً. لذا، نوصيك باستخدام أداة «Kutools لـ Excel» المميزة:استخراج النص، لمساعدتك على استخراج أول N أحرف أو آخر N أحرف من قائمة السلاسل النصية دفعة واحدة وبسهولة.

1. حدد مسبقًا قائمة السلاسل النصية التي ترغب في استخراج النص منها، ثم انقر على «Kutools» > «Text» > «استخراج النص».

2. في مربع الحوار المنبثق «استخراج النص»، يُرجى تهيئة الإعدادات على النحو التالي.

ملاحظة: لجعل النتيجة ديناميكية عند تغيُّر السلسلة النصية، يمكنك تحديد خانة الاختيار «إدراج كصيغة».

3. في مربع الحوار المنبثق «استخراج النص»، اختر الخلية التي تريد إخراج الأحرف المستخرَجة إليها، ثم انقر فوق «موافق».

بعد ذلك، يتم استخراج أول N حرفًا أو آخر N حرفًا من الخلايا المحددة دفعةً واحدة.

انقر لمعرفة المزيد عن هذه الميزة.

2. استخراج النص الذي يسبق أو يتبع حرفًا أو كلمة معيّنة

للاستخراج النص قبل أو بعد حرف أو كلمة معيّنة، تلبّي السيناريوهات المختلفة في هذا القسم احتياجاتك.

2.1 استخراج النص قبل أو بعد المحدِّد الأول (حرف)

كما هو موضح في لقطة الشاشة أدناه، لاستخراج النص قبل أو بعد المُحدِّد الأول من كل خلية في النطاق B4:B10، يمكنك تطبيق إحدى الطرق التالية.

2.1.1 استخراج النص قبل المحدِّد الأول باستخدام صيغة

يمكنك تطبيق صيغة تعتمد على دالتَي LEFT وFIND لاستخراج النص الموجود قبل المُحدِّد الأول في الخلية. اتبع الخطوات أدناه لإتمام هذه العملية بسهولة.

الصيغة العامة

=LEFT(text_string,FIND(«delimiter»,text_string,1)-1)

المعاملات

حدد خلية فارغة، ثم انسخ أو أدخل الصيغة أدناه واضغط مفتاح «Enter» للحصول على النتيجة الأولى. بعد ذلك، حدد الخلية التي تحتوي على النتيجة الأولى، واسحب مقبض التعبئة التلقائي لأسفل لاستخراج النصوص الواقعة قبل المحدِّد الأول في الخلايا الأخرى.

=LEFT(B5,FIND("-",B5,1)-1)

2.1.2 استخراج النص بعد المحدِّد الأول باستخدام صيغة

تساعدك الصيغة أدناه على استخراج النص الموجود بعد أول مُحدِّد في خلية Excel.

الصيغة العامة

=MID(text_string,FIND(«delimiter»,text_string)+1,LEN(text_string))

المعاملات

=MID(B5,FIND("-",B5)+1,LEN(B5))

2.1.3 استخراج النص قبل أو بعد المحدِّد الأول باستخدام أداة رائعة

هنا، نوصي بشدة بأداة «استخراج النص» من «Kutools لـ Excel»، التي تتيح لك استخراج النص بسهولة قبل أو بعد المحدِّد الأول من نطاق الخلايا دفعةً واحدة.

1. حدد نطاق الخلايا الذي تريد استخراج النص منه، ثم انقر فوق «Kutools» > «Text» > «استخراج النص».

2. في مربع حوار «استخراج النص»، قم بتكوين الإعدادات على النحو التالي.

ملاحظة: لجعل النتيجة ديناميكية تتغيّر تلقائيًا عند تعديل السلسلة النصية، فعّل خانة الاختيار «إدراج كصيغة».

3. بعد ذلك، يظهر مربع حوار «استخراج النص»—اختر خلية لإخراج النتائج وانقر فوق «موافق».

بعد ذلك، يتم استخراج النصوص دفعةً واحدة من الخلايا المحددة، إما قبل المحدد الأول أو بعده.

لمعرفة المزيد عن هذه الميزة، يُرجى زيارة: استخراج نص معين بسرعة من الخلايا في Excel.

2.2 استخراج النص قبل أو بعد المحدِّد الأخير (حرف)

في الخطوات السابقة، تعلّمنا الطرق الخاصة باستخراج النص قبل أو بعد المُحدِّد الأول من خلية. وكما يظهر في لقطة الشاشة أدناه، سيعرض هذا القسم صيغتين لاستخراج النص قبل أو بعد المُحدِّد الأخير من الخلية—يمكنك اتباع الخطوات التالية لإتمام هذه المهمة بسهولة.

2.2.1 استخراج النص قبل المحدِّد الأخير باستخدام صيغة

لاستخراج النص قبل المحدِّد الأخير من خلية، استخدم دوال SEARCH وLEN وSUBSTITUTE داخل دالة LEFT.

الصيغة العامة

=LEFT(text_string,SEARCH(«#»,SUBSTITUTE(text_string,«delimiter»,«#»,LEN(text_string)-LEN(SUBSTITUTE(text_string,«delimiter»,«»))))-1)

المعاملات

حدد خليةً، وأدخل الصيغة أدناه، ثم اضغط مفتاح «Enter» للحصول على النتيجة. بعد ذلك، حدد خلية النتيجة واسحب مقبض التعبئة التلقائي لأسفل لاستخراج النصوص من سلاسل النصوص الأخرى في نفس العمود.

=LEFT(B5,SEARCH("#",SUBSTITUTE(B5,"-","#",LEN(B5)-LEN(SUBSTITUTE(B5,"-",""))))-1)

2.2.2 استخراج النص بعد المحدِّد الأخير باستخدام صيغة

بعد استخراج النص الذي يسبق المُحدِّد الأخير من الخلية، يمكنك استخدام الصيغة أدناه لاستخراج النص التالي للمُحدِّد الأخير وفقًا لاحتياجاتك.

الصيغة العامة

=RIGHT(text_string,LEN(text_string)-SEARCH(«#»,SUBSTITUTE(text_string,«delimiter»,«#»,LEN(text_string)-LEN(SUBSTITUTE(text_string,«delimiter»,«»)))))

المعاملات

حدد خليةً، وأدخل الصيغة أدناه، ثم اضغط مفتاح «Enter» للحصول على النتيجة. بعد ذلك، حدد خلية النتيجة واسحب مقبض التعبئة التلقائي لأسفل لاستخراج النصوص من سلاسل النصوص الأخرى في نفس العمود.

=RIGHT(B5,LEN(B5)-SEARCH("#",SUBSTITUTE(B5,"-","#",LEN(B5)-LEN(SUBSTITUTE(B5,"-","")))))

2.3 استخراج النص بعد الحرف الـn

انظر إلى المثال أدناه: هناك قائمة من سلاسل نصية في النطاق B4:B10، وللاستخراج النص بعد الحرف الثالث من كل خلية، يمكنك استخدام صيغة تعتمد على دالتَي MID وLEN.

الصيغة العامة

=MID(text_string,nth_char+1,LEN(text_string))

المعاملات

حدد خلية فارغة، ثم انسخ أو أدخل الصيغة أدناه واضغط مفتاح «Enter» للحصول على النتيجة. بعد ذلك، حدد خلية النتيجة واسحب مقبض التعبئة التلقائي لأسفل لعرض باقي النتائج.

=MID(B5,3+1,LEN(B5))

2.4 استخراج الكلمة الـn من سلسلة نصية

بافتراض أن لديك قائمة من السلاسل النصية كما في لقطة الشاشة أدناه، وترغب في استخراج الكلمة التي تحتل المرتبة n فقط من كل سلسلة نصية، يقدّم لك هذا القسم ثلاث طرق فعّالة لتحقيق ذلك.

2.4.1 استخراج الكلمة ذات الرقم n باستخدام صيغة

يمكنك دمج دوال TRIM وMID وSUBSTITUTE وREPT وLEN لاستخراج الكلمة التي تحتل المرتبة n من سلسلة نصية موجودة في خلية.

الصيغة العامة

=TRIM(MID(SUBSTITUTE(text_string,« »,REPT(« »,LEN((text_string))), (N-1)*LEN((text_string)+1, LEN((text_string)))

المعاملات

في هذه الحالة، يحتوي النطاق B5:B10 على السلاسل النصية، بينما يحتوي النطاق D5:D10 على الأرقام التي تمثّل رقم الكلمة (n). لذا، دعنا نطبّق هذه الصيغة لاستخراج الكلمة ذات الرقم n من كل سلسلة نصية.

اختر خلية فارغة، ثم انْسخ أو أدخِل الصيغة أدناه فيها واضغط مفتاح «Enter» للحصول على أول نتيجة. بعد ذلك، حدد خلية النتيجة هذه واسحب مقبض التعبئة التلقائي (AutoFill Handle) لأسفل لاستخراج الكلمة ذات الرقم n من الخلايا الأخرى.

=TRIM(MID(SUBSTITUTE(B5," ",REPT(" ",LEN(B5))), (D5-1)*LEN(B5)+1, LEN(B5)))

ملاحظة: يمكنك إدخال رقم الكلمة (n) مباشرةً في الصيغة على النحو التالي.

=TRIM(MID(SUBSTITUTE(B5," ",REPT(" ",LEN(B5))), (2-1)*LEN(B5)+1, LEN(B5)))

2.4.2 استخراج الكلمة ذات الرقم n باستخدام دالة معرّفة من قبل المستخدم

بجانب الصيغة المذكورة أعلاه، يمكنك أيضًا استخدام دالة معرّفة من قِبل المستخدم (User-defined function) لاستخراج الكلمة ذات الرقم n من خلية في Excel.

1. اضغط مفاتيح «Alt» + "F11" لفتح نافذة «Microsoft Visual Basic for Applications».

2. في نافذة «Microsoft Visual Basic for Applications»، انقر فوق «Insert» > «Module»، ثم الصق كود VBA أدناه في نافذة الكود.

كود VBA: استخراج الكلمة ذات الرقم n من سلسلة نصية في خلية

Function ExtractTheNthWord(Source As String, Position As Integer)
'Update by Extendoffice 20211202
Dim arr() As String
arr = VBA.Split(Source, " ")
xCount = UBound(arr)
If xCount < 1 Or (Position - 1) > xCount Or Position < 0 Then
    FindWord = ""
Else
    FindWord = arr(Position - 1)
End If
End Function

3. اضغط مفاتيح «Alt» + «Q» لإغلاق نافذة «Microsoft Visual Basic for Applications».

4. عُد إلى ورقة العمل التي تحتوي على السلاسل النصية التي تريد استخراج الكلمة ذات الرقم n منها، واختر خلية فارغة، ثم انقل أو أدخل الصيغة أدناه فيها واضغط مفتاح «Enter» للحصول على الكلمة المطلوبة.

=FindWord(B5,D5)

أو

=FindWord(B5,2)

ملاحظة: في الصيغة، تمثّل الخلية D5 الخلية التي تحتوي على الرقم المُشار إلى رقم الكلمة (n). بدلاً من ذلك، يمكنك استبدال مرجع الخلية مباشرةً بالرقم المطلوب.

5. حدد خلية النتيجة، ثم اسحب مقبض التعبئة التلقائي (AutoFill Handle) لأسفل لاستخراج الكلمة التي تحتل المرتبة n من السلاسل النصية في الخلايا الأخرى.

2.4.3 استخراج الكلمة ذات الرقم n باستخدام أداة رائعة

إذا كنت تفضل عدم تطبيق صيغة أو دالة مُعرَّفة من قِبل المستخدم يدويًّا كما ورد أعلاه، فنوصيك هنا بأداة «استخراج الكلمة الثانية والعشرين من خلية» من Kutools لـ Excel. فباستخدام هذه الميزة، يمكنك استخراج الكلمة ذات الرقم n من سلسلة نصية في خلية بسهولة، وببضع نقرات فقط!

1. اختر الخلية التي ترغب في وضع النتيجة فيها، ثم انقر على «Kutools» > «مساعد الصيغة» > «Text» > «Extract the nth word in cell». راجع لقطة الشاشة:

2. في مربع الحوار «مساعد الصيغة»، قم بإجراء الإعدادات التالية.

3. بعد ذلك، يتم استخراج الكلمة الثانية (ذات الرقم n) من السلسلة النصية في الخلية B5، مع ملاحظة أن صيغةً قد تم إنشاؤها تلقائيًا في الوقت نفسه. حدد خلية النتيجة هذه، ثم اسحب مقبض التعبئة التلقائي (AutoFill Handle) لأسفل للحصول على الكلمة الثانية من السلاسل النصية الأخرى.

انقر لمعرفة المزيد عن هذه الميزة.

2.5 استخراج النص قبل أو بعد الظهور محدّد من محرف فاصل

بافتراض أن لديك قائمة من السلاسل النصية كما هو موضح في لقطة الشاشة أدناه، يقدم هذا القسم صيغتين تساعدانك على استخراج النص الموجود قبل التكرار الثاني لمسافة فارغة أو بعده.

2.5.1 استخراج النص قبل الظهور محدّد من محرف فاصل

يمكنك استخدام دالة LEFT مع دالتَي SUBSTITUTE وFIND لاستخراج النص الذي يسبق أول ظهور لمُحدد فاصل معين في خلية Excel.

الصيغة العامة

=LEFT(SUBSTITUTE(text_string,«delimiter»,CHAR(9),n),FIND(CHAR(9),SUBSTITUTE(text_string,«delimiter»,CHAR(9),n),1)-1)

المعاملات

اختر خلية، ثم انْسخ أو أدخِل الصيغة أدناه واضغط مفتاح «Enter» للحصول على النتيجة. بعد ذلك، حدد خلية النتيجة واسحب مقبض التعبئة التلقائي (AutoFill Handle) لأسفل لملء باقي الخلايا بالنتائج المطلوبة.

=LEFT(SUBSTITUTE(B5," ",CHAR(9),2),FIND(CHAR(9),SUBSTITUTE(B5," ",CHAR(9),2),1)-1)

ملاحظة: في الصيغة، تمثّل الخلية B5 الخلية التي تحتوي على السلسلة النصية التي تريد استخراج النص منها؛ وتشير علامتا الاقتباس « » إلى مسافة فارغة، بينما يشير الرقم 2 إلى التكرار الثاني للمسافة الفارغة. يمكنك بسهولة تعديل هذه القيم لتتناسب مع احتياجاتك.

2.5.2 استخراج النص بعد الظهور محدّد من محرف فاصل

لاستخراج النص الذي يظهر بعد المحرف الفاصل المحدَّد، يمكنك استخدام دالة RIGHT مع دوال SUBSTITUTE وLEN وFIND.

الصيغة العامة

=RIGHT(SUBSTITUTE(text_string, «delimiter», CHAR(9), n), LEN(text_string)- FIND(CHAR(9), SUBSTITUTE(text_string, «delimiter», CHAR(9), n), 1) + 1)

المعاملات

الآن يمكنك تطبيق هذه الصيغة لاستخراج النص الموجود بعد التكرار الثاني للمسافة من كل خلية في النطاق B5:B10 كما يلي.

اختر خليةً، وأدخل الصيغة أدناه، ثم اضغط مفتاح «Enter» للحصول على النتيجة. بعد ذلك، حدد خلية النتيجة واسحب مقبض التعبئة التلقائي (AutoFill Handle) لأسفل لملء باقي الخلايا بالنتائج المطلوبة.

=RIGHT(SUBSTITUTE(B5, " ", CHAR(9), 2), LEN(B5)- FIND(CHAR(9), SUBSTITUTE(B5, " ", CHAR(9), 2), 1) + 1)

2.6 استخراج النص قبل أو بعد فاصل سطر

افترض أن لديك قائمة طلبات في العمود B، وترغب في استخراج جزء التاريخ وجزء رقم المنتج من كل خلية. يمكنك استخدام صيغ Excel التالية لتحقيق ذلك.

2.6.1 استخراج النص قبل أول فاصل سطر باستخدام صيغة

كما ترى في لقطة الشاشة أعلاه، يظهر جزء التاريخ قبل أول فاصل سطر داخل الخلية. ويوضّح هذا القسم كيفية استخدام دالة LEFT مع دالة SEARCH لاستخراج النص الموجود قبل أول فاصل سطر داخل الخلية بسهولة ودقة.

الصيغة العامة

=LEFT(cell, SEARCH(CHAR(10), cell)-1)

المعاملات

اختر خلية فارغة، ثم انْسَخ أو أدخِل الصيغة أدناه فيها واضغط مفتاح «Enter» للحصول على النتيجة. بعد ذلك، حدد خلية النتيجة واسحب مقبض التعبئة التلقائي (AutoFill Handle) لأسفل لتطبيق الصيغة على الخلايا الأخرى.

=LEFT(B5, SEARCH(CHAR(10), B5)-1)

بعد ذلك، يمكنك ملاحظة أن النص الموجود قبل أول فاصل سطر في كل خلية ضمن النطاق B5:B8 قد تم استخراجه، كما يظهر في لقطة الشاشة أدناه.

ملاحظة: في الصيغة، يمثّل CHAR(10) فاصل سطر في نظام Windows.

2.6.2 استخراج النص بعد آخر فاصل سطر باستخدام صيغة

في الخطوة السابقة، تناولنا كيفية استخراج النص الموجود قبل أول فاصل سطر داخل الخلية. وسَيُرشدك هذا الجزء الآن إلى طريقة استخراج النص الموجود بعد آخر فاصل سطر داخل الخلية باستخدام صيغة مختلفة.

الصيغة العامة

=TRIM(RIGHT(SUBSTITUTE(cell,CHAR(10),REPT(« »,200)),200))

المعاملات

اختر خلية فارغة، وأدخل الصيغة أدناه، ثم اضغط مفتاح «Enter» للحصول على النتيجة. بعد ذلك، حدد خلية النتيجة واسحب مقبض التعبئة التلقائي (AutoFill Handle) لأسفل لتطبيق الصيغة على الخلايا الأخرى.

=TRIM(RIGHT(SUBSTITUTE(B5,CHAR(10),REPT(" ",200)),200))

بعد ذلك، يتم استخراج جزء رقم المنتج من كل خلية في القائمة، كما يظهر في لقطة الشاشة أعلاه.

ملاحظة: في الصيغة، يُمثل CHAR(10) فاصل سطر (سطر جديد) في نظام Windows.

2.7 استخراج النص قبل أو بعد كلمة

في الأجزاء السابقة، تعلّمنا كيفية استخراج النص قبل أو بعد حرف أو محرف فاصل. لكن ماذا لو أردت استخراج النص قبل أو بعد كلمة كاملة؟ يقدم هذا القسم ثلاث طرق فعّالة لمساعدتك على إنجاز هذه المهمة بسلاسة.

2.7.1 استخراج النص قبل كلمة معيّنة باستخدام صيغة

تتيح لك الصيغة التالية استخراج النص الموجود قبل كلمة معيّنة داخل خلية في Excel.

الصيغة العامة

=IFERROR(LEFT(cell,FIND(word,cell)-1),cell)

المعاملات

اختر خلية فارغة، وأدخل الصيغة أدناه، ثم اضغط مفتاح «Enter» للحصول على النتيجة. بعد ذلك، حدد خلية النتيجة واسحب مقبض التعبئة التلقائي (AutoFill Handle) لأسفل لتطبيق الصيغة على الخلايا الأخرى.

في هذا المثال، سنستخرج كل النصوص الظاهرة قبل كلمة «Excel»، لذا أدخلنا الكلمة مباشرةً في الصيغة ووضعناها بين علامتي اقتباس مزدوجتين. أو يمكنك بدلًا من ذلك الإشارة إلى خلية تحتوي على كلمة «Excel».

=IFERROR(LEFT(B5,FIND("Excel",B5)-1),B5)

ملاحظات:

2.7.2 استخراج النص بعد كلمة معيّنة باستخدام صيغة

لاستخراج النص بعد كلمة معيّنة، طبّق الصيغة التالية لتحقيق ذلك.

الصيغة العامة

=TRIM(MID(cell,SEARCH(word,cell)+LEN(word),255))

المعاملات

اختر خليةً، وأدخل الصيغة أدناه، ثم اضغط مفتاح «Enter» للحصول على النتيجة. بعد ذلك، حدد خلية النتيجة واسحب مقبض التعبئة التلقائي (AutoFill Handle) لأسفل لتطبيق الصيغة على الخلايا الأخرى.

=TRIM(MID(B5,SEARCH("Excel",B5)+LEN("Excel"),255))

بعد ذلك، يمكنك ملاحظة أن جميع النصوص الظاهرة بعد كلمة «Excel» في كل خلية قد تم استخراجها، كما يظهر في لقطة الشاشة أدناه.

ملاحظات:

2.7.3 استخراج النص قبل أو بعد كلمة معيّنة باستخدام أداة رائعة

إذا شعرت أن استخدام الصيغة قد يُعقّد الأمور، فنحن نوصي بشدة بأداة «استخراج النص» من «Kutools لـ Excel»، التي تُمكّنك من أتمتة مهمة الاستخراج في Excel بنقرات قليلة فقط.

1. انقر فوق «Kutools» > «Text» > «استخراج النص» لتفعيل هذه الميزة.

2. في مربع الحوار «استخراج النص»، قم بتطبيق الإعدادات التالية.

2.1) تأكد من أنك في علامة التبويب «استخراج حسب الموضع»؛

2.2) في مربع «النطاق»، انقر فوق الزرلتحديد نطاق الخلايا التي تريد استخراج النص فيها؛

2.3) في قسم «الخيارات»:

لاستخراج كل النصوص قبل كلمة ما، اختر خيار «قبل النص» زر راديو، ثم أدخل الكلمة في مربع النص؛

لاستخراج كل النصوص بعد كلمة ما، اختر خيار «بعد النص» زر راديو، ثم أدخل الكلمة في مربع النص.

2.4) انقر فوق زر «موافق». راجع لقطة الشاشة:

ملاحظة: إذا كنت ترغب في الحصول على نتائج ديناميكية، فعَلِّم خانة الاختيار «إدراج كصيغة»، وستُحدَّث النتائج تلقائيًا كلما تغيَّرت البيانات في النطاق.

3. بعد ذلك، يظهر مربع حوار «استخراج النص»، فاختر الخلية التي ترغب في إخراج النتيجة إليها، ثم انقر فوق زر «موافق».

بعد ذلك، يتم استخراج النصوص الموجودة قبل أو بعد الكلمة المعيّنة من كل خلية في نطاق التحديد فورًا.

ملاحظة: هذه الميزة حساسة لحالة الأحرف.

انقر لمعرفة المزيد عن هذه الميزة.

3. الاستخراج بين أحرف أو كلمات

إذا كنت ترغب في استخراج النص المحصور بين أحرف أو كلمات معيّنة، جرّب الطرق التالية.

3.1 استخراج النص بين حرفين

لاستخراج النص المحصور بين حرفين—قد يكونان متماثلين أو مختلفين—يوفّر هذا القسم عدة طرق، ويمكنك اختيار الأنسب منها ليلائم احتياجاتك.

3.1.1 استخراج النص بين حرفين متماثلين باستخدام صيغة

كما هو موضح في لقطة الشاشة أدناه، يحتوي العمود B على قائمة من سلاسل النصوص، وترغب في استخراج الجزء العددي الواقع بين الشرطتين المائلتين “/” من كل خلية ضمن النطاق. ويمكنك تحقيق ذلك بسهولة باستخدام الصيغة التالية.

اختر خلية فارغة، ثم انسخ الصيغة أدناه أو أدخلها يدويًّا، واضغط مفتاح «Enter» للحصول على النتيجة. بعد ذلك، حدد خلية النتيجة واسحب مقبض التعبئة التلقائي (AutoFill Handle) لأسفل لملء باقي الخلايا في القائمة بالنتائج المقابلة.

=SUBSTITUTE(MID(SUBSTITUTE("/" & B5&REPT(" ",6),"/",REPT(",",255)),2*255,255),",","")

بعد ذلك، يتم استخراج النص الموجود بين الشرطتين المائلتين «/» من كل خلية ضمن النطاق. راجع لقطة الشاشة:

ملاحظة:

 3.1.2 استخراج النص بين حرفين مختلفين باستخدام صيغة

بعد أن تعلّمتَ كيفية استخراج النص المحصور بين حرفين متماثلين داخل خلية، سنعرض لك الآن صيغةً لاستخراج النص الواقع بين حرفين مختلفين. كما يظهر في لقطة الشاشة أدناه، وللحصول على عنوان البريد الإلكتروني الموجود بين علامتي الاقتباس “” في كل خلية من العمود B، اتبع الخطوات التالية:

الصيغة العامة

=MID(LEFT(cel,FIND(«end_char»,cell)-1),FIND(«start_char»,cell)+1,LEN(cell))

المعاملات

اختر خلية فارغة، ثم انسخ الصيغة أدناه أو أدخلها يدويًّا واضغط مفتاح «Enter» للحصول على النتيجة. بعد ذلك، حدد خلية النتيجة واسحب مقبض التعبئة التلقائي (AutoFill Handle) لأسفل لتطبيق الصيغة على الخلايا الأخرى.

=MID(LEFT(B5,FIND(">",B5)-1),FIND("<",B5)+1,LEN(B5))

كما ترى في لقطة الشاشة أعلاه، تم استخراج النص الوحيد الواقع بين الحرفين المحددين بالضبط كما هو.

3.1.3 استخراج النص بين حرفين باستخدام أداة رائعة

هنا، نوصي بشدة بميزة «استخراج السلسلة بين الأحرف المحددة» من «Kutools لـ Excel»، التي تساعدك بسهولة على استخراج النص الواقع بين حرفين—متماثلين أو مختلفين—داخل خلية في Excel.

1. اختر خلية فارغة لإظهار النتيجة، ثم انقر «Kutools» > «مساعد الصيغة» > «مساعد الصيغة».

2. في مربع حوار «مساعد الصيغة»، قم بإجراء الإعدادات التالية.

3. بعد ذلك، يتم استخراج النص الوحيد الموجود بين علامتي الاقتباس “” في الخلية B5. وفي الوقت نفسه، يتم إنشاء صيغة؛ ما يتيح لك تحديد خلية النتيجة هذه ثم سحب مقبض التعبئة التلقائي (AutoFill Handle) لأسفل لاستخراج النص من الخلايا الأخرى في نفس القائمة.

انقر لمعرفة المزيد عن هذه الميزة.

3.1.4 استخراج النص بين حرفين (بما في ذلك الحرفان) وفقًا لقاعدة

إذا كنت ترغب في الاحتفاظ بالحرفين بعد الاستخراج، جرّب تطبيق قاعدة باستخدام ميزة «استخراج النص» من Kutools لـ Excel.

1. انقر «Kutools» > «Text» > «استخراج النص».

2. في مربع حوار «استخراج النص»، قم بتطبيق الإعدادات التالية.

2.1) انقر فوق علامة التبويب «استخراج حسب القاعدة»؛

2.2) في قسم «النطاق»، انقر فوق الزرلتحديد نطاق الخلايا التي تريد استخراج النص منها بين الأحرف؛

2.3) في مربع «النص»، أدخل «»؛

ملاحظة: «» هما الحرفان اللذان تريد استخراج النص بينهما، و* هو رمز بديل يمثل أي عدد من الأحرف. يمكنك إدخال الشرط وفقًا لاحتياجاتك.

2.4) انقر فوق زر «إضافة» لإضافة الشرط إلى مربع قائمة «محتوى القاعدة»؛

2.5) انقر فوق زر «موافق». راجع لقطة الشاشة:

3. يظهر مربع حوار آخر باسم «استخراج النص». يُرجى تحديد خلية لإخراج النتيجة، ثم انقر زر «موافق».

بعد ذلك، يتم استخراج النص الواقع بين الحرفين المحددين (بما في ذلك الحرفان أنفسهما) من كل خلية ضمن نطاق التحديد دفعة واحدة.

3.2 استخراج النص بين كلمتين

بالإضافة إلى استخراج النص المحصور بين حرفين، قد تحتاج أيضًا إلى استخراج النص الواقع بين كلمتين. على سبيل المثال، استخراج جميع سلاسل النصوص الواقعة بين الكلمتين “KTE” و“feature” من كل خلية في العمود B، كما يظهر في لقطة الشاشة أدناه. يمكنك تجربة إحدى الطرق التالية لإتمام هذه المهمة بسلاسة.

3.2.1 استخراج النص بين كلمتين باستخدام صيغة

يمكنك استخدام صيغة تعتمد على دالتي MID وSEARCH لاستخراج كل السلاسل النصية الواقعة بين كلمتين داخل خلية.

الصيغة العامة

=MID(cell,SEARCH(«start_word»,cell)+3,SEARCH(«end_word»,cell)-SEARCH(«start_word»,cell)-4)

المعاملات

اختر خلية فارغة، ثم انسخ الصيغة أدناه أو أدخلها يدويًّا واضغط مفتاح «Enter» للحصول على النتيجة. بعد ذلك، حدد خلية النتيجة واسحب مقبض التعبئة التلقائي (AutoFill Handle) لأسفل لتطبيق الصيغة على الخلايا الأخرى.

=MID(B5,SEARCH("KTE",B5)+3,SEARCH("feature",B5)-SEARCH("KTE",B5)-4)

ملاحظة: في الصيغة، يمثل الرقم 3 طول كلمة «KTE»، بينما يمثل الرقم 4 طولها مع إضافة 1.

ستلاحظ أن جميع سلاسل النصوص الواقعة بين الكلمتين المحدَّدتين قد تم استخراجها من كل خلية في العمود B.

3.2.2 استخراج النص بين كلمتين باستخدام أداة رائعة

بالنسبة للعديد من مستخدمي Excel، قد تكون الصيغ صعبة الحفظ والتعامل معها. لكن مع ميزة «استخراج السلسلة بين الأحرف المحددة» من «Kutools لـ Excel»، يمكنك بسهولة استخراج النص بين كلمتين بنقرات قليلة فقط!

1. اختر الخلية التي تريد إخراج النتيجة فيها، ثم انقر «Kutools» > «مساعد الصيغة» > «مساعد الصيغة».

2. في مربع حوار «مساعد الصيغة»، يُرجى إجراء الإعدادات التالية.

3. بعد ذلك، يتم استخراج جميع سلاسل النصوص الواقعة بين الكلمتين “KTE” و“feature” داخل الخلية B5، ويتم في الوقت نفسه إنشاء صيغة؛ يمكنك تحديد خلية النتيجة هذه ثم سحب مقبض التعبئة التلقائي (AutoFill Handle) لأسفل لاستخراج النص من الخلايا الأخرى في نفس القائمة.

استخراج الأرقام حسب الموقع

بالنسبة لقائمة من السلاسل الأبجدية الرقمية، قد توجد ثلاث حالات:

1. الرقم موجود في بداية النص؛
2. الرقم موجود في نهاية النص؛
3. يمكن أن يظهر الرقم في أي موضع ضمن النص.

في هذا القسم، سنعرض طرقًا متنوعة لاستخراج الأرقام في كل حالة من الحالات المذكورة أعلاه.

1 استخراج الرقم من يسار السلسلة

سيقدّم هذا الجزء صيغةً تساعدك على استخراج الأرقام التي تظهر قبل النص في الخلية فقط.

الصيغة العامة

=LEFT(cell, MATCH(FALSE, ISNUMBER(MID(cell, ROW(INDIRECT("1:"&LEN(cell)+1)), 1) *1), 0) -1)

المعاملات

ملاحظة:

اختر خلية فارغة، وأدخل الصيغة أدناه، ثم اضغط «Ctrl» + «Shift» + «Enter» أو مفتاح «Enter» للحصول على النتيجة. بعد ذلك، حدد خلية النتيجة واسحب مقبض التعبئة التلقائي (AutoFill Handle) لأسفل لملء باقي الخلايا بالأرقام المطلوبة.

=LEFT(B5, MATCH(FALSE, ISNUMBER(MID(B5, ROW(INDIRECT("1:"&LEN(B5)+1)), 1) *1), 0) -1)

ملاحظات:

2 استخراج الرقم من يمين السلسلة

كما هو موضح في لقطة الشاشة أدناه، لاستخراج الأرقام التي تظهر بعد النص في الخلية، جرّب الصيغة التالية:

الصيغة العامة

=RIGHT(cell, LEN(cell) - MAX(IF(ISNUMBER(MID(cell, ROW(INDIRECT("1:"&LEN(cell))), 1) *1)=FALSE, ROW(INDIRECT("1:"&LEN(cell))), 0)))

المعاملات

ملاحظة:

اختر خلية فارغة، وأدخل الصيغة أدناه، ثم اضغط «Ctrl» + «Shift» + «Enter» أو مفتاح «Enter» للحصول على النتيجة. بعد ذلك، حدد خلية النتيجة واسحب مقبض التعبئة التلقائي (AutoFill Handle) لأسفل لملء باقي الخلايا بالأرقام المطلوبة.

=RIGHT(B5, LEN(B5) - MAX(IF(ISNUMBER(MID(B5, ROW(INDIRECT("1:"&LEN(B5))), 1) *1)=FALSE, ROW(INDIRECT("1:"&LEN(B5))), 0)))

ملاحظات:

3. استخرج جميع الأرقام من أي موضع في السلسلة النصية

تتيح لك الطرق السابقة استخراج الأرقام من يسار السلسلة النصية أو يمينها فقط. أما إذا كنت ترغب في استخراج جميع الأرقام من أي موضع ضمن السلسلة النصية، فنحن نقدّم لك هنا ثلاث طرق فعّالة لإتمام هذه المهمة.

3.1 استخراج جميع الأرقام من أي مكان في سلسلة باستخدام صيغة

يمكنك تطبيق الصيغة التالية لاستخراج جميع الأرقام من أي موضع ضمن سلسلة نصية في Excel.

1. اختر خلية فارغة، ثم انقل الصيغة أدناه أو أدخلها يدويًّا واضغط مفتاح «Enter» لاستخراج جميع الأرقام من الخلية B5.

=SUMPRODUCT(MID(0&B5, LARGE(INDEX(ISNUMBER(--MID(B5, ROW(INDIRECT("1:"&LEN(B5))), 1)) * ROW(INDIRECT("1:"&LEN(B5))), 0), ROW(INDIRECT("1:"&LEN(B5))))+1, 1) * 10^ROW(INDIRECT("1:"&LEN(B5)))/10)

2. حدد خلية النتيجة، ثم اسحب مقبض التعبئة التلقائي (AutoFill Handle) لأسفل لملء باقي الخلايا بأرقامها تلقائيًا.

3.2 استخراج جميع الأرقام من أي مكان في سلسلة باستخدام VBA

الصيغة أعلاه طويلة ومعقّدة أكثر من اللازم بالنسبة للعديد من مستخدمي Excel. في الواقع، يمكنك أتمتة هذه المهمة بسهولة باستخدام نص برمجي (VBA) في Excel—ما عليك سوى اتباع الخطوات التالية.

1. اضغط مفاتيح «Alt» + "F11" لفتح نافذة «Microsoft Visual Basic for Applications».

2. في نافذة «Microsoft Visual Basic for Applications» المفتوحة، انقر «Insert» > «Module»، ثم الصق كود VBA أدناه في نافذة كود الوحدة (Module).

كود VBA: استخراج جميع الأرقام من أي مكان في سلسلة نصية

Sub ExtrNumbersFromRange()
'Updated by Extendoffice 20220106
    Dim xRg As Range
    Dim xDRg As Range
    Dim xRRg As Range
    Dim nCellLength As Integer
    Dim xNumber As Integer
    Dim strNumber As String
    Dim xTitleId As String
    Dim xI As Integer
    xTitleId = "KutoolsforExcel"
    Set xDRg = Application.InputBox("Please select text strings:", xTitleId, "", Type:=8)
    If TypeName(xDRg) = "Nothing" Then Exit Sub
    Set xRRg = Application.InputBox("Please select output cell:", xTitleId, "", Type:=8)
    If TypeName(xRRg) = "Nothing" Then Exit Sub
    xI = 0
    strNumber = ""
  For Each xRg In xDRg
    xI = xI + 1
    nCellLength = Len(xRg)
    For xNumber = 1 To nCellLength
      If IsNumeric(Mid(xRg, xNumber, 1)) Then
        strNumber = strNumber & Mid(xRg, xNumber, 1)
      End If
    Next xNumber
    xRRg.Item(xI) = strNumber
    strNumber = ""
  Next xRg
End Sub

3. اضغط مفتاح "F5" لتشغيل الكود. في مربع حوار «Kutools for Excel» الذي يظهر، حدد نطاق الخلايا التي تريد استخراج جميع الأرقام منها من كل خلية، ثم انقر زر «موافق».

4. بعد ذلك، يظهر مربع حوار باسم «KutoolsforExcel»؛ اختر فيه خلية الوجهة (destination cell) ثم انقر «OK».

بعد ذلك، يتم استخراج جميع الأرقام من كل خلية ضمن نطاق التحديد دفعةً واحدة.

4. استخراج الأرقام التي تلي نصًا معيّنًا

كما يظهر في لقطة الشاشة أدناه، يقدّم هذا القسم طريقتين لمساعدتك على استخراج أي أرقام تلي النص المعيّن «No.».

4.1 استخراج الأرقام بعد نص معيّن باستخدام صيغة

يمكنك تطبيق الصيغة التالية لاستخراج الأرقام التي تلي نصًا معيّنًا في خلية Excel.

الصيغة العامة:

=LOOKUP(10^6,1*MID(cell,MIN(FIND({0,1,2,3,4,5,6,7,8,9},cell&"0123456789",FIND(«text»,« »&cell&« »))),{2,3,4,5,6}))

المعاملات

اختر خلية فارغة، ثم انسخ الصيغة أدناه أو أدخلها واضغط مفتاح «Enter» للحصول على النتيجة. بعد ذلك، حدد خلية النتيجة واسحب مقبض التعبئة التلقائي (AutoFill Handle) لأسفل لتطبيق الصيغة على الخلايا الأخرى.

=LOOKUP(10^6,1*MID(B5,MIN(FIND({0,1,2,3,4,5,6,7,8,9},B5&"0123456789",FIND("No."," "&B5&" "))),{2,3,4,5,6}))

ملاحظات:

4.2 استخراج الأرقام بعد نص معيّن باستخدام دالة معرّفة من قبل المستخدم

يمكن للدالة المعرَّفة من قِبل المستخدم التالية أن تساعدك أيضًا في استخراج الأرقام التي تلي نصًّا معيَّنًا في خلية. يُرجى اتباع الخطوات التالية:

1. اضغط مفاتيح «Alt» + "F11" لفتح نافذة «Microsoft Visual Basic for Applications».

2. في نافذة «Microsoft Visual Basic for Applications»، انقر «Insert» > «Module»، ثم انسخ كود VBA أدناه في نافذة كود الوحدة (Module).

كود VBA: استخراج الأرقام بعد نص معيّن في خلية

Function GetNumberAfterTheChar(Rng As Range, Char As String)
'Updated by Extendoffice 20220106
Dim xValue As String
Dim xRntString As String
Dim xStart As Integer
Dim xC
    xValue = Rng.Text
    xStart = InStr(1, xValue, Char, vbTextCompare)
    If IsEmpty(xStart) Then
            GetNumberAfterTheChar = ""
            Exit Function
    End If
    If xStart < 1 Then
        GetNumberAfterTheChar = ""
        Exit Function
    End If
    xStart = xStart - 1 + Len(Char)
    If xStart < 1 Then
        GetNumberAfterTheChar = ""
        Exit Function
    End If
    xValue = Mid(xValue, xStart + 1)
    xRntString = ""
    For xI = 1 To Len(xValue)
        xC = Mid(xValue, xI, 1)
        Select Case Asc(xC)
        Case 48 To 57
            xRntString = xRntString & xC
       Case Else
            Exit For
        End Select
    Next
   GetNumberAfterTheChar = xRntString
End Function

3. اضغط مفاتيح «Alt» + «Q» لإغلاق نافذة «Microsoft Visual Basic for Applications».

4. اختر خليةً، وأدخل الصيغة أدناه، ثم اضغط مفتاح «Enter». بعد ذلك، حدد خلية النتيجة واسحب مقبض التعبئة التلقائي (AutoFill Handle) لأسفل لتطبيق الصيغة على الخلايا الأخرى.

=GetNumberAfterTheChar(B5,"No. ")

ملاحظات:

مقالات ذات صلة:

أفضل أدوات الإنتاجية لمكتبتك

🤖	KUTOOLS AI مساعد: ثوّر تحليل البيانات استنادًا إلى:التنفيذ الذكي   |  إنشاء الكود|  إنشاء الصيغ المخصصة  |  تحليل البيانات وإنشاء المخططات البيانية|  استدعاء الوظائف المحسنة…
	الميزات الشائعة:البحث، التمييز أو وضع علامة على المكررات   |  حذف الصفوف الفارغة   |  دمج الأعمدة أو الخلايا دون فقدان البيانات   |  التقريب بدون استخدام الصيغة...
	بحث متقدم:VLookup متعدد المعايير  |  VLookup متعدد القيم  |   VLookup عبر أوراق متعددة   |   مطابقة غامضة....
	قائمة منسدلة متقدمة:إنشاء قائمة منسدلة بسرعة   |  قائمة منسدلة تابعة   |  قائمة منسدلة متعددة الاختيار....
	مدير الأعمدة:إضافة عدد محدد من الأعمدة|نقل الأعمدة|تبديل حالة ظهور الأعمدة المخفية|مقارنة النطاقات والأعمدة...
	ميزات مميزة:التركيز على الشبكة   |  عرض التصميم   |شريط الصيغ المحسن   | مدير الدفتر والورقة   |  مكتبة الموارد(نص تلقائي)|  أداة اختيار التاريخ   |  تجميع ورقات العمل  |  تشفير/فك تشفير الخلايا   | إرسال رسائل البريد الإلكتروني حسب القائمة   |  مرشح متقدم   |   تصفية خاصة(تصفية الخلايا التي تحتوي على خط عريض/مائل/يتوسطه خط...) ...
	أفضل 15 مجموعات الأدوات:12 أدواتالنصوص(إضافة نص،حذف الأحرف المحددة، ...)|   50+أنواعالمخططات البيانية(مخطط جانت، ...)|   40+ صيغعملية(حساب العمر بناءً على تاريخ الميلاد، ...)|   19 أدواتالإدراج(إدراج رمز QR،إدراج صورة من المسار، ...)|   12 أدواتالتحويل(تحويل إلى كلمات،تحويل العملة، ...)|   7 أدواتدمج وتقسيم(دمج متقدم للصفوف،تقسيم الخلايا، ...)|... وأكثر من ذلك

استخدم Kutools باللغة التي تفضلها – يدعم الإنجليزية والإسبانية والألمانية والفرنسية والصينية و40+ لغات أخرى!

عزِّز مهاراتك في Excel باستخدام Kutools لـ Excel، وعايش الكفاءة كما لم تفعل من قبل.يقدّم Kutools لـ Excel أكثر من 300 ميزة متقدمة لتعزيز الإنتاجية ووقت الحفظ.انقر هنا للحصول على الميزة التي تحتاجها أكثر من غيرها...

مزيد من التفاصيل حول Kutools لـ Excel...تنزيل مجاني...

---

يجلب Office Tab واجهة ذات علامات تبويب إلى Office، ويجعل عملك أسهل بكثير

• تمكّن من التحرير والقراءة باستخدام علامات التبويب في Word وExcel وPowerPoint، وPublisher وAccess وVisio وProject.
• افتح وأنشئ مستندات متعددة في علامات تبويب جديدة داخل النافذة نفسها، بدلاً من فتح نوافذ جديدة.
• يزيد إنتاجيتك بنسبة 50% ويوفّر لك مئات نقرات الفأرة كل يوم!

مزيد من التفاصيل حول Office Tab...تنزيل مجاني...

---

جميع الإضافات من Kutools في برنامج تثبيت واحد!

Kutools for Office حزمةٌ تحتوي على إضافاتٍ مخصصة لتطبيقات Excel وWord وOutlook وPowerPoint، إلى جانب Office Tab Pro، مما يجعلها الخيار المثالي للفِرق التي تعمل عبر تطبيقات Office.

• حزمة شاملة واحدة— إضافات Excel وWord وOutlook وPowerPoint بالإضافة إلى Office Tab Pro
• برنامج تثبيت واحد، ترخيص واحد— الإعداد خلال دقائق (جاهز لـ MSI)
• يعمل بشكل أفضل معًا— إنتاجية ميسَّرة عبر تطبيقات Office
• تجربة مجانية لمدة 30 يومًا بكامل الميزات— بدون تسجيل، بدون بطاقة ائتمان
• أفضل قيمة— وفِّر مقارنةً بشراء الإضافات بشكل منفصل

مزيد من التفاصيل حول Kutools for Office...تنزيل مجاني...