KutoolsforOffice — حل واحد، خمس أدوات قوية.تحقيق المزيد بجهد أقل.

عد القيم الفريدة والمميزة بسهولة – 7 أمثلة

المؤلفشياويانغتاريخ التعديل

عادةً في Excel، تشير القيم الفريدة إلى تلك التي تظهر مرة واحدة فقط في القائمة دون أي تكرارات، بينما تشمل القيم المميزة جميع القيم المختلفة (أي القيم الفريدة بالإضافة إلى أول ظهور لكل قيمة مكررة). عند التعامل مع مجموعة بيانات كبيرة، قد تحتاج إلى حساب عدد القيم الفريدة والمميزة من بين التكرارات في قائمة خلايا، كما هو موضح في لقطة الشاشة أدناه. ويعرض هذا البرنامج التعليمي بعض الحيل السريعة لعد القيم الفريدة والمميزة في Excel.

عد القيم الفريدة أو القيم المميزة في قائمة

عدد القيم الفريدة في نطاق في Excel

عدد فريد القيم (الفريدة وأول حالة تكرار) في Excel

عدد القيم الفريدة في نطاق في Excel

سيستعرض هذا القسم بعض الأمثلة على الصيغ لعدّ القيم الفريدة، بما في ذلك تصنيفها حسب النص والأرقام في القائمة.

عدد القيم الفريدة في نطاق باستخدام الصيغ

لنفترض أن لدي قائمة أسماء تحتوي على بعض الأسماء المكررة. الآن، أحتاج إلى الحصول على عدد الأسماء الفريدة فقط (المعبأة باللون الأصفر)، كما هو موضح في لقطة الشاشة أدناه:

بيانات عينة

لحل هذه المشكلة، يمكن للصيغة التالية ذات المصفوفة أن تساعدك:

الخطوة 1: إدخال الصيغة

أدخل أو انسخ الصيغة أدناه في خلية فارغة حيث تريد إخراج النتيجة:

=SUM(IF(COUNTIF(A2:A12,A2:A12)=1,1,0))
ملاحظة: في الصيغة أعلاه، "A2:A12" هي قائمة البيانات التي تريد عد القيم الفريدة فيها.

الخطوة 2: اضغط على مفاتيح Ctrl + Shift + Enter للحصول على النتيجة الصحيحة:

عد القيم الفريدة باستخدام صيغة

ملاحظات:

  1. إذا احتوت قائمة الخلايا على أنواع أخرى من البيانات—مثل الأرقام أو القيم المنطقية (Booleans) أو قيم الأخطاء وما إلى ذلك—فإن تطبيق الصيغة أعلاه سيُعطيك عدد القيم الفريدة، بغض النظر عن نوع البيانات.
  2. عند احتواء قائمة البيانات على خلايا فارغة، تستبعد هذه الصيغة تلك الخلايا تلقائيًا.
  3. لحساب عدد القيم النصية الفريدة فقط إذا كانت هناك أنواع أخرى من البيانات، يُرجى تطبيق صيغة الصفيف أدناه، ثم الضغط على مفاتيح «Ctrl» + «Shift» + «Enter» لإرجاع النتيجة:
    =SUM(IF(ISTEXT(A2:A12)*COUNTIF(A2:A12,A2:A12)=1,1,0))
  4. لحساب عدد القيم الرقمية الفريدة فقط من قائمة خلايا تحتوي على أي نوع من البيانات، يُرجى استخدام صيغة الصفيف التالية، ثم الضغط على مفاتيح «Ctrl» + «Shift» + «Enter» لإرجاع النتيجة:
    =SUM(IF(ISNUMBER(A2:A12)*COUNTIF(A2:A12,A2:A12)=1,1,0))

عدد القيم الفريدة في نطاق بنقرات قليلة بواسطة Kutools لـ Excel

قد يصعب عليك تذكُّر الصيغ عندما تحتاج إلى تطبيقها في المرة القادمة. ولكن مع «Kutools لـ Excel» وخاصية «عدد القيم الفريدة في النطاق» المتاحة ضمن «مساعد الصيغة»، يمكنك الحصول على النتيجة بنقراتٍ قليلة فقط! شاهد العرض التوضيحي أدناه:

  1. انقر على خلية لإخراج النتيجة؛
  2. فعّل هذه الميزة بالنقر على «Kutools» > «مساعد الصيغة» > «مساعد الصيغة» > «Statistical» > «عدد القيم الفريدة في نطاق»؛
  3. حدد قائمة البيانات، ثم انقر «موافق».
    عد القيم الفريدة باستخدام kutools
نصائح:
  1. لتطبيق هذه الميزة، تحتاج إلىتنزيل وتثبيت Kutools لـ Excel.
  2. تجمع ميزة «مساعد الصيغة» أكثر من 40 صيغة شائعة الاستخدام، مثل «استخراج القيم الفريدة»، و«استخراج الخلايا ذات القيم الفريدة من نطاق (بما في ذلك التكرارات الأولى)»، و«عدّ القيم المفصولة بفواصل في خلية»، و«الجمع بناءً على نفس النص»، وغيرها الكثير...

عدد القيم الفريدة في نطاق في Excel 365/2021 باستخدام الصيغ

إذا كنت تستخدم Excel 365 أو Excel 2021، فستجد دالة UNIQUE الجديدة التي تُسهّل عليك إنشاء صيغ أبسط لحساب عدد القيم الفريدة في نطاق ضمن مجموعة البيانات.

على سبيل المثال، لعد عدد الأسماء الفريدة في النطاق A2:A12، يُرجى إدخال الصيغة التالية：

الخطوة 1: انسخ أو أدخل الصيغة أدناه

=IFERROR(ROWS(UNIQUE(A2:A12,,TRUE)), 0)
ملاحظة: في هذه الصيغة، "A2:A12" هي قائمة البيانات التي تريد عدد القيم الفريدة في نطاق.

الخطوة 2: اضغط على مفتاح Enter للحصول على النتيجة:

عد القيم الفريدة في Excel 365/2021 باستخدام صيغة

نصائح:

  1. إذا احتوت قائمة البيانات على أنواع مختلفة من البيانات—مثل النصوص، الأرقام، القيم المنطقية، أو قيم الأخطاء وما إلى ذلك—فستحسب هذه الصيغة عدد القيم الفريدة بغض النظر عن نوعها.
  2. ستحسب الصيغة أعلاه عدد القيم الفريدة في النطاق، بما في ذلك الخلايا الفارغة. إذا كنت ترغب في استبعاد الخلايا الفارغة، يُرجى تطبيق الصيغة أدناه، ثم اضغط مفتاح «Enter» فقط:
    =SUM(IF(COUNTIF(A2:A12,A2:A12)=1,1,0))

عدد فريد القيم (الفريدة وأول حالة تكرار) في Excel

لحساب القيم المختلفة (القيم الفريدة وأول حالة تكرار) في قائمة الخلايا، إليك صيغًا أخرى لتحقيق هذه المهمة.

عدد فريد القيم باستخدام الصيغ

في Excel، يمكنك استخدام أيٍّ من الصيغ أدناه لإرجاع عدد القيم المميزة.

الخطوة 1: أدخل أيّاً من الصيغ أدناه

الصيغة 1: بعد إدخال الصيغة، اضغط مفتاح «Enter».

=SUMPRODUCT(1/COUNTIF(A2:A12,A2:A12))

الصيغة 2: بعد إدخال الصيغة، اضغط على مفاتيح «Ctrl» + «Shift» + «Enter».

=SUM(1/COUNTIF(A2:A12,A2:A12))
ملاحظة: في هذه الصيغ، "A2:A12" هي قائمة البيانات التي تريد عد قيمة مختلفة فيها.

النتيجة:

عد القيم المميزة باستخدام صيغة

