كيف يمكن نسخ هيكل مجلدات Outlook بالكامل إلى سطح المكتب (في مستكشف ويندوز)؟

كما تعلم، يمكنك استخدام ميزة الأرشفة لنسخ هيكل مجلد Outlook إلى حساب Outlook آخر، ولكن هل تعلم كيف تنسخ هيكل مجلد Outlook إلى مجلد معيّن في نظام ويندوز، مثل سطح المكتب؟ سيعرض لك هذا المقال كود VBA الذي يتيح لك نسخ هيكل مجلد Outlook إلى مستكشف ويندوز بسهولة.

نسخ مجلد Outlook هيكل المجلد إلى سطح المكتب (مستكشف ويندوز)

---

نسخ مجلد Outlook هيكل المجلد إلى سطح المكتب (مستكشف ويندوز)

يرجى اتباع الخطوات أدناه لنسخ هيكل مجلدات Outlook إلى سطح المكتب أو إلى مستكشف ويندوز.

1. في نافذة التنقّل، انقر لتحديد المجلد الذي تريد نسخ هيكله، ثم اضغط مفتاحَيْ «Alt» + "F11" لفتح نافذة Microsoft Visual Basic for Applications.

2. انقر على «Tools» > «References» لفتح مربع حوار References. بعد ذلك، فعّل خيار «Microsoft Scripting Runtime» في مربع الحوار، ثم انقر على زر «OK». راجع لقطة الشاشة:

3. انقر على «Insert» > «Module»، ثم انسخ والصق كود VBA أدناه في نافذة الوحدة الجديدة.

VBA: نسخ مجلد Outlook هيكل المجلد إلى مستكشف ويندوز

Dim xFSO As Scripting.FileSystemObject
Sub CopyOutlookFldStructureToWinExplorer()
    ExportAction "Copy"
End Sub
  
Sub ExportAction(xAction As String)
Dim xFolder As Outlook.Folder
Dim xFldPath As String
xFldPath = SelectAFolder()
If xFldPath = "" Then
    MsgBox "You did not select a folder. Export cancelled.", vbInformation + vbOKOnly, "Kutools for Outlook"
Else
    Set xFSO = New Scripting.FileSystemObject
    Set xFolder = Outlook.Application.ActiveExplorer.CurrentFolder
    ExportOutlookFolder xFolder, xFldPath
End If
Set xFolder = Nothing
Set xFSO = Nothing
End Sub

Sub ExportOutlookFolder(ByVal OutlookFolder As Outlook.Folder, xFldPath As String)
Dim xSubFld As Outlook.Folder
Dim xItem As Object
Dim xPath As String
Dim xFilePath As String
Dim xSubject As String
Dim xCount As Integer
Dim xFilename As String
On Error Resume Next
xPath = xFldPath & "\" & OutlookFolder.Name
'?????????,??????
If Dir(xPath, 16) = Empty Then MkDir xPath
For Each xItem In OutlookFolder.Items
    xSubject = ReplaceInvalidCharacters(xItem.Subject)
    xFilename = xSubject & ".msg"
    xCount = 0
    xFilePath = xPath & "\" & xFilename
    If xFSO.FileExists(xFilePath) Then
        xCount = xCount + 1
        xFilename = xSubject & " (" & xCount & ").msg"
        xFilePath = xPath & "\" & xFilename
    End If
    xItem.SaveAs xFilePath, olMSG
Next
For Each xSubFld In OutlookFolder.Folders
    ExportOutlookFolder xSubFld, xPath
Next
Set OutlookFolder = Nothing
Set xItem = Nothing
End Sub

Function SelectAFolder() As String
Dim xSelFolder As Object
Dim xShell As Object
On Error Resume Next
Set xShell = CreateObject("Shell.Application")
Set xSelFolder = xShell.BrowseForFolder(0, "Select a folder", 0, 0)
If Not TypeName(xSelFolder) = "Nothing" Then
    SelectAFolder = xSelFolder.self.Path
End If
Set xSelFolder = Nothing
Set xShell = Nothing
End Function
  
Function ReplaceInvalidCharacters(Str As String) As String
Dim xRegEx
Set xRegEx = CreateObject("vbscript.regexp")
xRegEx.Global = True
xRegEx.IgnoreCase = False
xRegEx.Pattern = "\||\/|\<|\>|""|:|\*|\\|\?"
ReplaceInvalidCharacters = xRegEx.Replace(Str, "")
End Function

4. اضغط مفتاح "F5" أو انقر زر «Run» لتشغيل كود VBA هذا.

5. في مربع حوار «Browse For Folder» الظاهر، يُرجى تحديد المجلد الذي ترغب في وضع هيكل المجلد المنقول بداخله، ثم انقر على زر «OK». راجع لقطة الشاشة:

الآن، انتقل إلى المجلد المحدد وستلاحظ أن هيكل المجلد قد نُسخ بالكامل إلى القرص الصلب المحدد. راجع لقطة الشاشة:

ملاحظة: يتم نسخ عناصر المجلد —مثل الرسائل الإلكترونية والمواعيد والمهام وغيرها— أيضًا إلى مجلدات مُقابلة على القرص الصلب.

---

مقالات ذات صلة

كيف يمكن نسخ هيكل المجلد إلى ملف بيانات PST جديد في Outlook؟