كيف يمكن إخفاء رقم الفاكس عند عرض قائمة الأسماء في Outlook؟

في Outlook، ربما لاحظت أن عمود عنوان البريد الإلكتروني في قائمة «تحديد الأسماء» أو دفتر العناوين يحتوي ليس فقط على عناوين البريد الإلكتروني، بل أيضًا على إدخالات الفاكس التي قد تُسبب لك الإزعاج. في هذه المقالة، أقدّم لك بعض الطرق الفعّالة لإخفاء أرقام الفاكس.

إخفاء رقم الفاكس في تحديد قائمة الأسماء باستخدام VBA

---

إخفاء رقم الفاكس في تحديد قائمة الأسماء باستخدام VBA

إذا كنت ترغب في إخفاء رقم الفاكس الموجود مسبقًا في تحديد قائمة الأسماء، فالرجاء اتباع الخطوات التالية:

1. اضغط علىAlt + F11 لفتح نافذةMicrosoft Visual Basic for Applications.

2. انقر علىإدراج > وحدة نمطيةلإدراج وحدة نمطية فارغة جديدة، ثم انسخ والصق الكود أدناه في النص البرمجي.

VBA: إخفاء رقم الفاكس الموجود في تحديد الأسماء

Sub HideFaxNumbers_ExistingContacts()
'UpdatebyExtendoffice2018-5-23
Dim xStores As Outlook.Stores
Dim xStore As Outlook.Store
Dim xRootFolder As Outlook.Folder
Dim xFolder As Folder
On Error Resume Next
Set xStores = Outlook.Application.Session.Stores
For Each xStore In xStores
    Set xRootFolder = xStore.GetRootFolder
    For Each xFolder In xRootFolder.Folders
        Call ProcessFolders(xFolder)
    Next
Next
End Sub
Sub ProcessFolders(ByVal CurrentFolder As Outlook.Folder)
Dim xContactItem As Outlook.ContactItem
Dim xSubFolder As Outlook.Folder
Dim xFax As String
Dim I As Integer
On Error Resume Next
If CurrentFolder.DefaultItemType <> olContactItem Then Exit Sub
xFax = "Fax: "
For I = CurrentFolder.Items.Count To 1 Step -1
    Set xContactItem = CurrentFolder.Items.Item(I)
    With xContactItem
        If (Len(.BusinessFaxNumber) <> 0) And InStrRev(.BusinessFaxNumber, Trim(xFax)) = 0 Then
            .BusinessFaxNumber = xFax & .BusinessFaxNumber
        End If
        If (Len(.HomeFaxNumber) <> 0) And InStrRev(.HomeFaxNumber, Trim(xFax)) = 0 Then
            .HomeFaxNumber = xFax & .HomeFaxNumber
        End If
        If (Len(.OtherFaxNumber) <> 0) And InStrRev(.OtherFaxNumber, Trim(xFax)) = 0 Then
            .OtherFaxNumber = xFax & .OtherFaxNumber
        End If
        .Save
    End With
Next I
If CurrentFolder.Folders.Count <> 0 Then
    For I = CurrentFolder.Folders.Count To 1 Step -1
        Set xSubFolder = CurrentFolder.Folders.Item(I)
        Call ProcessFolders(xSubFolder)
    Next I
End If
End Sub

3. اضغط علىF5 لتشغيل الكود، وسيتم الآن إخفاء أرقام الفاكس.

إذا كنت ترغب في إخفاء رقم الفاكس في جهة اتصال، فاتبع الخطوات التالية:

1. اضغط علىAlt + F11لفتح نافذةMicrosoft Visual Basic for Applications.

2. انقر مرتين علىThisOutlookSession من جزءالمشروع-1، ثم انسخ والصق الكود أدناه في النص البرمجي.

VBA: إخفاء رقم الفاكس في إضافة جهة اتصال الجديدة

Public WithEvents xInspectors As Outlook.Inspectors
Public WithEvents xContactItem As Outlook.ContactItem
Private Sub Application_Startup()
'UpdatebyExtendoffice2018-5-23
    Set xInspectors = Outlook.Application.Inspectors
End Sub
Private Sub xInspectors_NewInspector(ByVal Inspector As Inspector)
If TypeName(Inspector.CurrentItem) = "ContactItem" Then
    Set xContactItem = Inspector.CurrentItem
End If
End Sub
Private Sub xContactItem_PropertyChange(ByVal Name As String)
Dim xArr() As Variant
Dim xFax As String
On Error Resume Next
xArr = Array("BusinessFaxNumber", "HomeFaxNumber", "OtherFaxNumber")
xFax = "Fax: "
With xContactItem
    Select Case Name
        Case xArr(0)
            If InStrRev(.BusinessFaxNumber, Trim(xFax)) = 0 Then
                .BusinessFaxNumber = xFax & .BusinessFaxNumber
            End If
        Case xArr(1)
            If InStrRev(.HomeFaxNumber, Trim(xFax)) = 0 Then
                .HomeFaxNumber = xFax & .HomeFaxNumber
            End If
        Case xArr(2)
            If InStrRev(.OtherFaxNumber, Trim(xFax)) = 0 Then
                .OtherFaxNumber = xFax & .OtherFaxNumber
            End If
    End Select
End With
End Sub

3. احفظ الكود، ثم أعد تشغيل Outlook لتفعيله.

ابتداءً من الآن، سيتم إخفاء أرقام الفاكس الخاصة بجميع جهات الاتصال الجديدة في نافذة «تحديد الأسماء: الجهات الاتصال».