كيف يمكن البحث عن نص في موضوع الرسائل أو المهام في Outlook واستبداله؟

في Outlook، إذا كان لديك عدة عناوين رسائل أو مهام تحتاج إلى استبدالها بنصٍّ معيّن من قِبَلك، فمن المؤكّد أنك تستطيع تعديلها واحدة تلو الأخرى — ولكن، هل هناك طريقة سريعة لإتمام هذه المهمة دفعةً واحدة في Outlook؟

البحث والاستبدال نص الموضوع ضمن عدة رسائل باستخدام كود VBA

البحث والاستبدال نص الموضوع ضمن عدة مهام باستخدام كود VBA

---

البحث والاستبدال نص الموضوع ضمن عدة رسائل باستخدام كود VBA

إذا كنت ترغب في العثور على نصٍّ معيّن واستبداله بنصٍّ آخر عبر عناوين عدة رسائل، فإن كود VBA أدناه سيُسهّل عليك المهمة. يُرجى اتباع الخطوات التالية:

1. حدد الرسائل الإلكترونية التي تريد تنفيذ البحث والاستبدال في نص موضوعها، ثم اضغط مع الاستمرار على مفتاحي «ALT + F11» لفتح نافذة «Microsoft Visual Basic for Applications».

2. بعد ذلك، انقر على «Insert» > «Module»، ثم انسخ والصق الكود أدناه في وحدة النمط الفارغة التي تم فتحها، كما هو موضّح في لقطة الشاشة:

كود VBA: البحث والاستبدال نص الموضوع ضمن عدة رسائل:

Option Explicit
Sub FindAndReplaceInSubject()
Dim xItem As Object
Dim xNewSubject As String
Dim xMailItem As MailItem
Dim xExplorer As Explorer
Dim i As Integer
On Error Resume Next
Set xExplorer = Outlook.Application.ActiveExplorer
For i = xExplorer.Selection.Count To 1 Step -1
    Set xItem = xExplorer.Selection.Item(i)
    If xItem.Class = olMail Then
        Set xMailItem = xItem
        With xMailItem
            xNewSubject = Replace(.Subject, "kte", "Kutools for Excel")
            .Subject = xNewSubject
            .Save
        End With
    End If
Next
End Sub

ملاحظات: في الكود أعلاه: `xNewSubject = Replace(.Subject، «kte»، «[[PH_8]]»)`، حيث يُعدّ `«kte»` النص القديم الذي تريد البحث عنه، و`«Kutools لـ Excel»` هو النص الجديد الذي تريد استبداله به. يُرجى تعديل هذه القيم وفقًا لاحتياجاتك.

3. بعد ذلك، اضغط على مفتاح "F5" لتشغيل هذا الكود، وسيتم استبدال النص المعيّن في عناوين الرسائل بالنص الجديد وفقًا لرغبتك، كما هو موضّح في لقطة الشاشة:

---

البحث والاستبدال نص الموضوع ضمن عدة مهام باستخدام كود VBA

إذا كنت بحاجة إلى البحث عن نص الموضوع في المهام واستبداله، فإن كود VBA التالي سيُساعدك أيضًا.

1. اضغط مع الاستمرار على مفتاحَي «ALT + F11» لفتح نافذة «Microsoft Visual Basic for Applications».

2. بعد ذلك، انقر على «Insert» > «Module»، ثم انسخ والصق الكود أدناه في وحدة النمط الفارغة التي تم فتحها، كما هو موضّح في لقطة الشاشة:

كود VBA: البحث والاستبدال نص الموضوع ضمن جميع المهام:

Option Explicit
Sub FindReplaceTextsInAllTaskSubjects()
Dim xPane As NavigationPane
Dim xModule As TasksModule
Dim xGroup As NavigationGroup
Dim xNavFolder As NavigationFolder
Dim xTaskItem As Outlook.TaskItem
Dim i, k As Integer
Dim xFindStr, xReplaceStr As String
Dim xTotalCount As Long
On Error Resume Next
xFindStr = InputBox("Type the words to find:", "Kutools for Outlook", xFindStr)
If Len(Trim(xFindStr)) = 0 Then Exit Sub
xReplaceStr = InputBox("Type the words to replace:", "Kutools for Outlook", xReplaceStr)
If Len(Trim(xReplaceStr)) = 0 Then Exit Sub
xTotalCount = 0
Set xPane = Outlook.Application.ActiveExplorer.NavigationPane
Set xModule = xPane.Modules.GetNavigationModule(olModuleTasks)
Set xGroup = xModule.NavigationGroups.Item(1)
For i = xGroup.NavigationFolders.Count To 1 Step -1
    Set xNavFolder = xGroup.NavigationFolders.Item(i)
    For k = xNavFolder.Folder.Items.Count To 1 Step -1
        Set xTaskItem = xNavFolder.Folder.Items(k)
        If InStr(xTaskItem.Subject, xFindStr) > 0 Then
            xTaskItem.Subject = Replace(xTaskItem.Subject, xFindStr, xReplaceStr)
            xTaskItem.Save
            xTotalCount = xTotalCount + 1
        End If
    Next
Next
MsgBox xTotalCount & " task subjects have been changed!", vbInformation + vbOKOnly, "Kutools for Outlook"
End Sub

3. بعد ذلك، اضغط على مفتاح "F5" لتنفيذ هذا الكود، وستظهر نافذة منبثقة. يُرجى إدخال النص الذي ترغب في البحث عنه ضمن عناوين المهام، كما هو موضّح في لقطة الشاشة:

4. انقر فوق «موافق»، وستظهر نافذة منبثقة أخرى. يُرجى إدخال النص الجديد الذي ترغب في استبداله به، كما هو موضّح في لقطة الشاشة:

5. بعد ذلك، انقر فوق «موافق»، وستظهر نافذة حوار تُبلغك بعدد العناوين التي تم تعديلها، كما هو موضّح في لقطة الشاشة:

6. انقر فوق «موافق»، وسيتم استبدال النص القديم في عناوين المهام بالعناوين الجديدة، كما هو موضّح في لقطة الشاشة: