إتقان عبارات IF المتداخلة في Excel – دليل خطوة بخطوة
في Excel، تُعد دالة IF ضرورية لإجراء الاختبارات المنطقية الأساسية، لكن الشروط المعقدة غالبًا ما تتطلب استخدام عبارات IF متداخلة لمعالجة البيانات بكفاءة أعلى. في هذا الدليل الشامل، سنستعرض أساسيات دالة IF المتداخلة بالتفصيل — بدءًا من تركيب الصيغة ووصولًا إلى التطبيقات العملية، بما في ذلك دمجها مع شروط AND وOR. كما سنوضح لك كيفية تحسين قابلية قراءة صيغ IF المتداخلة، ونشاركك نصائح مفيدة لاستخدامها بفعالية، إضافةً إلى استعراض بدائل قوية مثل VLOOKUP وIFS وغيرها، لتبسيط العمليات المنطقية المعقدة وجعلها أكثر سلاسة وكفاءة.
- جعل IF المتداخل سهل القراءة
- ترتيب دوال IF المتداخلة
- يجب التعامل مع الأرقام والنصوص بشكل مختلف
- محدوديات IF المتداخل
دالة IF في Excel مقابل عبارات IF المتداخلة
تُحقِّق دالة IF وعبارات IF المتداخلة في Excel أهدافًا متشابهة، لكنها تختلف اختلافًا كبيرًا من حيث التعقيد وطريقة التطبيق.
- الصيغة هي:
=IF (logical_test, [value_if_true], [value_if_false]) - القيود: تتعامل مع شرط واحد فقط في كل مرة، مما يجعلها أقل ملاءمةً للسيناريوهات المعقدة التي تتطلب تقييم معايير متعددة.
- الصيغة هي:
=IF( condition1, value_if_true1, IF( condition2, value_if_true2, value_if_false2 )) - التعقيد: يمكنها التعامل مع شروط متعددة، لكنها قد تصبح معقدة ويصعب قراءتها عند تداخل الطبقات بشكل كبير.
استخدام IF المتداخل
يوضّح هذا القسم الاستخدام الأساسي لعبارات IF المتداخلة في Excel، بما في ذلك صيغتها وأمثلتها العملية، بالإضافة إلى طريقة استخدامها مع شروط AND أو OR.
صيغة IF المتداخل
يُعد فهم صيغة الدالة أساسًا لتطبيقها بشكل صحيح وفعّال في Excel. دعونا نبدأ بصيغة عبارات IF المتداخلة.
الصيغة:
=IF(condition1, result1, IF(condition2, result2, IF(condition3, result3, result4)))
المعايير:
- الشرط 1،الشرط 2،الشرط 3: هذه هي الشروط التي تريد اختبارها. يتم تقييم كل شرط بالترتيب، بدءًا منالشرط 1.
- النتيجة1: هذه هي القيمة التي تُعاد إذا كان الشرط1 صحيحًا (TRUE).
- النتيجة2: تُعاد هذه القيمة إذا كان الشرط1 غير صحيح (FALSE) والشرط2 صحيحًا (TRUE). من المهم ملاحظة أن النتيجة2 لا تُقيَّم إلا بعد أن يكون الشرط1 غير صحيح.
- النتيجة3: تُعاد هذه القيمة إذا كان كلا الشرطين (الشرط1 والشرط2) غير صحيحَين، وكان الشرط3 صحيحًا (TRUE). وبشكل أساسي، لتقييمالنتيجة3يجب أن يكون كلا الشرطين السابقين (الشرط 1 والشرط 2) غير صحيحين.
- النتيجة4تُعاد هذه النتيجة إذا كانت جميع الشروط (الشرط1 والشرط2 والشرط3) غير صحيحة.باختصار، يمكن تفسير هذا التعبير كما يلي:Test condition1, if TRUE, return result1, if FALSE,
test condition2, if TRUE, return result2, if FALSE,
test condition3, if TRUE, return result3, if FALSE,
return result4
تذكّر أنه في هيكل IF المتداخل، يُقيَّم كل شرط لاحق فقط إذا كانت جميع الشروط السابقة **خاطئة**. ويُعدّ هذا الفحص التسلسلي عنصرًا جوهريًّا لفهم كيفية عمل عبارات IF المتداخلة.
أمثلة عملية على IF المتداخل
الآن، دعونا نتعمّق في استخدام IF المتداخلة من خلال مثالين عمليين.
المثال 1: نظام التقدير
كما هو موضح في لقطة الشاشة أدناه، افترض أن لديك قائمة بدرجات الطلاب وترغب في تعيين تقديرات بناءً على هذه الدرجات. يمكنك استخدام IF المتداخلة لإتمام هذه المهمة.
حدد خلية فارغة (مثل C2)، وأدخل الصيغة التالية، ثم اضغط Enter للحصول على النتيجة. بعد ذلك، اسحب مقبض التعبئة لأسفل لملء باقي الخلايا بالنتائج المقابلة.
=IF(B2>=90,$F$2,IF(B2>=80,$F$3,IF(B2>=70,$F$4,IF(B2>=60,$F$5,$F$6))))- يمكنك تحديد مستوى الدرجة مباشرةً في الصيغة، لذا يمكن تعديل الصيغة إلى:
=IF(A2>=90, "A", IF(A2>=80, "B", IF(A2>=70, "C", IF(A2>=60, "D", "F")))) - تُستخدم هذه الصيغة لتعيين درجة (A أو B أو C أو D أو F) بناءً على درجة موجودة في الخلية A2، باستخدام عتبات التقدير القياسية. وهي حالة استخدام نموذجية لعبارات IF المتداخلة في أنظمة التقدير الأكاديمي.
- شرح الصيغة:
- A2>=90: هذا هو الشرط الأول الذي تتحقق منه الصيغة. إذا كانت الدرجة في الخلية A2 أكبر من أو تساوي 90، فإن الصيغة تُرجع «A».
- A2>=80: إذا لم يتحقق الشرط الأول (أي كانت الدرجة أقل من 90)، يتم التحقق مما إذا كانت A2 أكبر من أو تساوي 80. وإذا صحّ ذلك، تُرجع النتيجة «B».
- A2>=70: وبالمثل، إذا كانت الدرجة أقل من 80، يتم التحقق مما إذا كانت أكبر من أو تساوي 70. وإذا صحّ ذلك، تُرجع «C».
- A2>=60: إذا كانت الدرجة أقل من 70، تتحقّق الصيغة مما إذا كانت أكبر من أو تساوي 60. وإذا كان ذلك صحيحًا، تُرجع «D».
- "F«: وأخيرًا، إذا لم يُحقَّق أيٌّ من الشروط السابقة (أي أن الدرجة أقل من 60)، تُرجع الصيغة »F".
المثال 2: حساب عمولة المبيعات
تخيّل سيناريوًّا يحصل فيه مندوبو المبيعات على نسب عمولة متفاوتة وفقًا لإنجازاتهم البيعية. كما يظهر في لقطة الشاشة أدناه، يمكنك حساب عمولة مندوب المبيعات استنادًا إلى عتبات مبيعات مختلفة، حيث تُعد صيغ IF المتداخلة أداة مثالية لتحقيق ذلك.
- الفئة 1 ($20،000+): 20%
- الفئة 2 ($10،000–$19،999): 15%
- الفئة 3 (<$10،000): 10%
حدد خلية فارغة (مثل C2)، وأدخل الصيغة التالية، ثم اضغط Enter للحصول على النتيجة. بعد ذلك، اسحب مقبض التعبئة لأسفل لملء باقي الخلايا بالنتائج المقابلة.
=B2*IF(B2>20000,$F$2,IF(B2>=10000,$F$3,$F$4))
- يمكنك تحديد نسبة العمولة مباشرةً في الصيغة، لذا يمكن تعديل الصيغة إلى:
=B2*IF(B2>20000, 20%, IF(B2>=10000, 15%, 10%)) - تُستخدم الصيغة المقدمة لحساب عمولة مندوب المبيعات بناءً على مبلغ مبيعاته، مع تطبيق نسب عمولة مختلفة حسب عتبات المبيعات المختلفة.
- شرح الصيغة:
- B2: يُشير هذا إلى مبلغ مبيعات البائع، والذي يُستخدم كأساسٍ لحساب عمولته.
- IF(B2>20000, «20%», ...): هذا هو الشرط الأول الذي يتم التحقق منه، حيث يُقيَّم ما إذا كان مبلغ المبيعات في الخلية B2 يتجاوز 20،000. وإذا تحقَّق ذلك، تطبِّق الصيغة معدل عمولة بنسبة 20%.
- IF(B2>=10000, «15%», «10%»): إذا لم يتحقّق الشرط الأول (أي أن المبيعات لا تتجاوز 20،000)، تنتقل الصيغة للتحقق مما إذا كانت المبيعات تساوي أو تزيد عن 10،000. فإذا كان ذلك صحيحًا، تُطبَّق عمولة بنسبة 15%. أما إذا كانت المبيعات أقل من 10،000، فتُعتمَد تلقائيًا عمولة بنسبة 10%.
IF المتداخل مع شرطَي AND / OR
في هذا القسم، قمت بتعديل المثال الأول أعلاه «نظام التقدير» لتوضيح كيفية الجمع بين IF المتداخلة مع شرط AND أو OR في Excel. في مثال التقدير المعدّل، قدّمتُ شرط إضافي استنادًا إلى «معدل الحضور».
استخدام IF المتداخلة مع شرط AND
إذا حقّق الطالب معايير الدرجة ومعدل الحضور معًا، فسيحصل على رفع في تقديره. على سبيل المثال، سيحصل طالب درجته 60 أو أعلى ومعدل حضوره 95% أو أكثر على رفع في تقديره بمستوى واحد، مثل من A إلى A+، أو من B إلى B+، وهكذا. ومع ذلك، إذا كان معدل الحضور أقل من 95%، فسيتم تطبيق معايير التقدير الأصلية المعتمدة على الدرجة فقط. في مثل هذه الحالات، نحتاج إلى استخدام عبارة IF متداخلة مع شرط AND.
حدد خلية فارغة (D2 في هذه الحالة)، وأدخل الصيغة التالية ثم اضغط Enter للحصول على النتيجة. بعد ذلك، اسحب مقبض التعبئة لأسفل للحصول على باقي النتائج.
=IF(AND(B2>=60, C2>=95%),IF(B2>=90, "A+", IF(B2>=80, "B+", IF(B2>=70, "C+", "D+"))),IF(B2>=90, "A", IF(B2>=80, "B", IF(B2>=70, "C", IF(B2>=60, "D", "F")))))
- فحص شرط AND:
AND(B2>=60, C2>=95%): يتحقق شرط AND أولاً مما إذا كان الشرطان محققين معًا — أي أن تكون درجة الطالب 60 أو أعلى، ومعدل الحضور 95% أو أكثر. - New grade assignment:
IF(B2>=[[PH_131]], «A+», IF(B2>=[[PH_130]], «B+», IF(B2>=[[PH_129]], «C+», «D+»))): إذا كان كلا الشرطين في عبارة AND صحيحَين، فإن الصيغة بعد ذلك تتحقق من درجة الطالب وترفع درجته بمستوى واحد.- B2>=90: إذا كانت الدرجة 90 أو أعلى، فإن التقدير يكون "A +".تعيين التقدير الجديد:
- B2>=80: إذا كانت الدرجة 80 أو أعلى (ولكن أقل من 90)، يكون التقدير "B +".
- B2>=70: إذا كانت الدرجة 70 أو أعلى (ولكن أقل من 80)، يُمنح التقدير «C+».
- B2>=60: إذا كانت الدرجة 60 أو أعلى (ولكن أقل من 70)، فإن التقدير يكون «D+».
- Regular Grade Assignment:
IF(B2>=[[PH_146]], «A», IF(B2>=[[PH_145]], «B», IF(B2>=[[PH_144]], «C», IF(B2>=[[PH_143]], «D», «F»)))): إذا لم يتحقق شرط AND (إما أن تكون الدرجة أقل من 80 أو الحضور أقل من 95%)، فإن الصيغة تعيّن الدرجات القياسية.- B2>=90: إذا كانت درجتك 90 أو أعلى، فستحصل على تقدير «A».
- B2>=80: إذا كانت درجتك 80 أو أعلى (ولكن أقل من 90)، فستحصل على تقدير «B».
- B2>=70: إذا كانت درجتك 70 أو أعلى (ولكن أقل من 80)، فستحصل على تقدير «C».
- B2>=60: إذا كانت الدرجة 60 أو أعلى (ولكن أقل من 70)، فستحصل على تقدير «D».
- الدرجات الأقل من 60 تحصل على تقدير «F».
استخدام IF المتداخلة مع شرط OR
في هذه الحالة، سيتم رفع تقدير الطالب بمستوى واحد إذا كانت درجته 95 أو أعلى، أو إذا كان معدل حضوره 95% أو أكثر. إليك كيف يمكننا تنفيذ ذلك باستخدام IF المتداخلة وشرط OR.
حدد خلية فارغة (D2 في هذه الحالة)، وأدخل الصيغة التالية ثم اضغط Enter للحصول على النتيجة. بعد ذلك، اسحب مقبض التعبئة لأسفل للحصول على باقي النتائج.
=IF(OR(B2>=95, C2>=95%),IF(B2>=90, "A+", IF(B2>=80, "B+", IF(B2>=70, "C+", IF(B2>=60, "D+", "F+")))),IF(B2>=90, "A", IF(B2>=80, "B", IF(B2>=70, "C", IF(B2>=60, "D", "F")))))
- فحص شرط OR:
OR(B2>=95, C2>=95%): تتحقق الصيغة أولًا مما إذا كان أحد الشرطين صحيحًا — إما أن تكون درجة الطالب 95 أو أعلى، أو أن يكون معدل الحضور 95% أو أعلى. - Grade Assignment with Bonus:
IF(B2>=[[PH_168]], «A+», IF(B2>=[[PH_167]], «B+», IF(B2>=[[PH_166]], «C+», IF(B2>=[[PH_165]], «D+», «F+»)))): إذا كان أحد الشرطين في عبارة OR صحيحًا، فسيتم رفع درجة الطالب بمستوى واحد.- B2>=90: إذا كانت الدرجة 90 أو أعلى، يكون التقدير «A+».
- B2>=80: إذا كانت الدرجة 80 أو أعلى (ولكن أقل من 90)، يكون التقدير «B+».
- B2>=70: إذا كانت الدرجة 70 أو أعلى (ولكن أقل من 80)، يكون التقدير «C+».
- B2>=60: إذا كانت الدرجة 60 أو أعلى (ولكن أقل من 70)، يكون التقدير «D+».
- وإلا، فإن التقدير يكون «F+».
- Regular Grade Assignment:
IF(B2>=[[PH_182]], «B», IF(B2>=[[PH_181]], «C», IF(B2>=[[PH_180]], «D», «F»)))): إذا لم يتحقق أيٌّ من شروط OR (أي كانت الدرجة أقل من 95 والحضور أقل من 95%)، فإن الصيغة تعيّن الدرجات القياسية.- B2>=90: إذا كانت الدرجة 90 أو أعلى، تحصل على تقدير «A».
- B2>=80: إذا كانت درجتك 80 أو أعلى (ولكن أقل من 90)، فستحصل على تقدير «B».
- B2>=70: إذا كانت درجتك 70 أو أعلى (ولكن أقل من 80)، فستحصل على تقدير «C».
- B2>=60: إذا كانت درجتك 60 أو أعلى (ولكن أقل من 70)، فستحصل على تقدير «D».
- الدرجات الأقل من 60 تحصل على تقدير «F».
جعل IF المتداخل سهل القراءة
قد تبدو عبارة IF المتداخلة موجزة ونموذجيّة، لكن فهمها قد يشكّل تحديًا.
في الصيغة التالية، يصعب بسرعة تحديد أين ينتهي شرط ويبدأ آخر، خاصةً مع تزايد التعقيد.
=IF(A2>=90, "A", IF(A2>=80, "B", IF(A2>=70, "C", IF(A2>=60, "D", "F"))))الحل: إضافة فواصل أسطر ومسافات بادئة
لجعل دوال IF المتداخلة أكثر سهولة في القراءة، يمكنك تقسيم الصيغة إلى عدة أسطر، بحيث يبدأ كل IF متداخل بسطر جديد. للقيام بذلك، ضع المؤشر قبل دالة IF في الصيغة، ثم اضغط على مفاتيح Alt + Enter.
بعد تقسيم الصيغة أعلاه، ستظهر كما يلي:
=IF(A2>=90, "A",
IF(A2>=80, "B",
IF(A2>=70, "C",
IF(A2>=60, "D", "F")))
)يوضّح هذا التنسيق بوضوح مكان كل شرط والمخرجات المرتبطة به، مما يعزز قابلية قراءة الصيغة.
ترتيب دوال IF المتداخلة
يكتسي ترتيب الشروط المنطقية في صيغة IF المتداخلة أهمية بالغة، إذ يحدد الطريقة التي يقيّم بها Excel هذه الشروط، ويؤثر بذلك مباشرةً على النتيجة النهائية للصيغة.
الصيغة الصحيحة
في مثال نظام التقدير، نستخدم الصيغة التالية لتحديد التقديرات وفقًا للدرجات.
=IF(B2>=90, "A", IF(B2>=80, "B", IF(B2>=70, "C", IF(B2>=60, "D", "F"))))
يقيّم Excel الشروط في صيغة IF المتداخلة بالتسلسل، بدءًا من أول شرط وصولًا إلى آخرها. فتبدأ الصيغة بالتحقق من أعلى عتبة درجات (>=90 للحصول على «A»)، ثم تنتقل تدريجيًّا إلى العتبات الأدنى، مما يضمن مقارنة الدرجة بأعلى تقدير مؤهل لها. فإذا كان الشرط الأول صحيحًا (A2>=90)، تُرجع الصيغة «A» ولا تُقيّم أي شروط إضافية.
الصيغة ذات الترتيب الخاطئ
لو عُكِس ترتيب الشروط وبدأنا بأدنى عتبة، لكان الناتج خاطئًا.
=IF(B2>=60, "D", IF(B2>=70, "C", IF(B2>=80, "B", IF(B2>=90, "A", "F"))))
في هذه الصيغة الخاطئة، ستلبّي الدرجة 95 فورًا الشرط الأول B2>=60، وستُعيَّن لها تقدير «D» بشكل خاطئ.
يجب التعامل مع الأرقام والنصوص بشكل مختلف
سيوضح هذا القسم كيفية معالجة الأرقام والنصوص بشكل مختلف في عبارات IF المتداخلة.
الأرقام
تُستخدم الأرقام في المقارنات الحسابية والعمليات الحسابية. وفي عبارات IF المتداخلة، يمكنك مقارنة الأرقام مباشرةً باستخدام عوامل مثل > و= و<=.
النصوص
في عبارات IF المتداخلة، يجب وضع النصوص بين علامتي اقتباس مزدوجتين. راجع القيم A وB وC وD وF في الصيغة التالية:
=IF(A2>=90, "A", IF(A2>=80, "B", IF(A2>=70, "C", IF(A2>=60, "D", "F"))))محدوديات IF المتداخل
يسرد هذا القسم عدة قيود وسلبيات لاستخدام IF المتداخلة.
التعقيد وقابلية القراءة:
على الرغم من أن Excel يتيح لك تداخل ما يصل إلى 64 دالة IF، فإن ذلك ليس موصىً به إطلاقًا؛ إذ كلما زادت مستويات التداخل، أصبحت الصيغة أكثر تعقيدًا، ما يجعلها صعبة القراءة والفهم والصيانة.
عرضة للأخطاء:
علاوةً على ذلك، قد تصبح عبارات IF المتداخلة والمعقدة عرضةً للأخطاء، ويصعب تصحيحها أو تعديلها.
صعوبة التوسعة أو التحجيم:
إذا تغيّر منطقك أو احتجتَ إلى إضافة شروط جديدة، فقد يصبح تعديل عبارات IF المتداخلة العميقة أو توسيعها أمرًا صعبًا.
إن فهم هذه القيود أمرٌ جوهري لاستخدام عبارات IF المتداخلة بفعالية في Excel. وغالبًا ما يؤدي دمج عبارات IF المتداخلة مع دوال أخرى أو البحث عن بدائل إليها إلى حلول أكثر كفاءة وسهولة في الصيانة.
بدائل IF المتداخل
يعرض هذا القسم مجموعة من دوال Excel التي يمكن استخدامها كبديلٍ فعّال لعبارات IF المتداخلة.
استخدام VLOOKUP
يمكنك استخدام دالة VLOOKUP بدلًا من عبارات IF المتداخلة لتنفيذ المثالين العمليين أعلاه. إليك كيف يمكنك فعل ذلك:
المثال 1: نظام التقدير باستخدام VLOOKUP
سأعرض هنا كيفية استخدام VLOOKUP لتعيين التقديرات بناءً على الدرجات.
الخطوة 1: إنشاء جدول بحث للتقييمات
أولاً، عليك إنشاء جدول بحث (مثل النطاق E1:F6 في هذه الحالة) يحتوي على درجات التقييمات المقابلة.ملاحظة:يجب أن تكون الدرجات في العمود الأول من الجدول مرتبة بترتيب تصاعدي.
الخطوة 2: تطبيق دالة VLOOKUP لتعيين التقديرات
حدّد خلية فارغة (مثل C2)، وأدخل الصيغة التالية، ثم اضغط مفتاح Enter للحصول على أول تقدير. بعد ذلك، حدد خلية الصيغة واسحب مقبض التعبئة لأسفل لملء باقي التقديرات تلقائيًا.
=VLOOKUP(B2,$E$2:$F$6,2,TRUE)
- القيمة 95 في الخلية B2 هي ما تبحث عنه دالة VLOOKUP في العمود الأول من جدول البحث ($E$2:$F$6). وإذا وُجدت، تُعيد الدرجة المقابلة من العمود الثاني في الجدول، الموجود في نفس الصف الذي تطابقت فيه القيمة.
- تذكّر جعل مرجع جدول البحث مطلقًا (بإضافة علامات الدولار $ قبل المراجع)، ليظل ثابتًا دون تغيير عند نسخ الصيغة إلى خلية أخرى.
- لمعرفة المزيد عن دالة VLOOKUP،زر هذه الصفحة.
المثال 2: حساب عمولة المبيعات باستخدام VLOOKUP
يمكنك أيضًا استخدام VLOOKUP لحساب عمولة المبيعات في Excel. يُرجى اتباع الخطوات التالية.
الخطوة 1: إنشاء جدول بحث للدرجات
أولاً، عليك إنشاء جدول بحث يحتوي على المبيعات ونسبة العمولة المقابلة لها، مثل النطاق E2:F4 في هذا المثال.ملاحظة: يجب أن تكون المبيعات في العمود الأول من الجدول مرتبة بترتيب تصاعدي.
الخطوة 2: تطبيق دالة VLOOKUP لتعيين الدرجات
حدد خلية فارغة (C2 في هذه الحالة)، وأدخل الصيغة التالية ثم اضغط مفتاح الإدخال (Enter) للحصول على العمولة الأولى. حدد خلية هذه الصيغة واسحب مقبض التعبئة (Fill Handle) لأسفل للحصول على باقي النتائج.
=B2*VLOOKUP(B2,$E$2:$F$4,2,TRUE)
- في كلا المثالين، تُستخدم دالة VLOOKUP للعثور على قيمة في جدول بناءً على قيمة بحث (مثل درجة أو مبلغ مبيعات)، ثم تُعيد قيمة من نفس الصف في عمود معيّن (كالدرجة أو نسبة العمولة). ويشير المعامل الرابع TRUE إلى استخدام مطابقة تقريبية، وهو الخيار الأمثل في هذه السيناريوهات التي قد لا تتضمّن القيمة المطلوبة بدقة في الجدول.
- لمعرفة المزيد عن دالة VLOOKUP،زر هذه الصفحة.
استخدام IFS
تبسّط دالة IFS العملية من خلال إلغاء الحاجة إلى التداخل وتجعل الصيغ أسهل في القراءة والإدارة. فهي تعزز الوضوح وتُبسّط التعامل مع عمليات التحقق الشرطية المتعددة. وللاستفادة من دالة IFS، تأكد من أنك تستخدم Excel 2019 أو إصدارًا أحدث، أو أن لديك اشتراك Office 365. دعونا نرى كيف يمكن تطبيقها في أمثلة عملية.
المثال 1: نظام التقدير باستخدام IFS
بافتراض نفس معايير التقدير السابقة، يمكن استخدام دالة IFS كما يلي:
حدد خلية فارغة، مثل C2، وأدخل الصيغة التالية ثم اضغط مفتاح الإدخال (Enter) للحصول على النتيجة الأولى. حدد خلية هذه النتيجة واسحب مقبض التعبئة (Fill Handle) لأسفل للحصول على باقي النتائج.
=IFS(B2>=90,"A",B2>=80,"B",B2>=70,"C",B2>=60,"D",B2<60,"F")
- يتم تقييم الشروط واحدًا تلو الآخر بالترتيب. وفور تحقُّق أحد الشروط، تُعاد النتيجة المرتبطة به على الفور، ولا تُتابع الصيغة التحقق من الشروط اللاحقة. وفي هذا السياق، تُستخدم الصيغة لتحديد التقدير بناءً على الدرجة المدوَّنة في الخلية B2، وفق مقياس تقدير نموذجي تتوافق فيه الدرجات الأعلى مع تقديرات أفضل.
- لمعرفة المزيد عن دالة IFS،زر هذه الصفحة.
المثال 2: حساب عمولة المبيعات باستخدام IFS
في سيناريو حساب عمولة المبيعات، يتم تطبيق دالة IFS كما يلي:
حدد خلية فارغة، مثل C2، وأدخل الصيغة التالية، ثم اضغط مفتاح الإدخال (Enter) للحصول على النتيجة الأولى. بعد ذلك، حدد خلية النتيجة واسحب مقبض التعبئة (Fill Handle) لأسفل لملء باقي الخلايا بالنتائج المطلوبة.
=B2*IFS(B2>20000,20%,B2>=10000,15%,TRUE,10%)
استخدام CHOOSE وMATCH
يمكن أن يكون نهج الدالتين CHOOSE وMATCH أكثر كفاءة وأسهل في الإدارة مقارنةً بعبارات IF المتداخلة. فهذه الطريقة تبسّط الصيغة وتجعل التحديثات أو التعديلات أكثر سهولة. سأوضح أدناه كيفية استخدام مزيج من دالتي CHOOSE وMATCH للتعامل مع المثالين العمليين الواردين في هذه المقالة.
المثال 1: نظام التقدير باستخدام CHOOSE وMATCH
يمكنك استخدام مزيج من دالتي CHOOSE وMATCH لتعيين الدرجات بناءً على درجات مختلفة.
الخطوة 1: إنشاء مصفوفة بحث باستخدام قيمة البحث
أولاً، عليك إنشاء نطاق من الخلايا يحتوي على قيم العتبات التي ستبحث عنها دالة MATCH، مثل $E$2:$E$6 في هذه الحالة.ملاحظة:يجب أن تكون الأرقام في هذا النطاق مرتبة تصاعديًا لتعمل دالة MATCH بشكل صحيح عند استخدام نوع المطابقة التقريبية.
الخطوة 2: تطبيق CHOOSE وMATCH لتعيين الدرجات
حدد خلية فارغة (مثل C2)، وأدخل الصيغة التالية، ثم اضغط مفتاح الإدخال (Enter) للحصول على الدرجة الأولى. بعد ذلك، حدد الخلية التي تحتوي على الصيغة واسحب مقبض التعبئة (Fill Handle) لأسفل لملء باقي النتائج تلقائيًا.
=CHOOSE(MATCH(B2, $E$2:$E$6, 1), "F", "D", "C", "B", "A")
- MATCH(B2, $E$2:$E$6, 1): يبحث هذا الجزء من الصيغة عن الدرجة (95) في الخلية B2 ضمن النطاق $E$2:$E$6. وتشير 1 إلى أن دالة MATCH يجب أن تبحث عن مطابقة تقريبية، ما يعني أنها تبحث عن أكبر قيمة في النطاق تكون أقل من أو يساوي B2.
- CHOOSE(..., «F», «D», «C», «B», «A»): استنادًا إلى الموقع الذي تُعيده دالة MATCH، تقوم دالة CHOOSE باختيار درجة مكافئة.
- لمعرفة المزيد عن دالة MATCH،زر هذه الصفحة.
- لمعرفة المزيد عن دالة CHOOSE،انقر هنا.
المثال 2: حساب عمولة المبيعات باستخدام IFS
يمكن أن يكون استخدام مزيج الدالتين CHOOSE وMATCH في حساب عمولة المبيعات فعّالًا أيضًا، خاصةً عندما تعتمد نسب العمولة على عتبات مبيعات محددة. دعونا نرى كيف يمكننا ذلك.
الخطوة 1: إنشاء مصفوفة بحث باستخدام قيمة البحث
أولاً، عليك إنشاء نطاق من الخلايا يحتوي على قيم العتبات التي ستبحث عنها دالة MATCH، مثل $E$2:$E$4 في هذه الحالة.ملاحظة:يجب أن تكون الأرقام في هذا النطاق مرتبة تصاعديًا لتعمل دالة MATCH بشكل صحيح عند استخدام نوع المطابقة التقريبية.
الخطوة 2: تطبيق CHOOSE وMATCH للحصول على النتائج
حدد خلية فارغة (C2 في هذه الحالة)، وأدخل الصيغة التالية ثم اضغط مفتاح الإدخال (Enter) للحصول على الدرجة الأولى. حدد خلية هذه الصيغة واسحب مقبض التعبئة (Fill Handle) لأسفل للحصول على باقي النتائج.
=B2*CHOOSE(MATCH(B2, $E$2:$E$4, 1), 10%, 15%, 20%)
في الختام، يُعد إتقان عباراتIF المتداخلة في Excel مهارة قيّمة تعزز قدرتك على التعامل مع السيناريوهات المنطقية المعقدة في تحليل البيانات واتخاذ القرارات. وعلى الرغم من قوة عباراتIF المتداخلة في معالجة المنطق المعقد، فمن المهم أن تكون واعيًا بحدودها. وقد توفر بدائل أبسط—مثلVLOOKUP وIFS وCHOOSE معMATCH—حلولًا أكثر سلاسة في بعض السيناريوهات. وبفضل هذه الرؤى، يمكنك الآن تطبيق تقنيات Excel الأنسب لمهامك التحليلية بثقة، مما يضمن الوضوح والدقة والكفاءة في جداولك الإلكترونية. ولمن يرغب في استكشاف المزيد من إمكانيات Excel، يحتوي موقعنا على كنزٍ من الدروس التعليمية.اكتشف المزيد من نصائح وحيل Excel هنا.
أفضل أدوات إنتاجية Office
عزِّز مهاراتك في Excel باستخدام Kutools لـ Excel، وعايش الكفاءة كما لم تفعل من قبل.يقدّم Kutools لـ Excel أكثر من 300 ميزة متقدمة لتعزيز الإنتاجية ووقت الحفظ.انقر هنا للحصول على الميزة التي تحتاجها أكثر من غيرها...
Office Tab يجلب واجهة ذات علامات تبويب إلى Office، ويجعل عملك أسهل بكثير
- تمكّن من التحرير والقراءة بعلامات تبويب في Word وExcel وPowerPointوPublisher وAccess وVisio وProject.
- افتح وأنشئ مستندات متعددة في علامات تبويب جديدة ضمن نفس النافذة، بدلاً من النوافذ الجديدة.
- يزيد إنتاجيتك بنسبة 50%، ويقلل مئات نقرات الفأرة عنك كل يوم!
جميع إضافات Kutools مُثبَّتة في حزمة واحدة.
Kutools for Office تحتوي حزمة التطبيقات على إضافات لـ Excel وWord وOutlook وPowerPoint، بالإضافة إلى Office Tab Pro، مما يجعلها الخيار المثالي للفرق التي تعمل عبر تطبيقات Office.
- حزمة شاملة واحدة— إضافات Excel وWord وOutlook وPowerPoint + Office Tab Pro
- مثبّت واحد، ترخيص واحد— الإعداد خلال دقائق (جاهز لـ MSI)
- تعمل بشكل أفضل معًا— إنتاجية ميسّرة عبر تطبيقات Office
- تجربة مجانية لمدة 30 يومًا بكامل الميزات— بدون تسجيل، ولا بطاقة ائتمان
- أفضل قيمة— وفّر مقارنةً بشراء الإضافات بشكل منفصل
جدول المحتويات
- دالة IF مقابل عبارات IF المتداخلة
- استخدام IF المتداخل
- صيغة IF المتداخل
- أمثلة عملية على IF المتداخل
- IF المتداخل مع شرطَي AND / OR
- نصائح وحيل لـ IF المتداخل
- جعل IF المتداخل سهل القراءة
- ترتيب دوال IF المتداخلة
- يجب التعامل مع الأرقام والنصوص بشكل مختلف
- محدوديات IF المتداخل
- بدائل IF المتداخل
- استخدام VLOOKUP
- استخدام IFS
- استخدام CHOOSE وMATCH
- مقالات ذات صلة
- أفضل أدوات إنتاجية Office
- التعليقات