إتقان عبارات IF المتداخلة في Excel – دليل خطوة بخطوة
في Excel، على الرغم من أن الدالة IF ضرورية للاختبارات المنطقية الأساسية، إلا أن الحالات المعقدة غالبًا ما تتطلب عبارات IF متداخلة لتحسين معالجة البيانات. في هذا الدليل الشامل، سنغطي أساسيات IF المتداخلة بالتفصيل، بدءًا من بناء الجملة وحتى التطبيقات العملية، بما في ذلك مجموعات IF المتداخلة مع شروط AND/OR. بالإضافة إلى ذلك، سنشارك كيفية تحسين إمكانية قراءة وظائف IF المتداخلة بالإضافة إلى بعض النصائح حول IF المتداخلة، واستكشاف البدائل القوية مثل VLOOKUP وIFS والمزيد لجعل العمليات المنطقية المعقدة أسهل في الاستخدام وأكثر كفاءة.
- جعل المتداخلة إذا سهلة القراءة
- ترتيب وظائف IF المتداخلة
- يجب التعامل مع الأرقام والنصوص بشكل مختلف
- حدود IF المتداخلة
دالة Excel IF مقابل عبارات IF المتداخلة
تخدم الدالة IF وعبارات IF المتداخلة في Excel أغراضًا متشابهة ولكنها تختلف بشكل كبير في تعقيدها وتطبيقها.
- بناء الجملة هو:
=IF (logical_test, [value_if_true], [value_if_false]) - تحديد: يمكن التعامل مع شرط واحد فقط في كل مرة، مما يجعله أقل ملاءمة لسيناريوهات اتخاذ القرار الأكثر تعقيدًا والتي تتطلب تقييم معايير متعددة.
- بناء الجملة هو:
=IF( condition1, value_if_true1, IF( condition2, value_if_true2, value_if_false2 )) - تعقيد: يمكن التعامل مع شروط متعددة ولكن يمكن أن تصبح معقدة ويصعب قراءتها مع وجود طبقات كثيرة جدًا من التداخل.
استخدام IF المتداخلة
يوضح هذا القسم الاستخدام الأساسي لعبارات IF المتداخلة في Excel، بما في ذلك بناء الجملة والأمثلة العملية وكيفية استخدامها مع شروط AND أو OR.
بناء جملة IF المتداخلة
إن فهم بناء جملة الدالة هو الأساس لتطبيقها الصحيح والفعال في Excel. لنبدأ ببناء جملة عبارات if المتداخلة.
بناء الجملة:
=IF(condition1, result1, IF(condition2, result2, IF(condition3, result3, result4)))
الحجج:
- Condition1, Condition2, Condition3: These are the conditions you want to test. Each condition is evaluated in order, starting with Condition1.
- Result1: This is the value returned if Condition1 is TRUE.
- Result2: This value is returned if Condition1 is FALSE and Condition2 is TRUE. It's important to note that Result2 is only evaluated if Condition1 is FALSE.
- Result3: This value is returned if both Condition1 and Condition2 are FALSE, and Condition3 is TRUE. Essentially, for Result3 to be evaluated, the previous conditions (Condition1 and Condition2) must both be FALSE.
- Result4: This result is returned if all the conditions (Condition1, Condition2, and Condition3) are FALSE.
In short, this expression can be interpreted as follows:Test condition1, if TRUE, return result1, if FALSE,
test condition2, if TRUE, return result2, if FALSE,
test condition3, if TRUE, return result3, if FALSE,
return result4
تذكر، في بنية IF المتداخلة، يتم تقييم كل شرط لاحق فقط إذا كانت جميع الشروط السابقة خاطئة. يعد هذا التحقق المتسلسل أمرًا بالغ الأهمية لفهم كيفية عمل IFs المتداخلة.
أمثلة عملية على IF المتداخلة
الآن، دعونا نتعمق في استخدام IF المتداخل مع مثالين عمليين.
مثال 1: نظام الدرجات
كما هو موضح في لقطة الشاشة أدناه، لنفترض أن لديك قائمة بدرجات الطلاب وتريد تعيين درجات بناءً على هذه الدرجات. يمكنك استخدام IF المتداخل لإنجاز هذه المهمة.
حدد خلية فارغة (C2 في هذه الحالة)، وأدخل الصيغة التالية واضغط أدخل للحصول على النتيجة. ثم اسحب مقبض التعبئة أسفل للحصول على بقية النتائج.
=IF(B2>=90,$F$2,IF(B2>=80,$F$3,IF(B2>=70,$F$4,IF(B2>=60,$F$5,$F$6))))
- يمكنك تحديد مستوى التقدير مباشرة في الصيغة، بحيث يمكن تغيير الصيغة إلى:
=IF(A2>=90, "A", IF(A2>=80, "B", IF(A2>=70, "C", IF(A2>=60, "D", "F"))))
- تُستخدم هذه الصيغة لتعيين تقدير (A، أو B، أو C، أو D، أو F) بناءً على الدرجة الموجودة في الخلية A2، باستخدام حدود التقدير القياسية. إنها حالة استخدام نموذجية لعبارات IF المتداخلة في أنظمة الدرجات الأكاديمية.
- شرح الصيغة:
- أ2>=90: هذا هو الشرط الأول الذي تتحقق منه الصيغة. إذا كانت النتيجة في الخلية A2 أكبر من أو تساوي 90، فستُرجع الصيغة "A".
- أ2>=80: إذا كان الشرط الأول خاطئًا (النتيجة أقل من 90)، فإنه يتحقق مما إذا كانت A2 أكبر من أو تساوي 80. إذا كان صحيحًا، فسيتم إرجاع "B".
- أ2>=70: وبالمثل، إذا كانت النتيجة أقل من 80، فإنه يتحقق مما إذا كانت أكبر من أو تساوي 70. إذا كان صحيحًا، فسيتم إرجاع "C".
- أ2>=60: إذا كانت النتيجة أقل من 70، تتحقق الصيغة مما إذا كانت أكبر من أو تساوي 60. إذا كان صحيحًا، فسيتم إرجاع "D".
- "F": أخيرًا، إذا لم يتم استيفاء أي من الشروط المذكورة أعلاه (بمعنى أن النتيجة أقل من 60)، ترجع الصيغة "F".
مثال 2: حساب عمولة المبيعات
تخيل سيناريو يحصل فيه مندوبو المبيعات على معدلات عمولة مختلفة بناءً على إنجازاتهم في المبيعات. كما هو موضح في لقطة الشاشة أدناه، فأنت تريد حساب عمولة مندوب المبيعات استنادًا إلى حدود المبيعات المختلفة، ويمكن أن تساعدك عبارات IF المتداخلة في ذلك.
- 20% للمبيعات التي تزيد عن 20,000 دولار
- 15% للمبيعات التي تتراوح بين 10,000 دولار و20,000 دولار
- 10% للمبيعات التي تقل عن 10,000 دولار
حدد خلية فارغة (C2 في هذه الحالة)، وأدخل الصيغة التالية واضغط أدخل للحصول على النتيجة. ثم اسحب مقبض التعبئة أسفل للحصول على بقية النتائج.
=B2*IF(B2>20000,$F$2,IF(B2>=10000,$F$3,$F$4))
- يمكنك تحديد سعر العمولة مباشرة في الصيغة، بحيث يمكن تغيير الصيغة إلى:
=B2*IF(B2>20000, 20%, IF(B2>=10000, 15%, 10%))
- يتم استخدام الصيغة المتوفرة لحساب عمولة مندوب المبيعات استنادًا إلى مبلغ مبيعاته، مع تطبيق معدلات عمولة مختلفة لحدود مبيعات مختلفة.
- شرح الصيغة:
- B2: يمثل هذا مبلغ المبيعات لمندوب المبيعات، والذي يستخدم كأساس لحساب العمولة.
- إذا (B2>20000، "20%"، ...): هذا هو الشرط الأول الذي تم التحقق منه. فهو يتحقق مما إذا كان مبلغ المبيعات في B2 أكبر من 20,000. إذا كان الأمر كذلك، فإن الصيغة تستخدم معدل عمولة قدره 20%.
- إذا(B2>=10000، "15%"، "10%"): إذا كان الشرط الأول خاطئًا (المبيعات ليست أكبر من 20,000)، تتحقق الصيغة مما إذا كانت المبيعات تساوي أو تتجاوز 10,000. إذا كان هذا صحيحا، فإنه يطبق معدل عمولة 15٪. إذا كان مبلغ المبيعات أقل من 10,000، فستكون الصيغة افتراضية بمعدل عمولة قدره 10%.
متداخل إذا كان مع شرط و/أو
في هذا القسم، قمت بتعديل المثال الأول أعلاه "نظام التقدير" لتوضيح كيفية دمج IF المتداخل مع شرط AND أو OR في Excel. في مثال الدرجات المعدل، قدمت شرطًا إضافيًا يعتمد على "معدل الحضور".
استخدام المتداخلة إذا مع الشرط
إذا استوفى الطالب معايير الدرجات والحضور، فسيحصل على زيادة في الدرجات. على سبيل المثال، الطالب الذي تبلغ درجته 60 أو أعلى ومعدل حضوره 95% أو أعلى، سيتم ترقية درجته بمستوى واحد، مثل من A إلى A+، ومن B إلى B+ وما إلى ذلك. ومع ذلك، إذا كان معدل الحضور أقل من 95%، فسوف يتبع التقييم المعايير الأصلية المعتمدة على الدرجات. في مثل هذه الحالات، نحتاج إلى استخدام عبارة IF متداخلة مع شرط AND.
حدد خلية فارغة (D2 في هذه الحالة)، وأدخل الصيغة التالية واضغط أدخل للحصول على النتيجة. ثم اسحب مقبض التعبئة أسفل للحصول على بقية النتائج.
=IF(AND(B2>=60, C2>=95%),IF(B2>=90, "A+", IF(B2>=80, "B+", IF(B2>=70, "C+", "D+"))),IF(B2>=90, "A", IF(B2>=80, "B", IF(B2>=70, "C", IF(B2>=60, "D", "F")))))
- وفحص الحالة:
و(B2>=60، C2>=95%): يتحقق الشرط "و" أولاً من استيفاء الشرطين - أن تكون درجة الطالب 60 أو أعلى، ومعدل حضوره 95% أو أكثر. - تعيين درجة جديدة:
IF(B2>=90، "A+"، IF(B2>=80، "B+"، IF(B2>=70، "C+"، "D+"))): إذا كان كلا الشرطين في جملة AND صحيحين، فستقوم الصيغة بعد ذلك بالتحقق من درجة الطالب ورفع درجته بمقدار مستوى واحد.- B2> = 90: إذا كانت الدرجة 90 فما فوق تكون الدرجة "أ".+".مهمة الصف الجديدة:
- B2> = 80: إذا كانت الدرجة 80 فما فوق (لكن أقل من 90) تكون الدرجة "ب".+".
- B2> = 70: إذا كانت النتيجة 70 فما فوق (لكن أقل من 80)، تكون الدرجة "C+".
- B2>=60: إذا كانت النتيجة 60 أو أعلى (لكن أقل من 70)، تكون الدرجة "D+".
- تعيين الصف العادي:
IF(B2>=90, "A"، IF(B2>=80, "B"، IF(B2>=70, "C"، IF(B2>=60, "D"، "F"))) ): إذا لم يتم استيفاء شرط "و" (إما أن تكون النتيجة أقل من 80 أو الحضور أقل من 95%)، تقوم الصيغة بتعيين درجات قياسية.- B2> = 90: النتيجة 90 أو أعلى تحصل على "A".
- B2> = 80: النتيجة 80 أو أعلى (لكن أقل من 90) تحصل على "B".
- B2> = 70: النتيجة 70 أو أعلى (لكن أقل من 80) تحصل على "C".
- B2> = 60: النتيجة 60 أو أعلى (لكن أقل من 70) تحصل على "D".
- الدرجات التي تقل عن 60 تحصل على "F".
استخدام متداخل إذا كان مع شرط OR
وفي هذه الحالة، سيتم رفع درجة الطالب درجة واحدة إذا كانت درجته 95 أو أعلى، أو إذا كانت نسبة حضوره 95% أو أكثر. إليك كيفية تحقيق ذلك باستخدام شروط IF وOR المتداخلة.
حدد خلية فارغة (D2 في هذه الحالة)، وأدخل الصيغة التالية واضغط أدخل للحصول على النتيجة. ثم اسحب مقبض التعبئة أسفل للحصول على بقية النتائج.
=IF(OR(B2>=95, C2>=95%),IF(B2>=90, "A+", IF(B2>=80, "B+", IF(B2>=70, "C+", IF(B2>=60, "D+", "F+")))),IF(B2>=90, "A", IF(B2>=80, "B", IF(B2>=70, "C", IF(B2>=60, "D", "F")))))
- أو التحقق من الحالة:
أو(B2>=95، C2>=95%): تتحقق الصيغة أولاً مما إذا كان أي من الشرطين صحيحًا — أن تكون درجة الطالب 95 أو أعلى، أو أن يكون معدل حضوره 95% أو أعلى. - تعيين الدرجة مع المكافأة:
IF(B2>=90، "A+"، IF(B2>=80، "B+"، IF(B2>=70، "C+"، IF(B2>=60، "D+"، "F+"))) ): إذا كان أحد الشرطين في عبارة OR صحيحًا، فسيتم رفع درجة الطالب درجة واحدة.- B2> = 90: إذا كانت الدرجة 90 فما فوق تكون الدرجة "A+".
- B2> = 80: إذا كانت النتيجة 80 فما فوق (لكن أقل من 90)، تكون الدرجة "B+".
- B2> = 70: إذا كانت النتيجة 70 فما فوق (لكن أقل من 80)، تكون الدرجة "C+".
- B2> = 60: إذا كانت النتيجة 60 فما فوق (لكن أقل من 70) تكون الدرجة "D+".
- وبخلاف ذلك، تكون الدرجة "F+".
- تعيين الصف العادي:
IF(B2>=80، "B"، IF(B2>=70، "C"، IF(B2>=60، "D"، "F")))): إذا لم يتم استيفاء أي من شروط OR (النتيجة أقل من 95 والحضور أقل من 95%)، تقوم الصيغة بتعيين الدرجات القياسية.- B2> = 90: النتيجة 90 أو أعلى تحصل على "A".
- B2> = 80: النتيجة 80 أو أعلى (لكن أقل من 90) تحصل على "B".
- B2> = 70: النتيجة 70 أو أعلى (لكن أقل من 80) تحصل على "C".
- B2> = 60: النتيجة 60 أو أعلى (لكن أقل من 70) تحصل على "D".
- الدرجات التي تقل عن 60 تحصل على "F".
جعل المتداخلة إذا سهلة القراءة
قد تبدو عبارة IF المتداخلة النموذجية مضغوطة ولكن قد يكون من الصعب فك تشفيرها.
في الصيغة التالية، من الصعب تحديد مكان انتهاء شرط وبدء شرط آخر بسرعة، خاصة مع زيادة التعقيد.
=IF(A2>=90, "A", IF(A2>=80, "B", IF(A2>=70, "C", IF(A2>=60, "D", "F"))))
الحل: إضافة فواصل الأسطر والمسافات البادئة
لتسهيل قراءة IF المتداخلة، يمكنك تقسيم الصيغة إلى أسطر متعددة مع كل IF متداخلة في سطر جديد. في الصيغة، ما عليك سوى وضع المؤشر قبل IF والضغط على مفتاحي Alt + Enter.
بعد كسر الصيغة أعلاه سوف تظهر على النحو التالي:
=IF(A2>=90, "A",
IF(A2>=80, "B",
IF(A2>=70, "C",
IF(A2>=60, "D", "F")))
)
يوضح هذا التنسيق مكان وجود كل شرط والمخرجات المقابلة له، مما يعزز إمكانية قراءة الصيغة.
ترتيب وظائف IF المتداخلة
يعد ترتيب الشروط المنطقية في صيغة IF المتداخلة أمرًا بالغ الأهمية لأنه يحدد كيفية تقييم Excel لهذه الشروط وبالتالي يؤثر على النتيجة النهائية للصيغة.
الصيغة الصحيحة
في مثال نظام الدرجات، نستخدم الصيغة التالية لتعيين الدرجات بناءً على الدرجات.
=IF(B2>=90, "A", IF(B2>=80, "B", IF(B2>=70, "C", IF(B2>=60, "D", "F"))))
يقوم Excel بتقييم الشروط في صيغة IF المتداخلة بشكل تسلسلي، من الشرط الأول إلى الأخير. تتحقق هذه الصيغة من الحد الأعلى للدرجات أولاً (>= 90 بالنسبة إلى "A") ثم تنتقل إلى الحدود الدنيا. ويضمن مقارنة النتيجة بأعلى درجة مؤهلة لها. إذا كان الشرط الأول صحيحًا (A2>=90)، فسيتم إرجاع "A" ولا يتم تقييم أي شروط أخرى.
صيغة مرتبة غير صحيحة
إذا تم عكس ترتيب الشروط، بدءًا من الحد الأدنى، فسيؤدي ذلك إلى إرجاع نتائج غير صحيحة.
=IF(B2>=60, "D", IF(B2>=70, "C", IF(B2>=80, "B", IF(B2>=90, "A", "F"))))
في هذه الصيغة غير الصحيحة، ستفي النتيجة 95 على الفور بالشرط الأول B2>=60 وسيتم تعيينها بشكل غير صحيح إلى الدرجة "D".
يجب التعامل مع الأرقام والنصوص بشكل مختلف
سيوضح لك هذا القسم كيفية التعامل مع الأرقام والنصوص بشكل مختلف في عبارات IF المتداخلة.
أرقام
يتم استخدام الأرقام للمقارنات والحسابات الحسابية. في عبارات IF المتداخلة، يمكنك مقارنة الأرقام مباشرةً باستخدام عوامل التشغيل مثل >، <، =، >=، و<=.
نص
في عبارات IF المتداخلة، يجب أن يكون النص محاطة بعلامات اقتباس مزدوجة. انظر A وB وC وD وF في الصيغة التالية:
=IF(A2>=90, "A", IF(A2>=80, "B", IF(A2>=70, "C", IF(A2>=60, "D", "F"))))
حدود IF المتداخلة
يسرد هذا القسم عدة قيود وعيوب IF المتداخلة.
التعقيد وسهولة القراءة:
على الرغم من أن برنامج Excel يسمح لك بدمج ما يصل إلى 64 دالة IF مختلفة، إلا أنه ليس من المستحسن على الإطلاق القيام بذلك. كلما زادت مستويات التداخل، أصبحت الصيغة أكثر تعقيدًا. يمكن أن يؤدي ذلك إلى صيغ يصعب قراءتها وفهمها وصيانتها.
معرض للخطأ:
علاوة على ذلك، يمكن أن تصبح عبارات IF المتداخلة المعقدة عرضة للأخطاء ويصعب تصحيحها أو تعديلها.
صعوبة التوسع أو التوسع:
إذا تغير منطقك أو كنت بحاجة إلى إضافة المزيد من الشروط، فقد يكون من الصعب تعديل أو توسيع نطاقات IF المتداخلة بشدة.
يعد فهم هذه القيود أمرًا أساسيًا لاستخدام عبارات IF المتداخلة بشكل فعال في Excel. في كثير من الأحيان، يمكن أن يؤدي الجمع بين IFs المتداخلة مع وظائف أخرى أو البحث عن أساليب بديلة إلى حلول أكثر كفاءة وقابلية للصيانة.
بدائل متداخلة IF
يسرد هذا القسم العديد من الوظائف في Excel التي يمكن استخدامها كبدائل لعبارات IF المتداخلة.
باستخدام VLOOKUP
يمكنك استخدام الدالة VLOOKUP بدلاً من عبارات IF المتداخلة لإنجاز المثالين العمليين أعلاه. وإليك كيف يمكنك القيام بذلك:
مثال 1: نظام الدرجات باستخدام VLOOKUP
سأوضح هنا كيفية استخدام VLOOKUP لتعيين الدرجات بناءً على الدرجات.
الخطوة 1: إنشاء جدول بحث للدرجات
أولاً، تحتاج إلى إنشاء جدول بحث (مثل E1:F6 في هذه الحالة) لنطاق الدرجات والدرجات المقابلة لها. ملاحظات: يجب فرز الدرجات الموجودة في العمود الأول من الجدول بترتيب تصاعدي.
الخطوة 2: تطبيق وظيفة VLOOKUP لتعيين الدرجات
حدد خلية فارغة (C2 في هذه الحالة)، وأدخل الصيغة التالية واضغط على أدخل مفتاح الحصول على الصف الأول. حدد خلية الصيغة هذه واسحبها مقبض التعبئة للحصول على بقية الدرجات.
=VLOOKUP(B2,$E$2:$F$6,2,TRUE)
- القيمة 95 في الخلية B2 هي ما تبحث عنه VLOOKUP في العمود الأول من جدول البحث ($E$2:$F$6). إذا تم العثور عليه، فإنه يقوم بإرجاع الدرجة المقابلة من العمود الثاني من الجدول، الموجود في نفس صف القيمة المطابقة.
- تذكر أن تجعل مرجع جدول البحث مطلقًا (أضف علامة الدولار ($) قبل المراجع)، مما يعني أن المرجع لن يتغير إذا تم نسخ الصيغة إلى خلية أخرى.
- لمعرفة المزيد عن وظيفة VLOOKUP، زيارة هذه الصفحة.
مثال 2: حساب عمولة المبيعات باستخدام VLOOKUP
يمكنك أيضًا استخدام VLOOKUP لإنجاز حساب عمولة المبيعات في Excel. يرجى القيام بما يلي.
الخطوة 1: إنشاء جدول بحث للدرجات
أولاً، تحتاج إلى إنشاء جدول بحث للمبيعات ومعدل العمولة المقابل، مثل E2:F4 في هذه الحالة. ملاحظات: يجب ترتيب المبيعات في العمود الأول من الجدول تصاعدياً.
الخطوة 2: تطبيق وظيفة VLOOKUP لتعيين الدرجات
حدد خلية فارغة (C2 في هذه الحالة)، وأدخل الصيغة التالية واضغط على مفتاح Enter للحصول على العمولة الأولى. حدد خلية الصيغة هذه واسحب مقبض التعبئة الخاص بها لأسفل للحصول على بقية النتائج.
=B2*VLOOKUP(B2,$E$2:$F$4,2,TRUE)
- في كلا المثالين، يتم استخدام VLOOKUP للبحث عن قيمة في جدول بناءً على قيمة بحث (النقاط أو مبلغ المبيعات) وإرجاع قيمة في نفس الصف من عمود محدد (الدرجة أو معدل العمولة). تشير المعلمة الرابعة TRUE إلى تطابق تقريبي، وهو مناسب لهذه السيناريوهات حيث قد لا تكون قيمة البحث الدقيقة موجودة في الجدول.
- لمعرفة المزيد عن وظيفة VLOOKUP، زيارة هذه الصفحة.
باستخدام آي إف إس
• وظيفة IFS يبسط العملية عن طريق إلغاء الحاجة إلى التداخل ويجعل الصيغ أسهل في القراءة والإدارة. إنه يعزز سهولة القراءة ويبسط التعامل مع الشيكات الشرطية المتعددة. للاستفادة من وظيفة IFS، تأكد من أنك تستخدم Excel 2019 أو إصدار أحدث، أو أن لديك اشتراك Office 365. دعونا نرى كيف يمكن تطبيقه في أمثلة عملية.
مثال 1: نظام الدرجات مع IFS
بافتراض نفس معايير التقدير كما كان من قبل، يمكن استخدام الدالة IFS على النحو التالي:
حدد خلية فارغة، مثل C2، وأدخل الصيغة التالية واضغط أدخل للحصول على النتيجة الأولى. حدد خلية النتيجة هذه واسحبها مقبض التعبئة أسفل للحصول على بقية النتائج.
=IFS(B2>=90,"A",B2>=80,"B",B2>=70,"C",B2>=60,"D",B2<60,"F")
- يتم تقييم كل حالة بالترتيب. بمجرد استيفاء الشرط، يتم إرجاع النتيجة المقابلة له، وتتوقف الصيغة عن التحقق من الشروط الإضافية. في هذه الحالة، يتم استخدام الصيغة لتعيين الدرجات بناءً على الدرجة في B2، باتباع مقياس الدرجات النموذجي حيث تتوافق الدرجات الأعلى مع درجة أفضل.
- لمعرفة المزيد عن وظيفة IFS، زيارة هذه الصفحة.
مثال 2: حساب عمولة المبيعات باستخدام IFS
بالنسبة لسيناريو حساب عمولة المبيعات، يتم تطبيق الدالة IFS على النحو التالي:
حدد خلية فارغة، مثل C2، وأدخل الصيغة التالية واضغط أدخل للحصول على النتيجة الأولى. حدد خلية النتيجة هذه واسحبها مقبض التعبئة أسفل للحصول على بقية النتائج.
=B2*IFS(B2>20000,20%,B2>=10000,15%,TRUE,10%)
باستخدام الاختيار والمطابقة
يمكن أن يكون أسلوب الاختيار والمطابقة أكثر كفاءة وأسهل في الإدارة مقارنةً بعبارات IF المتداخلة. تعمل هذه الطريقة على تبسيط الصيغة وإجراء التحديثات أو التغييرات بشكل أكثر وضوحًا. سأوضح أدناه كيفية استخدام مجموعة من الدالتين CHOOSE وMATCH للتعامل مع المثالين العمليين في هذه المقالة.
مثال 1: نظام الدرجات مع الاختيار والمطابقة
يمكنك استخدام مجموعة من وظيفتي الاختيار والمطابقة لتعيين التقديرات بناءً على درجات مختلفة.
الخطوة 1: إنشاء مصفوفة بحث تحتوي على قيم البحث
أولاً، تحتاج إلى إنشاء نطاق من الخلايا يحتوي على قيم العتبة التي ستبحث فيها MATCH، مثل $E$2:$E$6 في هذه الحالة. ملاحظات: يجب فرز الأرقام الموجودة في هذا النطاق بترتيب تصاعدي حتى تعمل الدالة MATCH بشكل صحيح عند استخدام نوع مطابقة تقريبي.
الخطوة 2: تطبيق الاختيار والمطابقة لتعيين الدرجات
حدد خلية فارغة (C2 في هذه الحالة)، وأدخل الصيغة التالية واضغط على أدخل مفتاح الحصول على الصف الأول. حدد خلية الصيغة هذه واسحبها مقبض التعبئة أسفل للحصول على بقية النتائج.
=CHOOSE(MATCH(B2, $E$2:$E$6, 1), "F", "D", "C", "B", "A")
- مطابقة(B2، $E$2:$E$6، 1): يبحث هذا الجزء من الصيغة عن النتيجة (95) في الخلية B2 ضمن النطاق $E$2:$E$6. يشير الرقم 1 إلى أن MATCH يجب أن تجد تطابقًا تقريبيًا، مما يعني أنها تعثر على أكبر قيمة في النطاق أقل من أو تساوي B2.
- اختر (...، "و"، "د"، "ج"، "ب"، "أ"): بناءً على الموضع الذي تم إرجاعه بواسطة الدالة MATCH، يقوم CHOOSE بتحديد الدرجة المقابلة.
- لمعرفة المزيد عن دالة MATCH, زيارة هذه الصفحة.
- لمعرفة المزيد عن اختر الوظيفة, زيارة هذه الصفحة.
مثال 2: حساب عمولة المبيعات باستخدام IFS
يمكن أن يكون استخدام مجموعة الاختيار والمطابقة لحساب عمولة المبيعات فعالاً أيضًا، خاصة عندما تستند معدلات العمولة إلى حدود المبيعات المحددة. دعونا نرى كيف يمكننا أن نفعل.
الخطوة 1: إنشاء مصفوفة بحث تحتوي على قيم البحث
أولاً، تحتاج إلى إنشاء نطاق من الخلايا يحتوي على قيم العتبة التي ستبحث فيها MATCH، مثل $E$2:$E$4 في هذه الحالة. ملاحظات: يجب فرز الأرقام الموجودة في هذا النطاق بترتيب تصاعدي حتى تعمل الدالة MATCH بشكل صحيح عند استخدام نوع مطابقة تقريبي.
الخطوة 2: قم بتطبيق الاختيار والمطابقة للحصول على النتائج
حدد خلية فارغة (C2 في هذه الحالة)، وأدخل الصيغة التالية واضغط على أدخل مفتاح الحصول على الصف الأول. حدد خلية الصيغة هذه واسحبها مقبض التعبئة أسفل للحصول على بقية النتائج.
=B2*CHOOSE(MATCH(B2, $E$2:$E$4, 1), 10%, 15%, 20%)
- لمعرفة المزيد عن دالة MATCH, زيارة هذه الصفحة.
- لمعرفة المزيد عن اختر الوظيفة, زيارة هذه الصفحة.
في الختام، يعد إتقان عبارات IF المتداخلة في Excel مهارة قيمة تعزز قدرتك على التعامل مع السيناريوهات المنطقية المعقدة في تحليل البيانات وعمليات اتخاذ القرار. على الرغم من أن IFs المتداخلة فعالة في العمليات المنطقية المعقدة، فمن المهم أن تضع في اعتبارك حدودها. يمكن للبدائل الأكثر بساطة مثل VLOOKUP وIFS وCHOOSE with MATCH أن توفر حلولاً أكثر بساطة في سيناريوهات معينة. بفضل هذه الرؤى، يمكنك الآن بثقة تطبيق تقنيات Excel الأكثر ملاءمة لمهام تحليل البيانات الخاصة بك، مما يضمن الوضوح والدقة والكفاءة في جداول البيانات الخاصة بك. بالنسبة لأولئك الذين يتوقون إلى التعمق في قدرات برنامج Excel، فإن موقعنا الإلكتروني يضم مجموعة كبيرة من البرامج التعليمية. اكتشف المزيد من النصائح والحيل الخاصة ببرنامج Excel هنا.
مقالات ذات صلة
استخدم الدالة IF مع AND و OR و NOT في Excel
عند دمجها مع عوامل التشغيل المنطقية مثل AND وOR وNOT، تتوسع إمكانيات الدالة IF بشكل ملحوظ. تكمن قوة هذا المزيج في قدرتها على معالجة حالات متعددة في وقت واحد، مما يوفر نتائج يمكن أن تتكيف مع سيناريوهات متنوعة ومعقدة. في هذا البرنامج التعليمي، سوف نستكشف كيفية الاستفادة بشكل فعال من هذه الوظائف القوية في Excel لفتح أبعاد جديدة لتحليل البيانات وتعزيز عملية اتخاذ القرار.
قائمة منسدلة مشروطة مع بيان IF
يوضح هذا البرنامج التعليمي 5 طرق ستساعدك في إنشاء قائمة منسدلة مشروطة في برنامج Excel خطوة بخطوة.
Power Query: عبارة If - ifs المتداخلة والشروط المتعددة
في Excel Power Query، تعد عبارة IF واحدة من أكثر الوظائف شيوعًا للتحقق من حالة ما وإرجاع قيمة محددة اعتمادًا على ما إذا كانت النتيجة TRUE أو FALSE. هناك بعض الاختلافات بين عبارة if هذه والدالة IF في Excel. في هذا البرنامج التعليمي، سأقدم لك بناء جملة عبارة if هذه وبعض الأمثلة البسيطة والمعقدة.
أفضل أدوات إنتاجية المكتب
عزز مهاراتك في Excel باستخدام Kutools for Excel، واختبر كفاءة لم يسبق لها مثيل. يقدم Kutools for Excel أكثر من 300 ميزة متقدمة لتعزيز الإنتاجية وتوفير الوقت. انقر هنا للحصول على الميزة التي تحتاجها أكثر...
يجلب Office Tab الواجهة المبوبة إلى Office ، ويجعل عملك أسهل بكثير
- تمكين التحرير والقراءة المبوبة في Word و Excel و PowerPointوالناشر والوصول و Visio والمشروع.
- فتح وإنشاء مستندات متعددة في علامات تبويب جديدة من نفس النافذة ، بدلاً من النوافذ الجديدة.
- يزيد من إنتاجيتك بنسبة 50٪ ، ويقلل مئات النقرات بالماوس كل يوم!
جدول المحتويات
- دالة IF مقابل عبارات IF المتداخلة
- استخدام IF المتداخلة
- بناء جملة IF المتداخلة
- أمثلة عملية على IF المتداخلة
- متداخل إذا كان مع شرط و/أو
- نصائح وحيل لـ IF المتداخلة
- جعل المتداخلة إذا سهلة القراءة
- ترتيب وظائف IF المتداخلة
- يجب التعامل مع الأرقام والنصوص بشكل مختلف
- حدود IF المتداخلة
- بدائل متداخلة IF
- باستخدام VLOOKUP
- باستخدام آي إف إس
- باستخدام الاختيار والمطابقة
- مقالات ذات صلة
- أفضل أدوات إنتاجية المكتب
- التعليقات