دليل Excel: حساب التاريخ والوقت (حساب الفرق، العمر، الجمع/الطرح)

في Excel، تُستخدم حسابات التاريخ والوقت بشكل متكرر، مثل حساب الفرق بين تاريخين أو وقتين، أو إضافة أو طرح تاريخ ووقت، أو حساب العمر بناءً على تاريخ الميلاد المعطى وغيرها. في هذا الدليل، ستجد تقريبًا جميع السيناريوهات المتعلقة بحسابات التاريخ والوقت مع توفير الطرق المناسبة لكل حالة.

في هذا الدليل، قمت بإنشاء بعض الأمثلة لشرح الطرق، يمكنك تغيير المراجع حسب حاجتك عند استخدامك لأكواد VBA أو الصيغ أدناه

1. حساب الفرق بين تاريخين/وقتين

يُعد حساب الفرق بين تاريخين أو وقتين من أكثر مشكلات حساب التاريخ والوقت شيوعًا التي قد تواجهها في عملك اليومي على Excel. قد تساعدك الأمثلة التالية في زيادة الكفاءة عند مواجهة نفس المشكلات.

1.11 حساب الفرق بين تاريخين بالأيام/الأشهر/السنوات/الأسابيع

يمكنك استخدام دالة DATEDIF في Excel لحساب الفرق بسرعة بين تاريخين بالأيام أو الأشهر أو السنوات أو الأسابيع.

انقر لمزيد من التفاصيل حول دالة DATEDIF

فرق الأيام بين تاريخين

لحساب فرق الأيام بين تاريخين في الخليتين A2 وB2، يرجى استخدام الصيغة التالية

=DATEDIF(A2,B2,"d")

اضغط Enter على المفتاح للحصول على النتيجة.

فرق الأشهر بين تاريخين

لحساب فرق الأشهر بين تاريخين في الخليتين A5 وB5، يرجى استخدام الصيغة التالية

=DATEDIF(A5,B5,"m")

اضغط Enter على المفتاح للحصول على النتيجة.

فرق السنوات بين تاريخين

لحساب فرق السنوات بين تاريخين في الخليتين A8 وB8، يرجى استخدام الصيغة التالية

=DATEDIF(A8,B8,"y")

اضغط Enter على المفتاح للحصول على النتيجة.

فرق الأسابيع بين تاريخين

لحساب فرق الأسابيع بين تاريخين في الخليتين A11 وB11، يرجى استخدام الصيغة التالية

=DATEDIF(A11,B11,"d")/7

اضغط Enter على المفتاح للحصول على النتيجة.

ملاحظة:

1) عند استخدام الصيغة أعلاه لحساب فرق الأسابيع، قد تظهر النتيجة بتنسيق تاريخ، لذا عليك تغيير تنسيق النتيجة إلى عام أو رقم حسب حاجتك.

2) عند استخدام الصيغة أعلاه لحساب فرق الأسابيع، قد تظهر النتيجة كرقم عشري، إذا كنت ترغب في الحصول على رقم الأسابيع الصحيح (عدد صحيح)، يمكنك إضافة دالة ROUNDDOWN كما هو موضح أدناه للحصول على فرق الأسابيع كعدد صحيح:

=ROUNDDOWN(DATEDIF(A11,B11,"d")/7,0)

1.12 حساب عدد الأشهر مع تجاهل السنوات والأيام بين تاريخين

إذا كنت ترغب فقط في حساب فرق الأشهر مع تجاهل السنوات والأيام بين تاريخين كما هو موضح في الصورة أدناه، فهناك صيغة يمكن أن تساعدك.

=DATEDIF(A2,B2,"ym")

اضغط Enter على المفتاح للحصول على النتيجة.

A2 هو تاريخ البدء، وB2 هو تاريخ الانتهاء.

1.13 حساب عدد الأيام مع تجاهل السنوات والأشهر بين تاريخين

إذا كنت ترغب فقط في حساب فرق الأيام مع تجاهل السنوات والأشهر بين تاريخين كما هو موضح في الصورة أدناه، فهناك صيغة يمكن أن تساعدك.

=DATEDIF(A5,B5,"md")

اضغط Enter على المفتاح للحصول على النتيجة.

A5 هو تاريخ البدء، وB5 هو تاريخ الانتهاء.

1.14 حساب الفرق بين تاريخين وإرجاع السنوات والأشهر والأيام

إذا كنت ترغب في الحصول على الفرق بين تاريخين وإرجاع النتيجة بصيغة xx سنوات، xx أشهر، xx أيام كما هو موضح في الصورة أدناه، فهناك أيضًا صيغة متاحة.

=DATEDIF(A8, B8, "y") &" years, "&DATEDIF(A8, B8, "ym") &" months, " &DATEDIF(A8, B8, "md") &" days"

اضغط Enter على المفتاح للحصول على النتيجة.

A8 هو تاريخ البدء، وB8 هو تاريخ الانتهاء.

1.15 حساب الفرق بين تاريخ معين واليوم الحالي

لحساب الفرق تلقائيًا بين تاريخ معين واليوم الحالي، فقط قم بتغيير end_date في الصيغ أعلاه إلى TODAY(). هنا سنحسب فرق الأيام بين تاريخ سابق واليوم الحالي كمثال.

=DATEDIF(A11,TODAY(),"d")

اضغط على مفتاح Enter للحصول على النتيجة.

ملاحظة: إذا كنت ترغب في حساب الفرق بين تاريخ مستقبلي واليوم الحالي، غيّر start_date إلى اليوم الحالي، واعتبر التاريخ المستقبلي هو end_date كما يلي:

=DATEDIF(TODAY(),A14,"d")

لاحظ أن start_date يجب أن يكون أصغر من end_date في دالة DATEDIF، وإلا ستظهر قيمة خطأ #NUM!.

1.16 حساب أيام العمل مع أو بدون العطلات بين تاريخين

أحيانًا قد تحتاج إلى عد عدد أيام العمل مع أو بدون العطلات بين تاريخين محددين.

في هذا الجزء، ستستخدم دالة NETWORKDAYS.INTL:

انقر على NETWORKDAYS.INTL لمعرفة الوسيطات وطريقة الاستخدام.

عد أيام العمل مع العطلات

لحساب أيام العمل مع العطلات بين تاريخين في الخليتين A2 وB2، يرجى استخدام الصيغة التالية:

=NETWORKDAYS.INTL(A2,B2)

اضغط Enter على المفتاح للحصول على النتيجة.

عد أيام العمل بدون العطلات

لحساب أيام العمل مع العطلات بين تاريخين في الخليتين A2 وB2، مع استثناء العطلات في النطاق D5:D9، يرجى استخدام الصيغة التالية:

=NETWORKDAYS.INTL(A5,B5,1,D5:D9)

اضغط Enter على المفتاح للحصول على النتيجة.

ملاحظة:

في الصيغ أعلاه، يتم اعتبار السبت والأحد كعطلة نهاية الأسبوع، إذا كانت لديك أيام عطلة نهاية أسبوع مختلفة، يرجى تغيير وسيطة [weekend] حسب حاجتك.

1.17 حساب عطلات نهاية الأسبوع بين تاريخين

إذا كنت ترغب في عد عدد عطلات نهاية الأسبوع بين تاريخين، يمكن أن تساعدك دوال SUMPRODUCT أو SUM في ذلك.

لحساب عطلات نهاية الأسبوع (السبت والأحد) بين تاريخين في الخليتين A12 وB12:

=SUMPRODUCT(--(WEEKDAY(ROW(INDIRECT(A12&":"&B12)),2)>5))

أو

=SUM(INT((WEEKDAY(A12-{1,7})+B12-A12)/7))

اضغط Enter على المفتاح للحصول على النتيجة.

1.18 حساب عدد أيام الأسبوع المحددة بين تاريخين

لحساب عدد أيام أسبوع محددة مثل الاثنين بين تاريخين، يمكن أن تساعدك دوال INT وWEEKDAY معًا.

الخليتان A15 وB15 هما التاريخان اللذان تريد عد عدد أيام الاثنين بينهما، يرجى استخدام الصيغة التالية:

=INT((WEEKDAY(A15-2)-A15 +B15)/7)

اضغط Enter على المفتاح للحصول على النتيجة.

غيّر رقم يوم الأسبوع في دالة WEEKDAY لعد يوم أسبوع مختلف:

1 هو الأحد،2 هو الاثنين،3 هو الثلاثاء،4 هو الأربعاء،5 هو الخميس،6 هو الجمعة و7 هو السبت

1.19 حساب الأيام المتبقية في الشهر/السنة

أحيانًا قد ترغب في معرفة عدد الأيام المتبقية في الشهر أو السنة بناءً على التاريخ المدخل كما هو موضح في الصورة أدناه:

الحصول على الأيام المتبقية في الشهر الحالي

انقر على EOMONTH لمعرفة الوسيطات وطريقة الاستخدام.

لحساب الأيام المتبقية من الشهر الحالي في الخلية A2، يرجى استخدام الصيغة التالية:

=EOMONTH(A2,0)-A2

اضغط Enter على المفتاح، واسحب مقبض التعبئة التلقائية لتطبيق هذه الصيغة على خلايا أخرى إذا لزم الأمر.

نصيحة: قد تظهر النتائج بتنسيق تاريخ، فقط قم بتغييرها إلى تنسيق عام أو رقم.

الحصول على الأيام المتبقية في السنة الحالية

لحساب الأيام المتبقية من السنة الحالية في الخلية A2، يرجى استخدام الصيغة التالية:

=DATE(YEAR(A2),12,31)-A2

اضغط Enter على المفتاح، واسحب مقبض التعبئة التلقائية لتطبيق هذه الصيغة على خلايا أخرى إذا لزم الأمر.

1.21 حساب الفرق بين وقتين

لحساب الفرق بين وقتين، هناك صيغتان بسيطتان يمكن أن تساعدك.

على افتراض أن الخليتين A2 وB2 تحتويان على وقت البدء ووقت الانتهاء على التوالي، استخدم الصيغ التالية:

=B2-A2

=TEXT(B2-A2,"hh:mm:ss")

اضغط Enter على المفتاح للحصول على النتيجة.

ملاحظة:

• إذا استخدمت end_time-start_time، يمكنك تغيير تنسيق النتيجة إلى تنسيق وقت آخر حسب حاجتك من خلال مربع حوار تنسيق الخلايا.
• إذا استخدمت TEXT(end_time-first_time,"time_format")، أدخل تنسيق الوقت الذي ترغب في عرض النتيجة به في الصيغة، مثل TEXT(end_time-first_time,"h") تعطي16.
• إذا كان end_time أصغر من start_time، ستعيد كلتا الصيغتين قيمة خطأ. لحل هذه المشكلة، يمكنك إضافة دالة ABS أمام الصيغ، مثل ABS(B2-A2)، ABS(TEXT(B2-A2,"hh:mm:ss"))، ثم قم بتنسيق النتيجة كوقت.

1.22 حساب الفرق بين وقتين بالساعات/الدقائق/الثواني

إذا كنت ترغب في حساب الفرق بين وقتين بالساعات أو الدقائق أو الثواني كما هو موضح في الصورة أدناه، يرجى اتباع هذا الجزء.

الحصول على فرق الساعات بين وقتين

لحساب فرق الساعات بين وقتين في الخليتين A5 وB5، يرجى استخدام الصيغة التالية:

=INT((B5-A5)*24)

اضغط Enter على المفتاح، ثم قم بتغيير تنسيق النتيجة إلى عام أو رقم.

إذا كنت ترغب في الحصول على فرق الساعات كرقم عشري، استخدم (end_time-start_time)*24.

الحصول على فرق الدقائق بين وقتين

لحساب فرق الدقائق بين وقتين في الخليتين A8 وB8، يرجى استخدام الصيغة التالية:

=INT((B8-A8)*1440)

اضغط Enter على المفتاح، ثم قم بتغيير تنسيق النتيجة إلى عام أو رقم.

إذا كنت ترغب في الحصول على فرق الدقائق كرقم عشري، استخدم (end_time-start_time)*1440.

الحصول على فرق الثواني بين وقتين

لحساب فرق الثواني بين وقتين في الخليتين A5 وB5، يرجى استخدام الصيغة التالية:

=(B11-A11)*86400)

اضغط Enter على المفتاح، ثم قم بتغيير تنسيق النتيجة إلى عام أو رقم.

1.23 حساب الفرق بالساعات فقط بين وقتين (لا يتجاوز24 ساعة)

إذا كان الفرق بين وقتين لا يتجاوز24 ساعة، يمكن لدالة HOUR الحصول بسرعة على فرق الساعات بين هذين الوقتين.

انقر على HOUR لمزيد من التفاصيل حول هذه الدالة.

لحساب فرق الساعات بين وقتين في الخليتين A14 وB14، يرجى استخدام دالة HOUR كما يلي:

=HOUR(B14-A14)

اضغط Enter على المفتاح للحصول على النتيجة.

يجب أن يكون start_time أصغر من end_time، وإلا ستعيد الصيغة قيمة خطأ #NUM!.

1.24 حساب الفرق بالدقائق فقط بين وقتين (لا يتجاوز60 دقيقة)

يمكن لدالة MINUTE الحصول بسرعة على فرق الدقائق فقط بين هذين الوقتين مع تجاهل الساعات والثواني.

انقر على MINUTE لمزيد من التفاصيل حول هذه الدالة.

لحساب فرق الدقائق فقط بين وقتين في الخليتين A17 وB17، يرجى استخدام دالة MINUTE كما يلي:

=MINUTE(B17-A17)

اضغط Enter على المفتاح للحصول على النتيجة.

يجب أن يكون start_time أصغر من end_time، وإلا ستعيد الصيغة قيمة خطأ #NUM!.

1.25 حساب الفرق بالثواني فقط بين وقتين (لا يتجاوز60 ثانية)

يمكن لدالة SECOND الحصول بسرعة على فرق الثواني فقط بين هذين الوقتين مع تجاهل الساعات والدقائق.

انقر على SECOND لمزيد من التفاصيل حول هذه الدالة.

لحساب فرق الثواني فقط بين وقتين في الخليتين A20 وB20، يرجى استخدام دالة SECOND كما يلي:

=SECOND(B20-A20)

اضغط Enter على المفتاح للحصول على النتيجة.

يجب أن يكون start_time أصغر من end_time، وإلا ستعيد الصيغة قيمة خطأ #NUM!.

1.26 حساب الفرق بين وقتين وإرجاع الساعات والدقائق والثواني

إذا كنت ترغب في عرض الفرق بين وقتين بصيغة xx ساعة xx دقيقة xx ثانية، يرجى استخدام دالة TEXT كما هو موضح أدناه:

انقر على TEXT لمعرفة الوسيطات وطريقة استخدام هذه الدالة.

لحساب الفرق بين وقتين في الخليتين A23 وB23، استخدم الصيغة التالية:

