كيف يمكن تصدير جهات الاتصال مع صورها من Outlook؟

عند تصدير جهات الاتصال من Outlook إلى ملف، يمكنك تصدير المعلومات النصية لجهات الاتصال فقط. ولكن في بعض الأحيان، قد تحتاج إلى تصدير الصور المرتبطة بها أيضًا مع بياناتها النصية. فكيف يمكنك تنفيذ هذه المهمة في Outlook؟

تصدير معلومات جهات الاتصال مع الصور المرتبطة بها باستخدام كود VBA

---

تصدير معلومات جهات الاتصال مع الصور المرتبطة بها باستخدام كود VBA

يمكنك استخدام كود VBA أدناه لتصدير جميع جهات الاتصال من مجلد جهات اتصال معيّن إلى ملفات نصية منفصلة، بما في ذلك صورها. يُرجى اتباع الخطوات التالية:

1. حدد مجلد جهات الاتصال الذي ترغب في تصدير جهات الاتصال منه مع صورها.

2. بعد ذلك، اضغط مع الاستمرار على مفتاحَي «ALT» + "F11" لفتح نافذة «Microsoft Visual Basic for Applications».

3. ثم انقر على «Insert» > «Module»، وانسخ والصق الكود أدناه في وحدة النمط الفارغة التي تم فتحها، كما هو موضح في لقطة الشاشة:

كود VBA: تصدير معلومات جهات الاتصال مع الصور

Sub BatchExportContactPhotosandInformation()
Dim xContactItems As Outlook.Items
Dim xItem As Object
Dim xContactItem As ContactItem
Dim xContactInfo As String
Dim xShell As Object
Dim xFSO As Scripting.FileSystemObject
Dim xTextFile As Scripting.TextStream
Dim xAttachments As Attachments
Dim xAttachment As Attachment
Dim xSavePath, xEmailAddress As String
Dim xFolder As Outlook.Folder
On Error Resume Next
Set xFSO = CreateObject("Scripting.FileSystemObject")
Set xShell = CreateObject("Shell.application").BrowseforFolder(0, "Select a Folder", 0, 16)
If xShell Is Nothing Then Exit Sub
xSavePath = xShell.Items.Item.Path & "\"
If Outlook.Application.ActiveExplorer.CurrentFolder.DefaultItemType <> olContactItem Then
    Set xFolder = Outlook.Application.Session.GetDefaultFolder(olFolderContacts)
Else
    Set xFolder = Outlook.Application.ActiveExplorer.CurrentFolder
End If
Set xContactItems = xFolder.Items
For i = xContactItems.Count To 1 Step -1
    Set xItem = xContactItems.Item(i)
    If xItem.Class = olContact Then
        Set xContactItem = xItem
        With xContactItem
            xEmailAddress = .Email1Address
            If Len(Trim(.Email2Address)) <> 0 Then
                xEmailAddress = xEmailAddress & ";" & .Email2Address
            End If
            If Len(Trim(.Email3Address)) <> 0 Then
                xEmailAddress = xEmailAddress & ";" & .Email3Address
            End If
            xContactInfo = "Name: " & .FullName & vbCrLf & "Email: " & _
                           xEmailAddress & vbCrLf & "Company: " & .CompanyName & _
                           vbCrLf & "Department: " & .Department & _
                           vbCrLf & "Job Title: " & .JobTitle & _
                           vbCrLf & "IM: " & .IMAddress & _
                           vbCrLf & "Business Phone: " & .BusinessTelephoneNumber & _
                           vbCrLf & "Home Phone: " & .HomeTelephoneNumber & _
                           vbCrLf & "BusinessFax Phone: " & .BusinessFaxNumber & _
                           vbCrLf & "Mobile Phone: " & .MobileTelephoneNumber & _
                           vbCrLf & "Business Address: " & .BusinessAddress
            Set xTextFile = xFSO.CreateTextFile(xSavePath & .FullName & ".txt", True)
            xTextFile.WriteLine xContactInfo
            If .Attachments.Count > 0 Then
                Set xAttachments = .Attachments
                For Each xAttachment In xAttachments
                    If InStr(LCase(xAttachment.FileName), "contactpicture.jpg") > 0 Then
                        xAttachment.SaveAsFile (xSavePath & .FullName & ".jpg")
                    End If
                Next
            End If
        End With
    End If
Next i
End Sub

4. بعد لصق الكود في الوحدة، انتقل إلى نافذة «Microsoft Visual Basic for Applications» وانقر على «Tools» > «References». ثم، في مربع الحوار المنبثق "References - Project1"، فعّل خيار «Microsoft Scripting Runtime» من قائمة «Available References»، كما هو موضح في لقطة الشاشة:

5. انقر على «موافق» لإغلاق مربع الحوار، ثم اضغط على مفتاح "F5" لتشغيل هذا الكود. في مربع الحوار المنبثق «استعراض المجلدات»، حدد المجلد الذي ترغب في حفظ جهات الاتصال المصدرة فيه، كما هو موضح في لقطة الشاشة:

6. بعد ذلك، انقر على «موافق»، وسيتم تصدير جميع المعلومات مع صور جهات الاتصال إلى المجلد الذي حددته بشكل منفصل، كما هو موضح في لقطة الشاشة: