كيف يمكنني الحصول على قائمة المجلدات في Outlook؟

أحيانًا، يُسهّل هيكل الشجرة الذي يعرض جميع مجلدات البريد — بما في ذلك المجلدات الشخصية التي أنشأتها — تنقل مستخدمي Outlook أثناء عملهم. وللحصول بسرعة على قائمة كاملة بهيكل المجلدات، يُمكن أن يساعدك كود VBA. في هذا البرنامج التعليمي، ستتعلم كيفية استخراج قائمة المجلدات بسهولة باستخدام كود VBA.

الحصول على قائمة المجلدات في Outlook باستخدام كود VBA

---

الحصول على قائمة المجلدات في Outlook باستخدام كود VBA

للحصول على قائمة المجلدات في Outlook باستخدام كود VBA، اتبع الخطوات التالية:

1. اضغط مفاتيح «Alt» + "F11" على لوحة المفاتيح لفتح نافذة «Microsoft Visual Basic for Applications».

2. بعد ذلك، انقر مرتين على "Project1" > «كائن Microsoft Outlook» > «ThisOutlookSession» لفتح نافذة «Project1 – ThisOutlookSession». راجع لقطة الشاشة:

3. بعد ذلك، انسخ والصق كود VBA أدناه في نافذة Project1 – ThisOutlookSession.

VBA: الحصول على قائمة المجلدات في Outlook

Option Explicit
Sub GetFoldersList()
    On Error GoTo On_Error
    
    Dim Report As String
    Dim Folder As Outlook.Folder
       
    For Each Folder In Application.Session.Folders
        Report = Report & "---------------------------------------------------------------------------" & vbCrLf
        Call RecurseFolders(Folder, "", Report)
    Next
    Call CreateReportEmail("Outlook Folders List", Report)
    
Exiting:
    Exit Sub
On_Error:
    MsgBox "error=" & Err.Number & " " & Err.Description
End Sub
Sub RecurseFolders(CurrentFolder As Outlook.Folder, TabChars, ByRef Report As String)
    Dim SubFolder As Outlook.Folder
    Dim FolderName, StoreName As String
    
    FolderName = CurrentFolder.Name
    StoreName = CurrentFolder.Store.DisplayName
    
    Report = Report & TabChars & FolderName & " (Store: " & StoreName & ")" & vbCrLf
    
    For Each SubFolder In CurrentFolder.Folders
        Call RecurseFolders(SubFolder, TabChars & vbTab, Report)
    Next SubFolder
End Sub
Sub CreateReportEmail(Title As String, Report As String)
    Dim aMail As MailItem
    
    Set aMail = Application.CreateItem(olMailItem)
        
    aMail.Subject = Title
    aMail.Body = Report
    
    aMail.Display
End Sub

4. اضغط مفتاح "F5" على لوحة المفاتيح لتشغيل كود VBA فورًا.

5. تظهر الآن نافذة منبثقة باسم «Macro»، يُرجى النقر على زر «Run».

6. انتظر حتى يتم تشغيل الـ Macro. بعد ذلك، ستظهر لك قائمة بجميع مجلدات بريدك الإلكتروني فورًا في نافذة رسالة جديدة تم إنشاؤها، ويمكنك طباعتها بسهولة. راجع لقطة الشاشة:

ملاحظة: يمكن تطبيق كود VBA هذا على إصدارات Outlook 2007 و2010 و2013.