إنشاء مجلدات ومجلدات فرعية متعددة من قائمة بيانات في Excel

لنفترض أن لديك قائمة بأسماء الموظفين ضمن نطاق خلايا في ورقة عمل، وتريد إنشاء مجلدات فردية لكلٍّ منهم لتخزين بياناتهم. قد يستغرق إنشاء كل مجلد يدويًّا وقتًا طويلاً، لكن لحسن الحظ، توجد طرق فعّالة للإسراع بهذه العملية. في هذا الدليل، سأعرض لكم عدة طرق سريعة لإنشاء مجلدات استنادًا إلى قيم الخلايا المحددة.

إنشاء مجلدات استنادًا إلى قيم الخلايا

• باستخدام أمر MD ومحرر Notepad
• باستخدام ميزة قوية – Kutools لـ Excel
• باستخدام رمز VBA

إنشاء مجلدات ومجلدات فرعية بناءً على قيم الخلايا باستخدام كود VBA

إنشاء مجلدات استنادًا إلى قيم الخلايا

في هذا القسم، سنستعرض طرقًا مختلفة بالتفصيل، مع تقديم إرشادات خطوة بخطوة شاملة لإنشاء مجلدات بناءً على قائمة بقيم الخلايا بسرعة وسهولة.

إنشاء مجلدات من قائمة باستخدام أمر MD وتطبيق المفكرة

تحويل قائمة من Excel إلى مجلدات باستخدام أمر MD وتطبيق المفكرة هو خدعة ذكية تجمع بين كتابة نصوص الدُفعات البسيطة وقدرة Excel على التنظيم. وتُعد هذه الطريقة مثالية لإنشاء عدد كبير من المجلدات بسرعة، دون الحاجة إلى إنشائها يدويًّا. فيما يلي دليلٌ خطوة بخطوة لإنجاز هذه المهمة:

الخطوة 1: استخدم أمر MD لـ إنشاء صيغة

انسخ الصيغة التالية أو أدخلها في خلية فارغة بجانب أول قيمة لديك (مثل B1)، ثم اسحب مقبض التعبئة لأسفل لتطبيقها على جميع عناصر القائمة.

="MD "&A1

الخطوة 2: انسخ الصيغ والصقها في ملف المفكرة

1. اضغط «Ctrl + C» لنسخ الخلايا التي تحتوي على صيغة أمر MD.
2. افتح Notepad ثم اضغط «Ctrl + V» للصق الأوامر في الملف المُنشأ.
   

الخطوة 3: احفظ ملف المفكرة كملف بامتداد .bat

من تبويب «ملف» في المفكرة، انقر على «حفظ باسم». في مربع الحوار «حفظ باسم»، اختر الدليل الذي ترغب في إنشاء المجلدات المتعددة بداخله، ثم أعطِ الملف اسمًا مع إضافة الامتداد .bat. وأخيرًا، انقر على زر «حفظ». راجع لقطة الشاشة:

الخطوة 4: انقر مرتين على ملف .bat لإنشاء مجلدات متعددة

1. أغلق ملف المفكرة، ثم انتقل إلى المجلد الذي حفظت فيه ملف .bat مسبقًا.
2. الآن، شاهد السحر بأم عينيك: انقر مرتين على الملف، وستشاهد إنشاء عدة مجلدات دفعة واحدة! تحقق من العرض التوضيحي أدناه:
   

إنشاء مجلدات من قائمة باستخدام أداة قوية – Kutools لـ Excel

بفضل ميزة «إنشاء مجلد استنادًا إلى النطاق» القوية من Kutools لـ Excel، يمكنك الآن إنشاء مجلدات من قائمة Excel بسهولة وسرعة. ولا يقتصر الأمر على المجلدات الأساسية فحسب، بل يمكّنك Kutools أيضًا من إنشاء هياكل معقدة تحتوي على مجلدات فرعية متعددة المستويات دفعة واحدة. فبضع خطوات بسيطة تكفي لتحويل بيانات Excel إلى نظام مجلدات منظم يعزز إنتاجيتك بشكل كبير.

بعد تثبيت Kutools لـ Excel، يرجى النقر على «KUTOOLS PLUS» > «استيراد/تصدير» > «إنشاء مجلد استنادًا إلى النطاق» لفتح مربع حوار إنشاء مجلد استنادًا إلى النطاق:

1. حدد قيم الخلايا التي تريد إنشاء مجلدات بناءً عليها؛
2. بعد ذلك، انقر على زرلتحديد مجلد الوجهة الذي تريد حفظ المجلدات فيه؛
3. وأخيرًا، انقر على زر «موافق».
   

النتيجة:

سيقوم Kutools بمعالجة القائمة من ورقتك وإنشاء مجلد منفصل لكل إدخال في الوجهة التي حددتها. انتقل إلى مجلد الوجهة للاطلاع على النتيجة. راجع لقطة الشاشة:

إنشاء مجلدات من قائمة باستخدام كود VBA

يمكنك استخدام كود VBA في Excel لتحويل مهمة إنشاء المجلدات من قائمة — والتي قد تكون مملة ومستهلكة للوقت — إلى عملية آلية سريعة وفعّالة. سيوضح لك هذا القسم كيفية تطبيق كود VBA لإنشاء المجلدات بسهولة.

الخطوة 1: افتح محرر وحدة VBA وانسخ الكود

1. اضغط مع الاستمرار على مفتاحَي «ALT + F11» في Excel، وستفتح لك نافذة «مايكروسوفت فيجوال بيسك للتطبيقات».
2. انقر على «إدراج» > «وحدة»، والصق الكود التالي في نافذة الوحدة.
   كود VBA: إنشاء مجلدات بناءً على قائمة بقيم الخلايا

   Sub CreateFoldersFromSelection()
   'Updateby Extendoffice
       Dim FolderPath As String
       Dim Cell As Range
       Dim SelectedRange As Range
       Dim FolderName As String
       On Error Resume Next
       Set SelectedRange = Application.InputBox("Select the range with folder names", "Kutools for Excel", Type:=8)
       If SelectedRange Is Nothing Then Exit Sub
       On Error GoTo 0
       
       With Application.FileDialog(msoFileDialogFolderPicker)
           .Title = "Select the destination Folder"
           .AllowMultiSelect = False
           If .Show <> -1 Then Exit Sub
           FolderPath = .SelectedItems(1) & "\"
       End With
       
       For Each Cell In SelectedRange
           FolderName = FolderPath & Cell.Value
           If Cell.Value <> "" And Not FolderExists(FolderName) Then
               MkDir FolderName
           End If
       Next Cell
   End Sub
   
   Function FolderExists(ByVal Path As String) As Boolean
       On Error Resume Next
       FolderExists = (GetAttr(Path) And vbDirectory) = vbDirectory
       On Error GoTo 0
   End Function
   

الخطوة 2: نفّذ الكود

1. بعد لصق هذا الكود، اضغط على مفتاح F5 لتشغيله. في مربع المطالبة، حدد الخلايا التي تحتوي على القيم التي ترغب في إنشاء المجلدات بناءً عليها، ثم انقر على «موافق».
   
2. بعد ذلك، في نافذة «تحديد مجلد الوجهة» التالية، حدد مسار الوجهة الذي ترغب في إخراج المجلدات المُنشأة إليه، ثم انقر على زر «موافق». راجع لقطة الشاشة:
   

النتيجة:

بعد تنفيذ كود VBA، انتقل إلى دليل الوجهة لعرض النتيجة. ستجد هناك المجلدات الجديدة التي تم إنشاؤها، وكلٌّ منها يتوافق مع عنصر من قائمة Excel الخاصة بك. راجع لقطة الشاشة:

إنشاء مجلدات ومجلدات فرعية بناءً على قيم الخلايا باستخدام كود VBA

قد تجد نفسك أحيانًا في موقف يتطلب إنشاء مجلداتٍ ومجلداتها الفرعية المقابلة، كل ذلك استنادًا إلى البيانات الموجودة في خلايا Excel. ولإنجاز هذه المهمة بكفاءة، إليك كود VBA المناسب لهذا الغرض.

الخطوة 1: إعداد البيانات

أولاً، أدخل البيانات كما هو موضح في لقطة الشاشة التالية: ضع اسم المجلد الرئيسي في العمود الأول وأسماء المجلدات الفرعية في العمود الثاني.

الخطوة 2: افتح محرر وحدة VBA وانسخ الكود

1. اضغط مع الاستمرار على مفتاحَي «ALT + F11» في Excel، وستفتح لك نافذة «مايكروسوفت فيجوال بيسك للتطبيقات».
2. انقر على «إدراج» > «وحدة»، والصق الكود التالي في نافذة الوحدة.
   كود VBA: إنشاء مجلدات ومجلدات فرعية بناءً على قيم الخلايا

   Sub CreateFoldersAndSubfoldersWithUserInput()
   'Updateby Extendoffice
       Dim Rng As Range
       Dim Cell As Range
       Dim basePath As String
       Dim fldrPicker As FileDialog
       Dim FolderPath As String, subfolderPath As String
       On Error Resume Next
       Set Rng = Application.InputBox("Select the range of cells (two columns: one is folder column, another s subfolder column):", "Kutools for Excel", Type:=8)
       If Rng Is Nothing Then Exit Sub
       On Error GoTo 0
       Set fldrPicker = Application.FileDialog(msoFileDialogFolderPicker)
       With fldrPicker
           .Title = "Select the Base Folder Path"
           .AllowMultiSelect = False
           If .Show <> -1 Then Exit Sub
           basePath = .SelectedItems(1)
       End With
       If Right(basePath, 1) <> "\" Then basePath = basePath & "\"
       For Each Cell In Rng.Columns(1).Cells
           If Not Cell.Value = "" Then
               FolderPath = basePath & Cell.Value
               If Not FolderExists(FolderPath) Then MkDir FolderPath
               If Not Cell.Offset(0, 1).Value = "" Then
                   subfolderPath = FolderPath & "\" & Cell.Offset(0, 1).Value
                   If Not FolderExists(subfolderPath) Then MkDir subfolderPath
               End If
           End If
       Next Cell
   End Sub
   
   Function FolderExists(FolderPath As String) As Boolean
       On Error Resume Next
       FolderExists = (GetAttr(FolderPath) And vbDirectory) = vbDirectory
       On Error GoTo 0
   End Function
   

الخطوة 3: نفّذ الكود

1. بعد لصق هذا الكود، اضغط على مفتاح F5 لتشغيله. في مربع المطالبة، حدد الخلايا التي تحتوي على القيم التي ترغب في إنشاء المجلدات بناءً عليها، ثم انقر على «موافق».
   
2. في النافذة المنبثقة التالية، حدد مسار الوجهة الذي تريد حفظ المجلدات المُنشأة فيه، ثم انقر على زر «موافق». راجع لقطة الشاشة:
   

النتيجة:

بعد تنفيذ كود VBA، انتقل إلى دليل الوجهة لعرض النتيجة، وستجد أن المجلدات والمجلدات الفرعية الخاصة بها—وفقًا لقيم الخلايا—قد أُنشئت بنجاح، كما يظهر في لقطة الشاشة التالية:

مقالات ذات صلة: