كيف يمكن تغيير التوقيع تلقائيًا في Outlook بناءً على المستلمين؟

بشكل افتراضي، يحتوي Outlook على وظيفة مدمجة تتيح لك تغيير التوقيع تلقائيًا عند إرسال رسائل البريد الإلكتروني من حسابات بريد إلكتروني مختلفة. ولكن إليك أيضًا طريقة ذكية لتغيير التوقيع تلقائيًا بناءً على المستلمين المختلفين المدرَجين في حقل «إلى» في Outlook.

تغيير التوقيع تلقائيًا بناءً على المستلمين باستخدام كود VBA

---

تغيير التوقيع تلقائيًا بناءً على المستلمين باستخدام كود VBA

يرجى اتباع الخطوات أدناه لتطبيق تواقيع مختلفة على المستلمين المعنيين عند إرسال رسائل البريد الإلكتروني في Outlook.

1. أولًا، تحتاج إلى تعطيل ميزة إرفاق التوقيع تلقائيًا في Outlook. انقر علىملف > خياراتلفتح نافذةخيارات Outlook.

2. في نافذةخيارات Outlook، اخترالبريدمن الجزء الأيسر، ثم انقر على زرالتواقيعفي قسمكتابة الرسائل. انظر لقطة الشاشة:

3. في مربع الحوارالتواقيع والورق المخصص، انتقل إلى قسماختيار التوقيع الافتراضيالموجود ضمن علامة التبويبتوقيع البريد الإلكتروني، وحدد حساب بريد إلكتروني من القائمة المنسدلةحساب البريد الإلكتروني، ثم اختر(بلا)من القائمتين المنسدلتينالرسائل الجديدةوالردود/إعادة التوجيه. كرّر هذه الخطوات حتى يتم ضبط جميع الحسابات على(بلا). بعد ذلك، انقر على زرموافق.

ملاحظة: يمكنك أيضًا إنشاء التواقيع التي تحتاجها في مربع الحوار هذاالتواقيع والورق المخصص.

4. عند العودة إلى نافذةخيارات Outlook، انقر على زرموافق.

5. اضغط على مفاتيحAlt + F11 لفتح نافذةمايكروسوفت فيجوال بيسك للتطبيقات.

6. في نافذةمايكروسوفت فيجوال بيسك للتطبيقات، انقر مرتين علىThisOutlookSession في الجزء الأيسر لفتح نافذة الكود، ثم الصق كود VBA التالي فيها. انظر لقطة الشاشة:

كود VBA: تغيير التوقيع تلقائيًا بناءً على المستلمين في Outlook

Private Sub Application_ItemSend(ByVal Item As Object, Cancel As Boolean)
'Updated by ExtendOffice 2022/08/01
Dim xMailItem As MailItem
Dim xRecipients As Recipients
Dim xRecipient As Recipient
Dim xRcpAddress As String
Dim xSignatureFile, xSignaturePath As String
Dim xFSO As Scripting.FileSystemObject
Dim xDoc As Document
Dim xFindStr As String
On Error Resume Next
Set xFSO = New Scripting.FileSystemObject
If Item.Class <> olMail Then Exit Sub
Set xMailItem = Item
Set xRecipients = xMailItem.Recipients
xSignaturePath = CreateObject("WScript.Shell").SpecialFolders(5) + "\Microsoft\Signatures\"
For Each xRecipient In xRecipients
    If xRecipient.AddressEntry.AddressEntryUserType = olExchangeUserAddressEntry Then
        xRcpAddress = xRecipient.AddressEntry.GetExchangeUser.PrimarySmtpAddress
    Else
        xRcpAddress = xRecipient.AddressEntry.Address
    End If
    Select Case xRcpAddress
        Case "Email Address 1"
            xSignatureFile = xSignaturePath & "aaa.htm"
            Exit For
        Case "Email Address 2", "Email Address 3"
            xSignatureFile = xSignaturePath & "bbb.htm"
            Exit For
        Case "Email Address 4"
            xSignatureFile = xSignaturePath & "ccc.htm"
            Exit For
    End Select
Next
VBA.DoEvents
Set xDoc = xMailItem.GetInspector.WordEditor
xFindStr = "From: " & xMailItem.Recipients.Item(1).Name & " <" & xRcpAddress & ">"
If VBA.InStr(1, xMailItem.Body, xFindStr) <> 0 Then
    xDoc.Application.Selection.HomeKey Unit:=wdStory, Extend:=wdMove
    With xDoc.Application.Selection.Find
        .ClearFormatting
        .Text = xFindStr
        .Execute Forward:=True
    End With
    With xDoc.Application.Selection
        .MoveLeft wdCharacter, 2
        .InsertParagraphAfter
        .MoveDown Unit:=wdLine, Count:=1
    End With
Else
    With xDoc.Application.Selection
        .EndKey Unit:=wdStory, Extend:=wdMove
        .InsertParagraphAfter
        .MoveDown Unit:=wdLine, Count:=1
    End With
End If
xDoc.Application.Selection.InsertFile FileName:=xSignatureFile, Link:=False, Attachment:=False
End Sub

ملاحظات:

• 1). في كود VBA، يُرجى استبدال "عنوان البريد الإلكتروني 1/2/3/4" بعنوان البريد الإلكتروني المعيّن للمستلمين.
• 2). "aaa.htm«، و»bbb.htm«، و»ccc.htm" هي التواقيع المحددة التي ستُرسَل إلى المستلمين المعنيين.
• 3). في هذه الحالة، سيتم إرسال التوقيع "aaa« إلى »عنوان البريد الإلكتروني 1«، وسيتم إرسال التوقيع »bbb« إلى »عنوان البريد الإلكتروني 2« و»عنوان البريد الإلكتروني 3"، كما سيتلقى "عنوان البريد الإلكتروني 4« البريد الإلكتروني المضمّن مع التوقيع »ccc". يُرجى تعديلها حسب احتياجاتك.
• 4). إذا تضمّن البريد الإلكتروني عدة مستلمين، يأخذ الكود بعين الاعتبار المستلم الأول فقط، وبالتالي سيتلقى باقي المستلمين رسائل تحمل نفس التوقيع المخصص للمستلم الأول.

7. بعد ذلك، انقر علىأدوات > المراجعللانتقال إلى مربع حوارالمراجع - المشروع. في المربع، يُرجى تحديد الخيارينMicrosoft Word Object Library وMicrosoft Scripting Runtime معًا، ثم انقر على زرموافق. انظر لقطة الشاشة:

8. اضغط على مفاتيحAlt+Q لإغلاق نافذةمايكروسوفت فيجوال بيسك للتطبيقات.

ابتداءً من الآن، وبعد كتابة رسالة بريد إلكتروني والنقر على زر الإرسال، سيتم إدراج التوقيع المناسب تلقائيًا في نهاية الرسالة بناءً على عنوان البريد الإلكتروني للمستلم الموجود في حقل «إلى».

---