=TEXT(B23-A23,"h"" hours ""m"" minutes ""s"" seconds"").

اضغط Enter على المفتاح للحصول على النتيجة.

ملاحظة:

هذه الصيغة تحسب أيضًا فرق الساعات فقط إذا لم يتجاوز24 ساعة، ويجب أن يكون end_time أكبر من start_time، وإلا ستظهر قيمة خطأ #VALUE!.

1.27 حساب الفرق بين تاريخين ووقتين (تاريخ ووقت)

إذا كان لديك وقتان بتنسيق mm/dd/yyyy hh:mm:ss، لحساب الفرق بينهما يمكنك استخدام إحدى الصيغ التالية حسب حاجتك.

الحصول على الفرق الزمني بين تاريخين ووقتين وإرجاع النتيجة بتنسيق hh:mm:ss

على افتراض وجود تاريخين ووقتين في الخليتين A2 وB2، يرجى استخدام الصيغة التالية:

=B2-A2

اضغط Enter على المفتاح، وستظهر النتيجة بتنسيق تاريخ ووقت، ثم قم بتنسيق النتيجة كالتالي [h]:mm:ss ضمن الفئة المخصصة في رقم تبويب في تنسيق الخلايا مربع الحوار.
 

الحصول على الفرق بين تاريخين ووقتين وإرجاع الأيام والساعات والدقائق والثواني

على افتراض وجود تاريخين ووقتين في الخليتين A5 وB5، يرجى استخدام الصيغة التالية:

=INT(B5-A5) & " Days, " & HOUR(B5-A5) & " Hours, " & MINUTE(B5-A5) & " Minutes, " & SECOND(B5-A5) & " Seconds "

اضغط Enter على المفتاح للحصول على النتيجة.

ملاحظة: في كلتا الصيغتين، يجب أن يكون end_datetime أكبر من start_datetime، وإلا ستعيد الصيغ قيم خطأ.

1.28 حساب الفرق الزمني مع أجزاء الألف من الثانية (ميلي ثانية)

أولاً، تحتاج إلى معرفة كيفية تنسيق الخلية لعرض أجزاء الألف من الثانية:

حدد الخلايا التي ترغب في عرض أجزاء الألف من الثانية بها وانقر بزر الفأرة الأيمن لاختيار تنسيق الخلايا لتفعيل تنسيق الخلايا مربع الحوار، اختر مخصص في الفئة ضمن تبويب الرقم، واكتب التالي hh:mm:ss.000 في مربع النص.

استخدم الصيغة:

لحساب الفرق بين وقتين في الخليتين A8 وB8، استخدم الصيغة التالية:

=ABS(B8-A8)

اضغط Enter على المفتاح للحصول على النتيجة.

1.29 حساب ساعات العمل بين تاريخين مع استثناء عطلات نهاية الأسبوع

أحيانًا قد تحتاج إلى عد ساعات العمل بين تاريخين مع استثناء عطلات نهاية الأسبوع (السبت والأحد).

هنا ساعات العمل ثابتة8 ساعات يوميًا، ولحساب ساعات العمل بين تاريخين في الخليتين A16 وB16، يرجى استخدام الصيغة التالية:

=NETWORKDAYS(A16,B16) *8

اضغط Enter على المفتاح ثم قم بتنسيق النتيجة كرقم أو عام.

لمزيد من الأمثلة حول حساب ساعات العمل بين تاريخين، يرجى زيارة الحصول على ساعات العمل بين تاريخين في Excel

إذا كان لديك Kutools لـ Excel مثبتًا في Excel، يمكنك حل90% من حسابات الفرق بين التواريخ والأوقات بسرعة دون الحاجة لحفظ أي صيغ.

1.31 حساب الفرق بين تاريخين ووقتين بواسطة مساعد التاريخ والوقت

لحساب الفرق بين تاريخين ووقتين في Excel، يكفي فقط استخدام مساعد التاريخ والوقت فقط.

1. حدد خلية لوضع النتيجة المحسوبة، ثم انقر على Kutools > مساعد الصيغة > مساعد التاريخ والوقت.

2. في مربع حوار مساعد التاريخ والوقت المنبثق، اتبع الإعدادات التالية:

1. حدد خيار الفرق;
2. حدد تاريخ ووقت البدء وتاريخ ووقت الانتهاء في قسم إدخال الوسيطات، يمكنك أيضًا إدخال التاريخ والوقت يدويًا في مربع الإدخال، أو النقر على أيقونة التقويم لاختيار التاريخ؛
3. حدد نوع النتيجة المخرجة من القائمة المنسدلة؛
4. معاينة النتيجة في قسم النتيجة.

3. انقر على موافق. سيتم إخراج النتيجة المحسوبة، واسحب مقبض التعبئة التلقائية على الخلايا الأخرى التي تحتاج أيضًا إلى حساب الفرق بينها.

نصيحة:

إذا كنت ترغب في الحصول على الفرق بين تاريخين ووقتين وعرض النتيجة كأيام وساعات ودقائق باستخدام Kutools لـ Excel، يرجى اتباع التالي:

حدد خلية لوضع النتيجة، ثم انقر على Kutools > مساعد الصيغة > التاريخ والوقت > عد الأيام والساعات والدقائق بين تاريخين.

ثم في مساعد الصيغ مربع الحوار، حدد تاريخ البدء وتاريخ الانتهاء، ثم انقر على موافق.

وسيتم عرض نتيجة الفرق كأيام وساعات ودقائق.

انقر على مساعد التاريخ والوقت لمعرفة المزيد عن استخدام هذه الميزة.

انقر على Kutools لـ Excel لمعرفة جميع ميزات هذا الإضافة.

انقر على تنزيل مجاني للحصول على نسخة تجريبية مجانية لمدة 30 يوم من Kutools لـ Excel

1.32 حساب الفرق بين عطلة نهاية الأسبوع/أيام العمل/يوم أسبوع محدد بين تاريخين ووقتين بواسطة مساعد الصيغة

إذا كنت ترغب في عد عطلات نهاية الأسبوع أو أيام العمل أو يوم أسبوع محدد بسرعة بين تاريخين ووقتين، يمكن لمجموعة مساعد الصيغة في Kutools لـ Excel مساعدتك. مساعد الصيغة في ذلك.

1. حدد الخلية التي ستضع فيها النتيجة المحسوبة، انقر على Kutools > العدد > عدد الأيام غير العمل بين تاريخين/عدد أيام العمل بين تاريخين/عدد أيام الأسبوع بين تاريخين.

2. في مربع حوار مساعد الصيغ المنبثق، حدد تاريخ البدء وتاريخ الانتهاء، وإذا طبقت عد عدد أيام الأسبوع بين تاريخين، تحتاج أيضًا إلى تحديد يوم الأسبوع.

لحساب يوم أسبوع محدد، يمكنك الرجوع إلى الملاحظة لاستخدام الأرقام من1 إلى7 للدلالة على الأحد إلى السبت.

3. انقر على موافق، ثم اسحب مقبض التعبئة التلقائية على الخلايا التي تحتاج إلى عد عدد عطلات نهاية الأسبوع/أيام العمل/يوم أسبوع محدد إذا لزم الأمر.

انقر على Kutools لـ Excel لمعرفة جميع ميزات هذا الإضافة.

انقر على تنزيل مجاني للحصول على نسخة تجريبية مجانية لمدة 30 يوم من Kutools لـ Excel

2. إضافة أو طرح التاريخ والوقت

بخلاف حساب الفرق بين تاريخين ووقتين، فإن الإضافة أو الطرح هو أيضًا من العمليات الشائعة على التاريخ والوقت في Excel. على سبيل المثال، قد ترغب في معرفة تاريخ الاستحقاق بناءً على تاريخ الإنتاج وعدد أيام الحفظ للمنتج.

2.11 إضافة أو طرح أيام إلى تاريخ

لإضافة أو طرح عدد معين من الأيام إلى تاريخ، هناك طريقتان مختلفتان.

على افتراض أنك تريد إضافة21 يومًا إلى تاريخ في الخلية A2، يرجى اختيار إحدى الطرق التالية لحل ذلك،

الطريقة1: التاريخ+الأيام

حدد خلية واكتب الصيغة:

=A+21

اضغط Enter على المفتاح للحصول على النتيجة.

إذا كنت ترغب في طرح21 يومًا، فقط غيّر علامة الجمع (+) إلى علامة الطرح (-).

الطريقة2: لصق خاص

1. اكتب عدد الأيام التي تريد إضافتها في خلية (مثلاً في الخلية C2)، ثم اضغط Ctrl + C للنسخ.

2. ثم حدد التواريخ التي تريد إضافة21 يومًا إليها، وانقر بزر الفأرة الأيمن لإظهار قائمة السياق، ثم اختر لصق خاص....

3. في لصق خاص مربع الحوار، حدد إضافة خيار (إذا كنت ترغب في طرح أيام، حدد طرح خيار). انقر على موافق.

4. الآن ستتغير التواريخ الأصلية إلى أرقام مكونة من5 أرقام، قم بتنسيقها كتاريخ.

2.12 إضافة أو طرح أشهر إلى تاريخ

لإضافة أو طرح أشهر إلى تاريخ، يمكن استخدام دالة EDATE.

انقر على EDATE لدراسة الوسيطات وطريقة الاستخدام.

على افتراض أنك تريد إضافة6 أشهر إلى تاريخ في الخلية A2، استخدم الصيغة التالية:

=EDATE(A2,6)

اضغط Enter على المفتاح للحصول على النتيجة.

إذا كنت ترغب في طرح6 أشهر من التاريخ، غيّر6 إلى -6.

2.13 إضافة أو طرح سنوات إلى تاريخ

لإضافة أو طرح عدد من السنوات إلى تاريخ، يمكن استخدام صيغة تجمع بين دوال DATE وYEAR وMONTH وDAY.

على افتراض أنك تريد إضافة3 سنوات إلى تاريخ في الخلية A2، استخدم الصيغة التالية:

=DATE(YEAR(A2) +3, MONTH(A2),DAY(A2))

اضغط Enter على المفتاح للحصول على النتيجة.

إذا كنت ترغب في طرح3 سنوات من التاريخ، غيّر3 إلى -3.

2.14 إضافة أو طرح أسابيع إلى تاريخ

لإضافة أو طرح أسابيع إلى تاريخ، الصيغة العامة هي

على افتراض أنك تريد إضافة4 أسابيع إلى تاريخ في الخلية A2، استخدم الصيغة التالية:

=A2+4*7

اضغط Enter على المفتاح للحصول على النتيجة.

إذا كنت ترغب في طرح4 أسابيع من التاريخ، غيّر علامة الجمع (+) إلى علامة الطرح (-).

2.15 إضافة أو طرح أيام عمل مع أو بدون العطلات

في هذا القسم، يتم شرح كيفية استخدام دالة WORKDAY لإضافة أو طرح أيام العمل إلى تاريخ معين مع استثناء أو تضمين العطلات.

قم بزيارة WORKDAY لمعرفة المزيد من التفاصيل حول الوسيطات وطريقة الاستخدام.

إضافة أيام عمل مع العطلات

في الخلية A2 يوجد التاريخ الذي ستستخدمه، وفي الخلية B2 يوجد عدد الأيام التي تريد إضافتها، يرجى استخدام الصيغة التالية:

=WORKDAY(A2,B2)

اضغط Enter على المفتاح للحصول على النتيجة.

إضافة أيام عمل مع استثناء العطلات

في الخلية A5 يوجد التاريخ الذي ستستخدمه، وفي الخلية B5 يوجد عدد الأيام التي تريد إضافتها، وفي النطاق D5:D8 توجد العطلات، يرجى استخدام الصيغة التالية:

=WORKDAY(A5,B5,D5:D8)

اضغط Enter على المفتاح للحصول على النتيجة.

ملاحظة:

تعتبر دالة WORKDAY يومي السبت والأحد كعطلة نهاية الأسبوع، إذا كانت عطلة نهاية الأسبوع لديك مختلفة، يمكنك استخدام دالة WORKDAY.INTL التي تتيح لك تحديد عطلات نهاية الأسبوع.

قم بزيارة WORKDAY.INTL لمزيد من التفاصيل.

إذا كنت ترغب في طرح أيام عمل من تاريخ، فقط غيّر عدد الأيام إلى رقم سالب في الصيغة.

2.16 إضافة أو طرح سنة محددة أو شهر أو أيام إلى تاريخ

إذا كنت ترغب في إضافة سنة أو شهر أو أيام محددة إلى تاريخ، يمكن أن تساعدك صيغة تجمع بين دوال DATE وYEAR وMONTH وDAYS.

لإضافة سنة واحدة وشهرين و30 يومًا إلى تاريخ في الخلية A11، يرجى استخدام الصيغة التالية:

=DATE(YEAR(A11)+1,MONTH(A11)+2,DAY(A11)+30)

اضغط Enter على المفتاح للحصول على النتيجة.

إذا كنت ترغب في الطرح، غيّر جميع علامات الجمع (+) إلى علامات الطرح (-).

2.21 إضافة أو طرح ساعات/دقائق/ثواني إلى تاريخ ووقت

هنا بعض الصيغ لإضافة أو طرح ساعات أو دقائق أو ثواني إلى تاريخ ووقت.

إضافة أو طرح ساعات إلى تاريخ ووقت

على افتراض أنك تريد إضافة3 ساعات إلى تاريخ ووقت (أو وقت فقط) في الخلية A2، يرجى استخدام الصيغة التالية:

=A2+3/24

اضغط Enter على المفتاح للحصول على النتيجة.

إضافة أو طرح دقائق إلى تاريخ ووقت

على افتراض أنك تريد إضافة15 دقيقة إلى تاريخ ووقت (أو وقت فقط) في الخلية A5، يرجى استخدام الصيغة التالية:

=A2+15/1440

اضغط Enter على المفتاح للحصول على النتيجة.

إضافة أو طرح ثواني إلى تاريخ ووقت

على افتراض أنك تريد إضافة20 ثانية إلى تاريخ ووقت (أو وقت فقط) في الخلية A8، يرجى استخدام الصيغة التالية:

=A2+20/86400

اضغط Enter على المفتاح للحصول على النتيجة.

2.22 جمع الأوقات التي تتجاوز24 ساعة

على افتراض وجود جدول في Excel يسجل أوقات العمل لجميع الموظفين خلال أسبوع، لجمع إجمالي وقت العمل لحساب الرواتب، يمكنك استخدام SUM(النطاق) للحصول على النتيجة. ولكن عادةً، ستظهر النتيجة المجمعة كوقت لا يتجاوز24 ساعة كما هو موضح في الصورة أدناه، فكيف يمكنك الحصول على النتيجة الصحيحة؟

في الواقع، فقط قم بتنسيق النتيجة كـ [hh]:mm:ss.

انقر بزر الفأرة الأيمن على خلية النتيجة، واختر تنسيق الخلايا من قائمة السياق، وفي مربع الحوار المنبثق تنسيق الخلايا اختر مخصص من القائمة، واكتب [hh]:mm:ss في مربع النص على اليمين، ثم انقر على موافق.
  

سيتم عرض النتيجة المجمعة بشكل صحيح.

2.23 إضافة ساعات العمل إلى تاريخ مع استثناء عطلات نهاية الأسبوع والعطلات الرسمية

هنا صيغة طويلة للحصول على تاريخ الانتهاء بناءً على إضافة عدد معين من ساعات العمل إلى تاريخ بدء مع استثناء عطلات نهاية الأسبوع (السبت والأحد) والعطلات.

في جدول Excel، تحتوي الخلية A11 على تاريخ ووقت البدء، والخلية B11 على ساعات العمل، وفي الخليتين E11 وE13 أوقات بدء وانتهاء العمل، والخلية E15 تحتوي على العطلة التي سيتم استثناؤها.

يرجى استخدام الصيغة التالية:

=WORKDAY(A11,INT(B11/8)+IF(TIME(HOUR(A11),MINUTE(A11),SECOND(A11))+TIME(MOD(B11,8),MOD(MOD(B11,8),1)*60,0)> $E$13,1,0),$E$15)+IF(TIME(HOUR(A11),MINUTE(A11),SECOND(A11))+TIME(MOD(B11,8),MOD(MOD(B11,8),1)*60,0)>$E$13,$E$11 +TIME(HOUR(A11),MINUTE(A11),SECOND(A11))+TIME(MOD(B11,8),MOD(MOD(B11,8),1)*60,0)-$E$13,TIME(HOUR(A11),MINUTE(A11),SECOND(A11)) +TIME(MOD(B11,8),MOD(MOD(B11,8),1)*60,0))

اضغط Enter على المفتاح للحصول على النتيجة.

إذا كان لديك Kutools لـ Excel مثبتًا، أداة واحدة فقط – مساعد التاريخ والوقتيمكنها حل معظم العمليات الحسابية على إضافة وطرح التاريخ والوقت.

1. انقر على خلية تريد إخراج النتيجة فيها، وطبق هذه الأداة بالنقر على Kutools > مساعد الصيغة > مساعد التاريخ والوقت.

2. في مربع حوار مساعد التاريخ والوقت، حدد خيار إضافة أو خيار طرح حسب حاجتك، ثم اختر الخلية أو اكتب مباشرة التاريخ والوقت الذي تريد استخدامه في قسم إدخال الوسيطات، ثم حدد السنوات والأشهر والأسابيع والأيام والساعات والدقائق والثواني التي تريد إضافتها أو طرحها، ثم انقر على موافق. انظر الصورة:

يمكنك معاينة النتيجة المحسوبة في النتيجة القسم.

الآن تم إخراج النتيجة، اسحب مقبض التعبئة التلقائية على الخلايا الأخرى للحصول على النتائج.

انقر على مساعد التاريخ والوقت لمعرفة المزيد عن استخدام هذه الميزة.

انقر على Kutools لـ Excel لمعرفة جميع ميزات هذا الإضافة.

انقر على تنزيل مجاني للحصول على نسخة تجريبية مجانية لمدة 30 يوم من Kutools لـ Excel

2.41 التحقق أو تمييز إذا كان التاريخ منتهي الصلاحية

إذا كان لديك قائمة تواريخ انتهاء صلاحية المنتجات، قد ترغب في التحقق وتمييز التواريخ المنتهية بناءً على اليوم الحالي كما هو موضح في الصورة أدناه.

في الواقع، يمكن لتنسيق الشروط التعامل مع هذه المهمة بسرعة.

1. حدد التواريخ التي تريد التحقق منها، ثم انقر على الصفحة الرئيسية > تنسيق الشروط > قاعدة جديدة.

2. في قاعدة تنسيق جديدة مربع الحوار، اختر استخدام صيغة لتحديد الخلايا التي سيتم تنسيقها في تحديد نوع القاعدة القسم، واكتب =B2 في مربع الإدخال (B2 هو أول تاريخ تريد التحقق منه)، ثم انقر على تنسيق لإظهار تنسيق الخلايا مربع الحوار، ثم اختر تنسيقًا مختلفًا لتمييز التواريخ المنتهية حسب حاجتك. انقر على موافق > موافق.
  

2.42 إرجاع نهاية الشهر الحالي/أول يوم من الشهر القادم

تواريخ انتهاء صلاحية بعض المنتجات تكون في نهاية شهر الإنتاج أو في أول يوم من الشهر التالي للإنتاج، ولإدراج تواريخ الانتهاء بسرعة بناءً على تاريخ الإنتاج، يرجى اتباع هذا الجزء.

الحصول على نهاية الشهر الحالي

يوجد تاريخ إنتاج في الخلية B13، يرجى استخدام الصيغة التالية:

=EOMONTH(B13,0)

اضغط Enter على المفتاح للحصول على النتيجة.

الحصول على أول يوم من الشهر القادم

يوجد تاريخ إنتاج في الخلية B18، يرجى استخدام الصيغة التالية:

=EOMONTH(B18,0)+1

اضغط Enter على المفتاح للحصول على النتيجة.

3. حساب العمر

في هذا القسم، ستجد طرق حل كيفية حساب العمر بناءً على تاريخ معين أو رقم تسلسلي.

3.11 حساب العمر بناءً على تاريخ الميلاد المحدد

الحصول على العمر كرقم عشري بناءً على تاريخ الميلاد

انقر على YEARFRAC لمعرفة تفاصيل الوسيطات وطريقة الاستخدام.

على سبيل المثال، لحساب الأعمار بناءً على قائمة تواريخ الميلاد في العمود B2:B9، يرجى استخدام الصيغة التالية:

=YEARFRAC(B2,TODAY())

اضغط Enter على المفتاح، ثم اسحب مقبض التعبئة التلقائية للأسفل حتى يتم حساب جميع الأعمار.

نصيحة:

1) يمكنك تحديد عدد الأماكن العشرية حسب حاجتك في تنسيق الخلايا مربع الحوار.

