كيف يمكن إيقاف أو تعطيل تحذير «عدم وجود موضوع» في Outlook؟

عند استخدامك لبرنامجَي Outlook 2010 و2013، سيظهر لك مربع تحذير في كل مرة تُرسل فيها رسالة بريد إلكتروني دون موضوع، ليذكّرك بإضافة عنوانٍ لها. لكن إذا كنت لا ترغب فعليًّا في ملء حقل الموضوع، فقد يصبح هذا التحذير مصدر إزعاجٍ كبيرٍ لك. ولمساعدتك على التخلص منه، نقدّم لك خدعة بسيطة في البرنامج التعليمي التالي.

إيقاف أو تعطيل تحذير عدم وجود موضوع في Outlook

---

إيقاف أو تعطيل تحذير عدم وجود موضوع في Outlook

في Outlook 2007، لا يظهر أي تحذير عند إرسال رسالة بريد إلكتروني دون موضوع. وقد تم تفعيل هذه الميزة في إصداري Outlook 2010 و2013. ومع ذلك، لا توجد خاصية مدمجة تسمح لك بإيقاف هذا التحذير أو تعطيله مباشرةً. في هذا البرنامج التعليمي، سنعرض لك كود VBA الذي يمكنك استخدامه لتحقيق ذلك.

1. اضغط على مفتاحَي «Alt» + "F11" لفتح مربع حوار «Microsoft Visual Basic for Applications».

2. قم بتوسيع "Project1" > «كائنات Microsoft Outlook» بالنقر المزدوج عليهما، ثم انقر مرتين على «ThisOutlookSession» لفتح نافذة «VbaProject.OTM».

3. انسخ والصق كود VBA أدناه في النافذة.

VBA: إيقاف أو تعطيل تحذير عدم وجود موضوع

Option Explicit
Private WithEvents oInspectors As Outlook.Inspectors

Private Sub Application_Startup()
    Set oInspectors = Outlook.Inspectors
End Sub

Private Sub oInspectors_NewInspector(ByVal Inspector As Inspector)
    Dim oItem As Object
    On Error GoTo ExitProc
    Set oItem = Inspector.CurrentItem
    If oItem.Sent = False Then
        If oItem.Subject = "" Then oItem.Subject = " "
    End If
ExitProc:
    Set oItem = Nothing
    Set Inspector = Nothing
End Sub

Private Sub Application_ItemSend(ByVal Item As Object, Cancel As Boolean)
    On Error Resume Next
    Item.Subject = Trim(Item.Subject)
End Sub

Private Sub Application_Quit()
    Set oInspectors = Nothing
End Sub

4. انقر على زر «حفظ» لحفظ كود VBA.

5. أعد تشغيل تطبيق Outlook.

بعد ذلك، سيصبح كود VBA ساري المفعول، ولن يظهر مربع التحذير الخاص بعدم وجود موضوع عند إرسال رسالة دون موضوع بعد الآن.

ملاحظة: تأكد من تأشير خيار «تمكين جميع ماكرو». (يمكنك التحقق من ذلك بالنقر على «ملف» > «خيارات» > «مركز الثقة» > «إعدادات مركز الثقة»، ثم في مربع حوار «مركز الثقة»، اختر «إعدادات الماكرو» > «تمكين جميع ماكرو»)، انظر لقطة الشاشة: