كيفية تصدير وطباعة قائمة جميع المجلدات والمجلدات الفرعية في Outlook؟

Author: Kelly Last Modified: 2025-08-06

بشكل عام، يمكنك الضغط على مفتاحي "Ctrl" + "6" لعرض قائمة جميع المجلدات في لوحة التنقل في Outlook. ومع ذلك، لا يمكنك طباعة قائمة المجلدات مباشرة. يقدم هذا المقال سكربتين VBA لتصدير وطباعة قائمة جميع المجلدات والمجلدات الفرعية في Outlook.

تصدير وطباعة قائمة جميع مجلدات Outlook والمجلدات الفرعية في بريد إلكتروني جديد
تصدير وطباعة قائمة جميع مجلدات Outlook والمجلدات الفرعية في Notepad

تصدير وطباعة قائمة جميع مجلدات Outlook والمجلدات الفرعية في بريد إلكتروني جديد

تُقدم هذه الطريقة سكربت VBA لتصدير قائمة جميع المجلدات والمجلدات الفرعية في حساب البريد الإلكتروني المحدد إلى بريد إلكتروني جديد في Outlook. بعد ذلك، يمكنك بسهولة طباعة قائمة المجلدات.

1. اضغط على "Alt" + "F11" لفتح نافذة Microsoft Visual Basic for Applications.

2. انقر على "إدراج" > "وحدة"، والصق الكود التالي لـ VBA في نافذة الوحدة الجديدة.

VBA: تصدير قائمة المجلدات والمجلدات الفرعية في بريد إلكتروني جديد في Outlook

Public gFolders As String

Public Sub GetFolderNames()
Dim oSession As Outlook.NameSpace
Dim oFolder As Outlook.MAPIFolder
Dim oNewMail As Outlook.MailItem

Set oSession = Outlook.Application.GetNamespace("MAPI")
Set oFolder = oSession.PickFolder

If (oFolder Is Nothing) Then Exit Sub

ProcessFolder oFolder

Set oNewMail = Application.CreateItem(olMailItem)
oNewMail.Body = gFolders
oNewMail.Display

gFolders = ""
End Sub

Sub ProcessFolder(CurrentFolder As Outlook.MAPIFolder)
Dim i As Long
Dim oSubFolder As Outlook.MAPIFolder
Dim oFolder As Outlook.MAPIFolder
Dim sFolderPaths As String

For i = CurrentFolder.Folders.Count To 1 Step -1
    Set oFolder = CurrentFolder.Folders(i)
    sFolderPaths = oFolder.FolderPath
    gFolders = gFolders & vbCrLf & sFolderPaths & " " & oFolder.Items.Count
Next

For Each oSubFolder In CurrentFolder.Folders
    If oSubFolder.Name <> "Deleted Items" Then
        ProcessFolder oSubFolder
    End If
Next
End Sub

3. اضغط على "F5" لتشغيل VBA.

4. في مربع الحوار "تحديد مجلد" الذي يظهر، حدد حساب البريد الإلكتروني الذي تريد طباعة قائمة مجلداته، ثم انقر على "موافق".

Select folder dialog

5. سيتم نسخ قائمة المجلدات الخاصة بالحساب المحدد إلى بريد إلكتروني جديد كما هو موضح أدناه. انقر على "ملف" > "طباعة" لطباعة قائمة المجلدات.

Generated email with folder list

6. بعد الطباعة، أغلق البريد الإلكتروني الجديد دون حفظه.

تصدير وطباعة قائمة جميع مجلدات Outlook والمجلدات الفرعية في Notepad

تُقدم هذه الطريقة سكربت VBA لتصدير قائمة جميع المجلدات والمجلدات الفرعية في حساب البريد الإلكتروني المحدد من Outlook إلى Notepad. بعد ذلك، يمكنك بسهولة طباعة قائمة المجلدات.

1. اضغط على "Alt" + "F11" لفتح نافذة Microsoft Visual Basic for Applications.

2. انقر على "إدراج" > "وحدة"، ثم الصق الكود التالي لـ VBA في نافذة الوحدة الجديدة.

VBA: تصدير قائمة جميع مجلدات Outlook والمجلدات الفرعية من Outlook إلى Notepad

Dim gFileName, gCreateTree, gBase

Public Sub ExportFolderTree()
Dim objOutlook
Dim F, Folders
Dim Result

