كيفية العثور على واستبدال نصوص متعددة في Word باستخدام Excel؟

في Microsoft Word، تعتبر ميزة البحث والاستبدال وسيلة فعالة للبحث بسرعة واستبدال نصوص معينة. ومع ذلك، عندما تحتاج إلى استبدال عدة مصطلحات مختلفة، يمكن أن يكون إدخال كل منها يدويًا أمرًا يستغرق وقتًا طويلاً.

لتسهيل هذه العملية، يمكنك استخدام Excel لإنشاء قائمة بالنصوص التي تريد العثور عليها واستبدالها، ثم أتمتة المهمة باستخدام كود VBA بسيط. سيرشدك هذا البرنامج التعليمي خلال استخدام Excel وVBA للعثور على النصوص واستبدالها في مستند Word واحد. بالإضافة إلى ذلك، سأوضح لك كيفية توسيع هذا ليشمل مستندات متعددة وأقدم لك ميزة قوية من Kutools لاستبدال النصوص بشكل جماعي.

العثور على النصوص واستبدالها في مستند Word واحد من Excel باستخدام كود VBA

العثور على النصوص واستبدالها في مستندات Word متعددة من Excel باستخدام كود VBA

العثور على النصوص واستبدالها في مستندات Word متعددة باستخدام ميزة قوية

العثور على النصوص واستبدالها في مستند Word واحد من Excel باستخدام كود VBA

إذا كنت ترغب في العثور على بعض النصوص واستبدالها في ملف Word واحد فقط، يمكن أن يساعدك الكود التالي لـ VBA.

1. في ورقة عمل Excel، قم بإنشاء عمود يحتوي على النصوص التي تريد العثور عليها واستبدالها، وعمود آخر بالنصوص التي سيتم استبدالها بها كما هو موضح في لقطة الشاشة أدناه. وبعد ذلك اضغط على مفاتيح Alt+ F11 معًا لفتح نافذة Microsoft Visual Basic for Applications.

2. بعد ذلك، انقر فوق إدراج > وحدة، وقم بنسخ ولصق كود VBA أدناه في النافذة.

كود VBA: العثور على النصوص واستبدالها في ملف Word واحد

Sub replace_texts_range_of_cells()
'Updateby ExtendOffice
Dim xWordApp As Word.Application
Dim xDoc As Word.Document
Dim xRng As Range
Dim I As Integer
Dim xFileDlg As FileDialog
On Error GoTo ExitSub
Set xFileDlg = Application.FileDialog(msoFileDialogFilePicker)
xFileDlg.AllowMultiSelect = False
xFileDlg.Filters.Add "Word Document", "*.docx; *.doc; *.docm"
xFileDlg.FilterIndex = 2
If xFileDlg.Show <> -1 Then GoTo ExitSub
Set xRng = Application.InputBox("Please select the lists of find and replace texts (Press Ctrl key to select two same size ranges):", "Kutools for Excel", , , , , , 8)
If xRng.Areas.Count <> 2 Then
  MsgBox "Please select two columns (press Ctrl key), the two ranges have the same size.", vbInformation + vbOKOnly, "Kutools for Excel"
  GoTo ExitSub
End If
If (xRng.Areas.Item(1).Rows.Count <> xRng.Areas.Item(2).Rows.Count) Or _
  (xRng.Areas.Item(1).Columns.Count <> xRng.Areas.Item(2).Columns.Count) Then
  MsgBox "Please select two columns (press Ctrl key), the two ranges have the same size.", vbInformation + vbOKOnly, "Kutools for Excel"
  GoTo ExitSub
End If
Set xWordApp = CreateObject("Word.application")
xWordApp.Visible = True
Set xDoc = xWordApp.Documents.Open(xFileDlg.SelectedItems.Item(1))
For I = 1 To xRng.Areas.Item(1).Cells.Count
  With xDoc.Application.Selection.Find
    .ClearFormatting
    .Replacement.ClearFormatting
    .Text = xRng.Areas.Item(1).Cells.Item(I).Value
    .Replacement.Text = xRng.Areas.Item(2).Cells.Item(I).Value
    .Forward = True
    .Wrap = wdFindContinue
    .Format = False
    .MatchCase = False
    .MatchWholeWord = False
    .MatchByte = False
    .MatchWildcards = False
    .MatchSoundsLike = False
    .MatchAllWordForms = False
  End With
  xDoc.Application.Selection.Find.Execute Replace:=wdReplaceAll
Next
ExitSub:
  Set xRng = Nothing
  Set xFileDlg = Nothing
  Set xWordApp = Nothing
  Set xDoc = Nothing
End Sub

3. بعد لصق الكود، لا تزال في نافذة Microsoft Visual Basic for Applications، انقر فوق أدوات > مراجع، انظر لقطة الشاشة:

4. في مربع الحوار المنبثق References – VBAProject، حدد خيار Microsoft Word 16.0 Object Library من قائمة الخيارات، انظر لقطة الشاشة:

5. انقر فوق زر موافق لإغلاق مربع الحوار، والآن اضغط على مفتاح F5 لتشغيل هذا الكود، وفي نافذة الاستعراض المنبثقة، حدد ملف Word الذي تريد استبدال النصوص فيه، انظر لقطة الشاشة:

6. بعد ذلك، انقر فوق موافق، في مربع الحوار التالي، اضغط مع الاستمرار على مفتاح Ctrl لتحديد خلايا النص الأصلي والنص الجديد التي تريد استخدامها، انظر لقطة الشاشة:

7. وبعد ذلك، انقر فوق زر موافق، الآن تم العثور على النصوص واستبدالها بالنصوص الجديدة في المستند المحدد، ويتم فتح الملف أيضًا، يجب عليك حفظه للحفاظ على التغييرات.

العثور على النصوص واستبدالها في مستندات Word متعددة من Excel باستخدام كود VBA

لقد قمت أيضًا بإنشاء كود VBA لمساعدتك في العثور على النصوص واستبدالها عبر مستندات Word متعددة. اتبع الخطوات التالية:

1. افتح ملف Excel الذي يحتوي على عمودين من القيم المراد استبدالها والقيم المراد استبدالها بها كما هو موضح في لقطة الشاشة أدناه، وبعد ذلك اضغط على مفاتيح Alt+ F11 معًا لفتح نافذة Microsoft Visual Basic for Applications.

2. بعد ذلك، انقر فوق إدراج > وحدة، وقم بنسخ ولصق كود VBA أدناه في النافذة.

كود VBA: العثور على النصوص واستبدالها في ملفات Word متعددة

Sub FindReplaceAcrossMultipleWordDocuments()
'Updateby ExtendOffice
Dim xWordApp As Word.Application
Dim xDoc As Word.Document
Dim xRng As Range
Dim I As Integer
Dim xFolderDlg As FileDialog
Dim xFSO As Scripting.FileSystemObject
Dim xFile As File
On Error GoTo ExitSub
Set xFolderDlg = Application.FileDialog(msoFileDialogFolderPicker)
If xFolderDlg.Show <> -1 Then GoTo ExitSub
Set xRng = Application.InputBox("Please select the lists of find and replace texts (Press Ctrl key to select two same size ranges", "Kutools for Excel", , , , , , 8)
If xRng.Areas.Count <> 2 Then
  MsgBox "Please select two columns (press Ctrl key), the two ranges have the same size", vbInformation + vbOKOnly, "Kutools for Excel"
  GoTo ExitSub
End If
If (xRng.Areas.Item(1).Rows.Count <> xRng.Areas.Item(2).Rows.Count) Or _
  (xRng.Areas.Item(1).Columns.Count <> xRng.Areas.Item(2).Columns.Count) Then
  MsgBox "Please select two columns (press Ctrl key), the two ranges have the same size.", vbInformation + vbOKOnly, "Kutools for Excel"
  GoTo ExitSub
End If
Set xFSO = New Scripting.FileSystemObject
Set xWordApp = CreateObject("Word.application")
xWordApp.Visible = True
For Each xFile In xFSO.GetFolder(xFolderDlg.SelectedItems(1)).Files
  If VBA.InStr(xFile.Type, "Microsoft Word") > 0 Then
    Set xDoc = xWordApp.Documents.Open(xFile.Path)
    For I = 1 To xRng.Areas.Item(1).Cells.Count
      With xDoc.Application.Selection.Find
        .ClearFormatting
        .Replacement.ClearFormatting
        .Text = xRng.Areas.Item(1).Cells.Item(I).Value
        .Replacement.Text = xRng.Areas.Item(2).Cells.Item(I).Value
        .Forward = True
        .Wrap = wdFindContinue
        .Format = False
        .MatchCase = False
        .MatchWholeWord = False
        .MatchByte = False
        .MatchWildcards = False
        .MatchSoundsLike = False
        .MatchAllWordForms = False
      End With
      xDoc.Application.Selection.Find.Execute Replace:=wdReplaceAll
    Next
    xDoc.Close wdSaveChanges
  End If
Next
xWordApp.Quit
MsgBox "The Find and Replace has been completed", vbInformation + vbOKOnly, "Kutools for Excel"
ExitSub:
  Set xRng = Nothing
  Set xFolderDlg = Nothing
  Set xWordApp = Nothing
  Set xDoc = Nothing
End Sub

3. لا تزال في نافذة Microsoft Visual Basic for Applications، انقر فوق أدوات > مراجع، في مربع الحوار References – VBAProject، حدد خيارات Microsoft Word 16.0 Object Library وMicrosoft Scripting Runtime من قائمة الخيارات، انظر لقطة الشاشة:

4. بعد تحديد الخيارين، انقر فوق موافق لإغلاق مربع الحوار، وبعد ذلك، استمر في الضغط على مفتاح F5 لتنفيذ هذا الكود، في نافذة الاستعراض المفتوحة، اختر مجلدًا يحتوي على مستندات Word التي تريد تنفيذ عملية البحث والاستبدال فيها، انظر لقطة الشاشة:

5. انقر فوق زر موافق، في مربع الحوار المنبثق، اضغط مع الاستمرار على مفتاح Ctrl لتحديد أعمدة النص الأصلي والنص الجديد التي تريد استخدامها، انظر لقطة الشاشة:

6. أخيرًا، انقر فوق موافق، وسيتم استبدال النصوص الأصلية بالنصوص الجديدة عبر هذه الملفات، وبعد الانتهاء، سيظهر مربع حوار كما هو موضح في لقطة الشاشة أدناه:

7. انقر فوق موافق لإغلاق مربع الحوار. ويمكنك الانتقال إلى الملفات للتحقق من نتائج التحويل.

العثور على النصوص واستبدالها في مستندات Word متعددة باستخدام ميزة قوية

في هذا القسم، سأشرح كيفية البحث الجماعي عن النصوص واستبدالها عبر مستندات Word متعددة باستخدام Word نفسه، بدلاً من Excel. باستخدام Kutools for Word القوي، يمكنك البحث بكفاءة عن نصوص معينة واستبدالها بنصوص جديدة في الجزء الرئيسي، الهوامش، التعليقات، والمزيد، مع تسليط الضوء على النتائج عند الحاجة.

1. افتح أحد ملفات Word، وبعد ذلك انقر فوق Kutools Plus > Batch Find and Replace، انظر لقطة الشاشة:

2. في مربع الحوار Batch Find and Replace الذي تم فتحه، يرجى القيام بالعمليات التالية:

• انقر فوق زر إضافة لإضافة ملفات Word حيث تريد العثور على النصوص واستبدالها؛
• في اللوحة اليسرى، انقر فوق إضافة صف من الشريط العلوي؛
• في الحقل المدرج، أدخل النص الأصلي والنص الجديد في أعمدة البحث والاستبدال على حدة التي تريد العثور عليها واستبدالها. أيضًا، يمكنك تحديد لون لتسليط الضوء على النصوص المستبدلة حسب الحاجة.

3. بعد إنشاء معايير البحث، انقر فوق زر استبدال للانتقال إلى علامة تبويب معاينة النتيجة لعرض نتائج البحث والاستبدال. انظر لقطة الشاشة:

4. بعد ذلك، انقر فوق زر إغلاق، وسيظهر مربع مطالبة ينبهك إذا كنت تريد حفظ هذا السيناريو، انقر فوق نعم لحفظه، وانقر فوق لا لتتجاهله، انظر لقطة الشاشة:

قم بالمزيد في وقت أقل مع Kutools المُحسّن بالذكاء الاصطناعي لبرنامج Word

Kutools for Word ليس مجرد مجموعة من الأدوات - بل هو حل ذكي مصمم لتعزيز إنتاجيتك. بفضل الإمكانيات المدعومة بالذكاء الاصطناعي والميزات الأكثر أهمية، يساعدك Kutools على تحقيق المزيد في وقت أقل:

• تلخيص وإعادة كتابة وتأليف وترجمة المحتوى فوراً.
• تدقيق النصوص في الوقت الفعلي مع اقتراحات حول القواعد والنحو والأسلوب أثناء الكتابة.
• إعادة صياغة وترجمة المحتوى مع الحفاظ على التخطيط والنمط والهيكل دون تغيير.
• ترجمة المحتوى الخاص بك إلى أكثر من 40 لغة بسهولة، مما يوسع نطاق وصولك عالميًا.
• الحصول على مساعدة فورية وأفكار ذكية بناءً على محتوى المستند الحالي.
• اسأل عن كيفية إكمال مهمة - مثل إزالة فواصل الأقسام - وسيقوم الذكاء الاصطناعي بإرشادك أو القيام بذلك نيابةً عنك.
• حجب المعلومات الحساسة أو السرية في غضون ثوانٍ لضمان الخصوصية الكاملة.
• كل الأدوات تعمل بسلاسة داخل Word، دائمًا في متناول اليد.

• إنشاء وتحسين وترجمة وتلخيص وتأمين المستندات بسهولة.
• تحسين القواعد والوضوح والأسلوب أثناء الكتابة في الوقت الفعلي.
• إعادة صياغة وترجمة المحتوى بدون أي تغييرات في التخطيط أو التنسيق.
• اسأل عن كيفية إكمال مهمة - مثل إزالة فواصل الأقسام - وسيقوم الذكاء الاصطناعي بإرشادك أو القيام بذلك نيابةً عنك.
• كل الأدوات تعمل بسلاسة داخل Word، دائمًا في متناول اليد.

تعرف على المزيد حول Kutools for Word تحميل الآن