2) إذا كنت ترغب في حساب العمر في تاريخ محدد بناءً على تاريخ ميلاد معين، غيّر TODAY() إلى التاريخ المحدد بين علامتي اقتباس مزدوجتين مثل =YEARFRAC(B2,"1/1/2021")

3) إذا كنت ترغب في الحصول على عمر السنة القادمة بناءً على تاريخ الميلاد، فقط أضف1 في الصيغة مثل =YEARFRAC(B2,TODAY())+1.

الحصول على العمر كعدد صحيح بناءً على تاريخ الميلاد

انقر على DATEDIF لمعرفة تفاصيل الوسيطات وطريقة الاستخدام.

باستخدام المثال أعلاه، لحساب العمر بناءً على تواريخ الميلاد في القائمة في B2:B9، يرجى استخدام الصيغة التالية:

=DATEDIF(B2,TODAY(),"y")

اضغط Enter على المفتاح، ثم اسحب مقبض التعبئة التلقائية للأسفل حتى يتم حساب جميع الأعمار.

نصيحة:

1) إذا كنت ترغب في حساب العمر في تاريخ محدد بناءً على تاريخ ميلاد معين، غيّر TODAY() إلى التاريخ المحدد بين علامتي اقتباس مزدوجتين مثل =DATEDIF(B2,"1/1/2021","y").