Set objOutlook = CreateObject("Outlook.Application")
Set F = objOutlook.Session.PickFolder

If Not F Is Nothing Then
    Set Folders = F.Folders
    Result = MsgBox("Do you want to create tree?", vbYesNo + vbDefaultButton2 + vbApplicationModal, "Output Folder Tree")
    If Result = 6 Then
        gCreateTree = True
    Else
        gCreateTree = False
    End If

    gFileName = GetDesktopFolder() & "\Outlook-Folders.txt"
    gBase = Len(F.FolderPath) - Len(Replace(F.FolderPath, "\", "")) + 1

    WriteToATextFile (CreateFolderTree(F.FolderPath, F.Name))
    LoopFolders Folders

    Set F = Nothing
    Set Folders = Nothing
    Set objOutlook = Nothing
End If
End Sub

Private Function GetDesktopFolder()
Dim objShell
Set objShell = CreateObject("WScript.Shell")
GetDesktopFolder = objShell.SpecialFolders("Desktop")
Set objShell = Nothing
End Function

Private Sub LoopFolders(Folders)
Dim F
For Each F In Folders
    WriteToATextFile (CreateFolderTree(F.FolderPath, F.Name))
    LoopFolders F.Folders
Next
End Sub

Private Sub WriteToATextFile(OLKfoldername)
Dim objFSO, objTextFile
Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objTextFile = objFSO.OpenTextFile(gFileName, 8, True)
objTextFile.WriteLine (OLKfoldername)
objTextFile.Close
Set objFSO = Nothing
Set objTextFile = Nothing
End Sub

Private Function CreateFolderTree(OLKfolderpath, OLKfoldername)
If gCreateTree = False Then
    CreateFolderTree = Mid(OLKfolderpath, 3)
Else
    Dim i, x, OLKprefix
    i = Len(OLKfolderpath) - Len(Replace(OLKfolderpath, "\", ""))
    For x = gBase To i
        OLKprefix = OLKprefix & "-"
    Next
    CreateFolderTree = OLKprefix & OLKfoldername
End If
End Function

3. اضغط على "F5" لتشغيل VBA. في مربع الحوار "تحديد مجلد" الذي يفتح، حدد حساب البريد الإلكتروني الذي تريد تصدير قائمة مجلداته وطباعتها، ثم انقر على "موافق".

Select folder dialog

4. سيظهر مربع الحوار "مخرجات شجرة المجلدات". انقر على "نعم" أو "لا" بناءً على ما إذا كنت ترغب في تضمين المسافة البادئة للشجرة.

Prompt for tree creation

الآن، تم إنشاء وحفظ ملف نصي باسم "Outlook-Folders" على سطح المكتب كما هو موضح أدناه:

Outlook-Folders text file

5. انقر مرتين لفتح الملف النصي الجديد، ثم انقر على "ملف" > "طباعة" لطباعة القائمة المصدرة لمجلدات Outlook.

مساعد البريد الإلكتروني الذكي في Outlook: ردود أذكى، تواصل أوضح (سحر بنقرة واحدة!) مجانًا

قم بتبسيط مهام Outlook اليومية باستخدام مساعد البريد الإلكتروني الذكي من أدوات Kutools لـ Outlook. هذا الأداة القوية تتعلم من رسائل البريد الإلكتروني السابقة لتقدم ردودًا ذكية ودقيقة، تحسين محتوى البريد الإلكتروني، وتساعدك على صياغة وتحسين الرسائل بسهولة.

هذه الميزة تدعم:

ردود ذكية: احصل على ردود مصممة من محادثاتك السابقة - مخصصة، دقيقة وجاهزة للإرسال.
تحسين المحتوى: قم بتحسين نصوص البريد الإلكتروني تلقائيًا لتحقيق الوضوح والتأثير.
الكتابة السهلة: فقط قدم الكلمات المفتاحية، ودع الذكاء الاصطناعي يتولى الباقي، مع أساليب كتابة متعددة.
التوسعات الذكية: قم بتوسيع أفكارك باقتراحات تعتمد على السياق.
الملخصات: احصل على ملخصات مختصرة للرسائل الطويلة فورًا.
التواصل العالمي: قم بترجمة رسائل البريد الإلكتروني إلى أي لغة بسهولة.

هذه الميزة تدعم: