كيف يمكن حفظ رسالة بريد إلكتروني كصورة (بصيغة JPG أو TIFF) في Outlook؟

هل سبق أن حاولت حفظ رسالة بريد إلكتروني كصورة، مثل صيغة JPG أو TIFF، في Outlook؟ يعرض لك هذا المقال طريقة فعّالة لحل هذه المشكلة.

حفظ رسالة البريد الإلكتروني بصيغة صورة باستخدام كود VBA

---

حفظ رسالة البريد الإلكتروني بصيغة صورة باستخدام كود VBA

الرجاء اتباع الخطوات التالية لحفظ رسالة البريد الإلكتروني كصورة في Outlook.

1. حدد رسالة البريد الإلكتروني التي تريد حفظها كصورة، ثم اضغط في الوقت نفسه على مفاتيحAlt+F11 لفتح نافذةMicrosoft Visual Basic for Applications.

2. في نافذةMicrosoft Visual Basic for Applications، انقر علىإدراج > UserForm. انظر لقطة الشاشة:

3. أنشئUserform كما هو موضح في لقطة الشاشة أدناه.

4. حدد زر الخيارjpg، ثم غيّر اسمه إلىopbJPG في جزءالخصائصالموجود على اليسار.

5. كرّر الخطوة السابقة 4 لتغيير اسم زر الخيار الآخر إلىopbTIFF. كما غيّر اسم زر الأمرموافقواسم زر الأمرإلغاءإلىcdbOk وcdbCancel على التوالي.

ملاحظة: إذا لم يظهر جزءالخصائصفي نافذةMicrosoft Visual Basic for Applications، يُرجى الضغط على مفتاحF4 لإظهار الجزء.

6. انقر نقرًا مزدوجًا على أي مساحة فارغة في النموذج لفتح نافذةالكود، ثم استبدل كل الكود بالنص البرمجي التالي لـ VBA، وأغلق نافذة الكود.

كود VBA 1: حفظ رسالة البريد الإلكتروني كصورة

Option Explicit
'Update by Extendoffice 2018/3/5
Public xRet As Boolean
Private Sub cdbCancel_Click()
  xRet = False
  FrmPicType.Hide
End Sub
Private Sub cdbOk_Click()
  xRet = True
  FrmPicType.Hide
End Sub

7. حددUserForm1 وغيّر اسمه إلىFrmPicType في جزءالخصائص، كما هو موضح في لقطة الشاشة أدناه.

8. انقر علىإدراج > وحدة نمطية (Module)، ثم انسخ كود VBA التالي إلى نافذة الوحدة النمطية.

كود VBA 2: حفظ رسالة البريد الإلكتروني كصورة

Public Declare PtrSafe Function ShellExecute Lib "shell32.dll" Alias "ShellExecuteA" (ByVal hwnd As Long, ByVal lpOperation As String, ByVal lpFile As String, ByVal lpParameters As String, ByVal lpDirectory As String, ByVal nShowCmd As Long) As Long
'Update by Extendoffice 2018/3/5
Sub ExportEmailAsImage()
Dim xMail As Outlook.MailItem
Dim xFileName, xFilePath, xWdDocPath As String
Dim xPPTApp As PowerPoint.Application
Dim xPresentation As PowerPoint.Presentation
Dim xPPTShape As PowerPoint.Shape
Dim xPicType As String
Dim xFileFormat As PpSaveAsFileType
On Error Resume Next
FrmPicType.Show
If FrmPicType.xRet Then
  If FrmPicType.opbJPG.Value = True Then
    xPicType = ".jpg"
    xFileFormat = ppSaveAsJPG
  ElseIf FrmPicType.opbTIFF.Value = True Then
    xPicType = ".tiff"
    xFileFormat = ppSaveAsTIF
  End If
Else
  Exit Sub
End If
Set xShell = CreateObject("Shell.Application")
Set xFolder = xShell.BrowseForFolder(0, "Select a folder:", 0, 0)
If Not TypeName(xFolder) = "Nothing" Then
    Set xFolderItem = xFolder.self
    xFilePath = xFolderItem.Path & "\"
Else
    xFilePath = ""
    Exit Sub
End If
'ShellExecute 0, "Open", "POWERPNT.exe", "", "", 0
Set xPPTApp = New PowerPoint.Application
xPPTApp.Height = 0
xPPTApp.Width = 0
xPPTApp.WindowState = ppWindowMinimized
xPPTApp.Visible = msoFalse
For Each xMail In Outlook.Application.ActiveExplorer.Selection
    xFileName = Replace(xMail.Subject, "/", " ")
    xFileName = Replace(xFileName, "\", " ")
    xFileName = Replace(xFileName, ":", "")
    xFileName = Replace(xFileName, "?", " ")
    xFileName = Replace(xFileName, Chr(34), " ")
    xWdDocPath = Environ("Temp") & "\" & xFileName & ".doc"
    xMail.SaveAs xWdDocPath, olDoc
    
    Set xPresentation = xPPTApp.Presentations.Add
    xPresentation.Application.WindowState = ppWindowMinimized
    xPresentation.Application.Visible = msoFalse
    With xPresentation
        .PageSetup.SlideHeight = 900 '792
        .PageSetup.SlideWidth = 612
        .Slides.AddSlide 1, .SlideMaster.CustomLayouts(1)
    End With
    xPPTApp.WindowState = ppWindowMinimized
    With xPresentation.Slides(1)
         .Application.Visible = msoFalse
         Set xPPTShape = .Shapes.AddOLEObject(0, 0, 612, 900, , xWdDocPath)
         xPresentation.SaveAs xFilePath & xFileName & xPicType, xFileFormat, msoTrue
    End With
    xPresentation.Close
Next
xPPTApp.Quit
MsgBox "Mails has been successfully saved as picture", vbInformation + vbOKOnly
End Sub

9. انقر علىأدوات > المراجع، وفعّل خانة الاختيار الخاصة بـمكتبة كائنات Microsoft PowerPoint، ثم انقر على زرموافق. انظر لقطة الشاشة:

10. اضغط على مفتاحF5 لتشغيل الكود. بعد ذلك، سيظهر مربع حوارUserForm1. يرجى تحديد نوع الصورة ثم النقر على زرموافق. انظر لقطة الشاشة:

11. في مربع حواراستعراض المجلدات، حدِّد مجلدًا لحفظ الصورة فيه، ثم انقر على زرموافق.

12. أخيرًا، سيظهر مربع حوار منMicrosoft Outlook لإعلامك باكتمال عملية الحفظ. يُرجى النقر على زرموافق.

لقد تم الآن تحويل رسائل البريد الإلكتروني المحددة بنجاح إلى صورة بصيغة JPG أو TIFF وحفظها في المجلد المحدد.

---

مقالات ذات صلة:

• كيف يمكن حفظ جميع المرفقات من عدة رسائل بريد إلكتروني في مجلد واحد في Outlook؟
• كيف يمكنني إزالة جميع المرفقات من رسالة بريد إلكتروني في Outlook؟