كيف يمكن العثور على مجلد (مع عرض المسار الكامل لملفه) في Outlook باستخدام اسم المجلد؟

اتبع الخطوات التالية للبحث عن مجلدات حسب اسم المجلد باستخدام VBA في Outlook.

1. اضغط مفاتيح «Alt» + "F11" معًا لفتح نافذة «Microsoft Visual Basic for Applications».

2. انقر فوق «Insert» > «Module»، ثم الصق كود VBA أدناه في نافذة الوحدة الجديدة.

VBA: البحث وفتح المجلد حسب اسم المجلد في Outlook

Private m_Folder As MAPIFolder
Private m_Find As String
Private m_Wildcard As Boolean

Private Const SpeedUp As Boolean = True
Private Const StopAtFirstMatch As Boolean = True

Public Sub FindFolder()
Dim sName As String
Dim oFolders As Folders

  Set m_Folder = Nothing
m_Find = ""
m_Wildcard = False

  sName = InputBox("Find:", "Search folder")
If Len(Trim(sName)) = 0 Then Exit Sub
m_Find = sName

  m_Find = LCase(m_Find)
m_Find = Replace(m_Find, "%", "*")
m_Wildcard = (InStr(m_Find, "*"))

  Set oFolders = Application.Session.Folders
LoopFolders oFolders

  If Not m_Folder Is Nothing Then
If MsgBox("Activate folder: " & vbCrLf & m_Folder.FolderPath, vbQuestion Or vbYesNo) = vbYes Then
Set Application.ActiveExplorer.CurrentFolder = m_Folder
End If
Else
MsgBox "Not found", vbInformation
End If
End Sub

Private Sub LoopFolders(Folders As Outlook.Folders)
Dim oFolder As MAPIFolder
Dim bFound As Boolean

If SpeedUp = False Then DoEvents

  For Each oFolder In Folders
If m_Wildcard Then
bFound = (LCase(oFolder.Name) Like m_Find)
Else
bFound = (LCase(oFolder.Name) = m_Find)
End If

    If bFound Then
If StopAtFirstMatch = False Then
If MsgBox("Found: " & vbCrLf & oFolder.FolderPath & vbCrLf & vbCrLf & "Continue?", vbQuestion Or vbYesNo) = vbYes Then
bFound = False
End If
End If
End If
If bFound Then
Set m_Folder = oFolder
Exit For
Else
LoopFolders oFolder.Folders
If Not m_Folder Is Nothing Then Exit For
End If
Next
End Sub

3. اضغط مفتاح "F5" أو انقر زر «Run» لتشغيل كود VBA هذا.

4. في مربع الحوار المنبثق «Search folder»، اكتب اسم المجلد الذي تريد البحث فيه، ثم انقر فوق زر «OK».

ملاحظة: يدعم هذا الكود البرمجي VBA استخدام الرمز النجمي (*) كعنصر بديل. على سبيل المثال، يمكنك كتابة tes* للعثور على جميع المجلدات التي يبدأ اسمها بـ «tes».

5. الآن تظهر نافذة حوار تعرض مسار المجلد الذي تم العثور عليه. إذا كنت ترغب في فتح هذا المجلد، يُرجى النقر على زر «Yes».

والآن يتم فتح المجلد الذي تم العثور عليه في التنقل كما هو موضح في لقطة الشاشة أدناه:

ملاحظة: إذا وُجد أكثر من مجلد واحد يحمل الاسم المحدد، فإن كود VBA هذا يستطيع العثور على مجلد واحد فقط وفتحه.

إذا كان لديك «Kutools لـ Outlook» مثبَّتًا، فيمكنك استخدام ميزة «Go To» الخاصة به للعثور بسرعة على جميع المجلدات بناءً على اسم مجلد معيَّن، وفتح أيٍّ من المجلدات التي تم العثور عليها بسهولة أيضًا.

1. انقر فوق «KUTOOLS PLUS» > «Go To» لتفعيل هذه الميزة.

2. في مربع حوار «Go To»، اكتب اسم المجلد المحدد في حقل «Search»، ثم اختر المجلد من نتائج البحث وانقر على زر «OK».

الآن تم العثور على المجلد المحدد الذي يحتوي على اسم المجلد المعيّن، وتم فتحه فورًا.