2) إذا كنت ترغب في الحصول على عمر السنة القادمة بناءً على تاريخ الميلاد، فقط أضف1 في الصيغة مثل =DATEDIF(B2,TODAY(),"y")+1.

3.12 حساب العمر بصيغة سنوات وأشهر وأيام بناءً على تاريخ الميلاد

إذا كنت ترغب في حساب العمر بناءً على تاريخ ميلاد معين، وعرض النتيجة بصيغة xx سنوات، xx أشهر، xx أيام كما هو موضح في الصورة أدناه، فهناك صيغة طويلة يمكن أن تساعدك.

لحساب العمر بالسنوات والأشهر والأيام بناءً على تاريخ الميلاد في الخلية B12، يرجى استخدام الصيغة التالية:

=DATEDIF(B12,TODAY(),"Y")&" Years, "&DATEDIF(B12,TODAY(),"YM")&" Months, "&DATEDIF(B12,TODAY(),"MD")&" Days"

اضغط Enter على المفتاح للحصول على العمر، ثم اسحب مقبض التعبئة التلقائية للأسفل إلى الخلايا الأخرى.

نصيحة:

إذا كنت ترغب في حساب العمر في تاريخ محدد بناءً على تاريخ ميلاد معين، غيّر TODAY() إلى التاريخ المحدد بين علامتي اقتباس مزدوجتين مثل =DATEDIF(B12,"1/1/2021","Y")&" Years, "&DATEDIF(B12,"1/1/2021","YM")&" Months, "&DATEDIF(B12,"1/1/2021","MD")&" Days".

3.13 حساب العمر بناءً على تاريخ ميلاد قبل1/1/1900

في Excel، لا يمكن إدخال تاريخ قبل1/1/1900 كتاريخ ووقت أو حسابه بشكل صحيح. ولكن إذا كنت ترغب في حساب عمر شخص مشهور بناءً على تاريخ ميلاد (قبل1/1/1900) وتاريخ الوفاة، يمكن فقط لكود VBA مساعدتك.

1. اضغط على مفاتيح Alt + F11 لتفعيل نافذة Microsoft Visual Basic for Applications، ثم انقر على تبويب إدراج واختر وحدة نمطية لإنشاء وحدة جديدة.

2. ثم انسخ والصق الكود أدناه في الوحدة الجديدة.

VBA: حساب العمر قبل1/1/1900

Public Function AgeFunc(SDate As Variant, EDate As Variant) As Long
'UpdatebyExtendOffice
    Dim xSMonth As Integer
    Dim xSDay As Integer
    Dim xSYear As Integer
    Dim xEMonth As Integer
    Dim xEDay As Integer
    Dim xEYear As Integer
    Dim xAge As Integer
    If Not GetDate(SDate, xSYear, xSMonth, xSDay) Then
        AgeFunc = "Invalid Date"
        Exit Function
    End If
    If Not GetDate(EDate, xEYear, xEMonth, xEDay) Then
        AgeFunc = "Invalid Date"
        Exit Function
    End If
    xAge = xEYear - xSYear
    If xSMonth > xEMonth Then
        xAge = xAge - 1
    ElseIf xSMonth = xEMonth Then
        If xSDay > xEDay Then xAge = xAge - 1
    End If
    If xAge < 0 Then
        AgeFunc = "Invalid Date"
    Else
        AgeFunc = xAge
    End If
End Function
Private Function GetDate(ByVal DateStr As String, Y As Integer, M As Integer, D As Integer) As Boolean
    Dim I As Long
    Dim K As Long
    Y = 0
    M = 0
    D = 0
    GetDate = True
    On Error Resume Next
    I = InStr(1, DateStr, "/")
    M = CLng(Left(DateStr, I - 1))
    D = CLng(Mid(DateStr, I + 1, InStr(I + 1, DateStr, "/") - I - 1))
    Y = CLng(Right(DateStr, Len(DateStr) - InStrRev(DateStr, "/")))
    If M < 1 Or M > 12 Or D < 1 Or D > 31 Or Y < 1 Then
        GetDate = False
    End If
End Function

3. احفظ الكود، وارجع إلى الورقة وحدد خلية لوضع العمر المحسوب، واكتب =AgeFunc(birthdate,deathdate)، في هذه الحالة، =AgeFunc(B22,C22), اضغط على مفتاح Enter للحصول على العمر. واستخدم مقبض التعبئة التلقائية لتطبيق هذه الصيغة على خلايا أخرى إذا لزم الأمر.

إذا كان لديك Kutools لـ Excel مثبت في Excel، يمكنك تطبيق أداة مساعد التاريخ والوقت لحساب العمر.

1. حدد خلية لوضع العمر المحسوب، ثم انقر على Kutools > مساعد الصيغة > مساعد التاريخ والوقت.

2. في مربع حوار مساعد التاريخ والوقت،