نصائح:

  1. إذا احتوت قائمة البيانات على أنواع أخرى من البيانات—مثل الأرقام أو القيم المنطقية أو قيم الأخطاء وما إلى ذلك—فستُرجع هذه الصيغة القيم المميزة بغض النظر عن نوعها.
  2. عند استخدام الصيغة أعلاه، ستحصل على قيمة خطأ #DIV/0 إذا احتوت قائمة البيانات على خلايا فارغة. ولإصلاح ذلك وتجاهل الخلايا الفارغة، يجب تطبيق إحدى الصيغتين أدناه:
    الصيغة 1: بعد إدخال الصيغة، اضغط على مفتاح «Enter».
    =SUMPRODUCT((A2:A12<>"")/COUNTIF(A2:A12,A2:A12&""))
    الصيغة 2: بعد إدخال الصيغة، اضغط على مفاتيح «Ctrl» + «Shift» + «Enter».
    =SUM(IF(A2:A12<>"",1/COUNTIF(A2:A12, A2:A12), 0))

    عد القيم المميزة باستثناء الخلايا الفارغة باستخدام صيغة

  3. للحصول على عدد القيم النصية المميزة فقط ضمن قائمة بيانات، يُرجى تطبيق صيغة الصفيف أدناه، ثم الضغط على مفاتيح «Ctrl» + «Shift» + «Enter» للحصول على النتيجة:
    =SUM(IF(ISTEXT(A2:A12),1/COUNTIF(A2:A12, A2:A12),""))
  4. لحساب عدد القيم الرقمية المميزة فقط، يُرجى استخدام صيغة الصفيف التالية، ثم الضغط على مفاتيح «Ctrl» + «Shift» + «Enter» للحصول على النتيجة:
    =SUM(IF(ISNUMBER(A2:A12),1/COUNTIF(A2:A12, A2:A12),""))

عدد فريد القيم بنقرات قليلة بواسطة Kutools لـ Excel

إذا كنت بحاجة إلى تطبيق الصيغ بشكل متكرر في مصنفك، فقد يصعب عليك تذكّرها في المرة القادمة. ولكن مع «Kutools لـ Excel» وخاصيته «Count cells with unique values (include the first duplicate)» المتاحة في «مساعد الصيغة»، يمكنك الحصول على النتيجة بنقرات قليلة فقط. شاهد العرض التوضيحي أدناه:

  1. انقر على خلية لإخراج النتيجة؛
  2. فعّل هذه الميزة بالنقر على «Kutools» > «مساعد الصيغة» > «Statistical» > «Count unique cells with unique values (include the first duplicate)»؛
  3. حدد قائمة البيانات، ثم انقر «موافق».
    عد القيم المميزة باستخدام kutools
نصائح:
  1. لتطبيق هذه الميزة، ستحتاج إلىتنزيل وتثبيت Kutools لـ Excel.
  2. تجمع ميزة «مساعد الصيغة» أكثر من 40 صيغة شائعة الاستخدام، مثل «استخراج القيم الفريدة»، و«استخراج الخلايا ذات القيم الفريدة من نطاق (بما في ذلك التكرارات الأولى)»، و«عدّ القيم المفصولة بفواصل في خلية»، و«الجمع بناءً على نفس النص»، وغيرها الكثير...

عدد فريد القيم باستخدام PivotTable

في Excel، يمكن لـ PivotTable أيضاً مساعدتك في الحصول على عدد القيم المميزة من قائمة البيانات، يُرجى اتباع الخطوات التالية:

الخطوة 1: إنشاء جدول بيانات محوري

  1. حدد قائمة البيانات، ثم انقر على «Insert» > «PivotTable» من الشريط، انظر لقطة الشاشة:
    إنشاء جدول محوري للبيانات المحددة
  2. في مربع الحوار المنبثق «PivotTable from table or range»:
    (1). اختر ورقة عمل جديدة أو ورقة عمل موجودة لوضع الجدول المحوري فيها؛
    (2). بعد ذلك، فعّل خانة الاختيار «Add this data to the Data Model»؛
    (3). ثم انقر على زر «OK».
    تعيين الخيارات في مربع حوار الجدول المحوري من جدول أو نطاق

الخطوة 2: تنظيم الحقل واختيار خيار Distinct Count

  1. يظهر جزء «PivotTable Fields»، اسحب حقل «Names» إلى منطقة «Values»، انظر العرض التوضيحي أدناه:
    ترتيب الحقول للجدول المحوري
  2. بعد ذلك، انقر على القائمة المنسدلة لـ «Count of Names»، واختر «Value إعدادات الحقول»، انظر لقطة الشاشة:
    انقر على خيار إعدادات حقل القيمة
  3. بعد ذلك، سيُفتح مربع حوار «Value إعدادات الحقول»، اختر «Distinct Count» من مربع القائمة تحت تبويب «Summarize Value By»، ثم انقر على زر «OK»، انظر لقطة الشاشة:
    حدد خيار العد المميز

النتيجة:

الآن، سيعرض جدول بيانات محوري الذي تم إنشاؤه عدد القيم المميزة من قائمة البيانات كما هو موضح في لقطة الشاشة أدناه:

نتيجة الجدول المحوري لعد القيم المميزة

نصائح:

  1. إذا قمت بتحديث بياناتك الأصلية للحصول على أحدث الأرقام، فما عليك سوى النقر بزر الماوس الأيمن على الجدول المحوري واختيار «تحديث».
  2. يتوفر خيار «العد المميز» (Distinct Count) في Excel 2013 والإصدارات الأحدث فقط.

عدد فريد القيم في Excel 365/2021 باستخدام الصيغ

في Excel 365 أو Excel 2021، يمكنك دمج الدالة الجديدة UNIQUE مع دالة COUNTA المعتادة لإنشاء صيغة بسيطة وفعّالة.

يرجى نسخ الصيغة أدناه أو إدخالها في خلية فارغة، ثم الضغط على مفتاح «Enter» للحصول على النتيجة:

=COUNTA(UNIQUE(A2:A12))
ملاحظة: في هذه الصيغة، "A2:A12" هي قائمة البيانات التي تريد عدد فريد القيم فيها.

عد القيم المميزة في Excel 365/2021 باستخدام صيغة

نصائح:

  1. إذا احتوت قائمة البيانات على أنواعٍ أخرى من البيانات—مثل النصوص، الأرقام، القيم المنطقية، قيم الأخطاء، وما إلى ذلك—فستحسب هذه الصيغة عدد القيم المميزة بغض النظر عن نوع البيانات.
  2. ستحسب الصيغة أعلاه عدد القيم الفريدة، بما في ذلك الخلايا الفارغة. إذا كنت ترغب في استبعاد الخلايا الفارغة، يُرجى تطبيق الصيغة أدناه، ثم الضغط على مفتاح «Enter» للحصول على النتيجة:
    =COUNTA(UNIQUE(FILTER(A2:A12, A2:A12<>"")))

    عد القيم المميزة في Excel 365/2021 باستخدام صيغة مع استثناء الخلايا الفارغة

مقالات ذات صلة:

  • عدد القيم الفريدة في نطاق في جدول بيانات محوري
  • بشكل افتراضي، عند إنشاء جدول بيانات محوري استنادًا إلى نطاق يحتوي على قيم مكررة، يتم احتساب جميع السجلات. لكن في بعض الأحيان، قد ترغب فقط في حساب القيم الفريدة بناءً على عمود واحد للحصول على نتيجة دقيقة تعكس لقطة الشاشة الصحيحة. في هذه المقالة، سأوضح لك كيفية حساب القيم الفريدة في جدول بيانات محوري.
  • عدد القيم الفريدة في نطاق بمعايير متعددة
  • هنا نطاق من البيانات يحتوي على أسماء ومشاريع ومواقع متعددة، وما نحتاج إليه هو تحديد الأسماء التي تطابق المعايير المذكورة، ثم احتساب كل اسم مطابق مرة واحدة فقط، كما يظهر في لقطة الشاشة أدناه. هل تعرف حيلةً ذكيةً لحل هذه المهمة؟ في هذا المقال، سأكشف لك تلك الحيل!
  • دمج القيم الفريدة
  • إذا كانت لديّ قائمة طويلة من القيم تحتوي على بيانات مكرَّرة، وأريد استخراج القيم الفريدة فقط ثم دمجها في خلية واحدة، فكيف يمكنني حل هذه المهمة بسرعة وسهولة في Excel؟