• 1) حدد خيار العمر;
• 2) اختر خلية تاريخ الميلاد أو أدخل تاريخ الميلاد مباشرة أو انقر على أيقونة التقويم لاختيار تاريخ الميلاد؛
• 3) اختر خيار اليوم إذا كنت ترغب في حساب العمر الحالي، أو اختر خيار تاريخ محدد وأدخل التاريخ إذا كنت ترغب في حساب العمر في الماضي أو المستقبل؛
• 4) حدد نوع الإخراج من القائمة المنسدلة؛
• 5) معاينة نتيجة الإخراج. انقر على موافق.

انقر على مساعد التاريخ والوقت لمعرفة المزيد عن استخدام هذه الميزة.

انقر على Kutools لـ Excel لمعرفة جميع ميزات هذا الإضافة.

انقر على تنزيل مجاني للحصول على نسخة تجريبية مجانية لمدة 30 يوم من Kutools لـ Excel

3.31 استخراج تاريخ الميلاد من رقم الهوية

إذا كان لديك قائمة بأرقام الهوية التي تستخدم أول6 أرقام لتسجيل تاريخ الميلاد مثل920315330 يعني أن تاريخ الميلاد هو15/03/1992، كيف يمكنك استخراج تاريخ الميلاد بسرعة إلى عمود آخر؟

لنأخذ قائمة أرقام الهوية التي تبدأ في الخلية C2 كمثال، واستخدم الصيغة التالية:

=MID(C2,5,2)&"/"&MID(C2,3,2)&"/"&MID(C2,1,2)

اضغط Enter على المفتاح. ثم اسحب مقبض التعبئة التلقائية للأسفل للحصول على النتائج الأخرى.

ملاحظة:

في الصيغة، يمكنك تغيير المرجع حسب حاجتك. على سبيل المثال، إذا كان رقم الهوية يظهر كـ13219920420392، وتاريخ الميلاد هو20/04/1992، يمكنك تغيير الصيغة إلى =MID(C2,8,2)&"/"&MID(C2,10,2)&"/"&MID(C2,4,4) للحصول على النتيجة الصحيحة.

3.32 حساب العمر من رقم الهوية

إذا كان لديك قائمة بأرقام الهوية التي تستخدم أول6 أرقام لتسجيل تاريخ الميلاد مثل920315330 يعني أن تاريخ الميلاد هو15/03/1992، كيف يمكنك حساب العمر بسرعة بناءً على كل رقم هوية في Excel؟

لنأخذ قائمة أرقام الهوية التي تبدأ في الخلية C2 كمثال، واستخدم الصيغة التالية:

=DATEDIF(DATE(IF(LEFT(C2,2)>TEXT(TODAY(),"YY"),"19"&LEFT(C2,2),"20"&LEFT(C2,2)),MID(C2,3,2),MID(C2,5,2)),TODAY(),"y")

اضغط Enter على المفتاح. ثم اسحب مقبض التعبئة التلقائية للأسفل للحصول على النتائج الأخرى.

ملاحظة:

في هذه الصيغة، إذا كان العام أقل من العام الحالي، سيتم اعتبار العام يبدأ بـ20، مثل200203943 سيتم اعتباره عام2020؛ وإذا كان العام أكبر من العام الحالي، سيتم اعتباره يبدأ بـ19، مثل920420392 سيتم اعتباره عام1992.

المزيد من دروس Excel:

---

أفضل أدوات إنتاجية لمكتب العمل

Kutools لـ Excel يحل معظم مشاكلك ويزيد من إنتاجيتك بنسبة 80%

• شريط الصيغة الفائق (تحرير سهل للنصوص والصيغ المتعددة الأسطر); تخطيط القراءة (قراءة وتحرير سهل للخلايا الكبيرة العدد); لصق إلى النطاق المُرشح...
• دمج الخلايا/الصفوف/الأعمدة مع الاحتفاظ بالبيانات; تقسيم محتوى الخلايا; دمج الصفوف المكررة والمجموع/المتوسط... منع الخلايا المكررة; مقارنة النطاقات...
• تحديد الصفوف المكررة أو الفريدة; تحديد الصفوف الفارغة (جميع الخلايا فارغة); البحث المتقدم والبحث الضبابي في العديد من المصنفات; اختيار عشوائي...
• نسخ دقيق للخلايا المتعددة دون تغيير مرجع الصيغة; إنشاء تلقائي للمراجع إلى أوراق متعددة; إدراج رموز تعداد نقطي، مربعات اختيار وأكثر...
• تفضيل وإدراج سريع للصيغ، النطاقات، الرسوم البيانية والصور; تشفير الخلايا بكلمة مرور; إنشاء قائمة بريدية وإرسال رسائل البريد الإلكتروني...
• استخراج النص، إضافة نص، إزالة الأحرف في موضع محدد، إزالة المسافات; إنشاء وطباعة إحصاءات صفحة البيانات; التحويل بين محتويات الخلايا والتعليقات...
• مرشح متقدم (حفظ وتطبيق مخططات التصفية على أوراق أخرى); ترتيب متقدم حسب الشهر/الأسبوع/اليوم، التكرار وأكثر; تصفية خاصة حسب العريض، المائل...
• تجميع المصنفات وأوراق العمل; دمج الجداول بناءً على الأعمدة الرئيسية; تقسيم البيانات إلى أوراق متعددة; تحويل دفعة xls، xlsx وPDF...
• تجميع جدول محوري حسب رقم الأسبوع، يوم الأسبوع وأكثر... عرض الخلايا غير المؤمنة، المؤمنة بألوان مختلفة; تمييز الخلايا التي تحتوي على صيغة/اسم...

اقرأ المزيد... تجربة مجانية لمدة 30 يومًا بكامل الميزات... شراء... 

---

Office Tab - يجلب واجهة التبويب إلى Office، ويجعل عملك أسهل بكثير

• تمكين التحرير والقراءة بتبويب في Word، Excel، PowerPoint، Publisher، Access، Visio وProject.
• فتح وإنشاء مستندات متعددة في تبويبات جديدة لنفس النافذة، بدلاً من النوافذ الجديدة.
• يزيد من إنتاجيتك بنسبة 50%، ويقلل من مئات النقرات بالماوس لك كل يوم!

اقرأ المزيد... تجربة مجانية لمدة 30 يومًا بكامل الميزات... شراء...