كيف يمكن وضع علامة تلقائية على رسائل البريد الإلكتروني في Outlook بناءً على وجود مرفق معيّن؟

عند استلام بعض رسائل البريد الإلكتروني التي تحتوي على مرفقات مهمة معيّنة، قد ترغب في وضع علامة عليها لتمييزها، حتى يتسنّى لك العثور عليها بسرعة وسهولة لمتابعتها. في هذه المقالة، سأعرض طريقةً سهلةً لوضع علامة تلقائية على الرسائل التي تتضمّن مرفقات بأسماء معيّنة.

وضع علامة تلقائية على رسائل البريد الإلكتروني بناءً على مرفق معيّن باستخدام كود VBA

---

وضع علامة تلقائية على رسائل البريد الإلكتروني بناءً على مرفق معيّن باستخدام كود VBA

لوضع علامة تلقائية على الرسائل التي تحتوي على مرفق معيّن، يُرجى تطبيق كود VBA التالي:

1. افتح Outlook، ثم اضغط مع الاستمرار على مفتاحَي «ALT + F11» لفتح نافذة «Microsoft Visual Basic for Applications».

2. في نافذة «Microsoft Visual Basic for Applications»، انقر مرتين على «ThisOutlookSession» ضمن جزء "Project1 (VbaProject.OTM)" لفتح وحدة جديدة، ثم انسخ والصق الكود التالي في الوحدة الفارغة.

كود VBA: وضع علامة تلقائية على رسائل البريد الإلكتروني بناءً على مرفق معيّن:

Public WithEvents GMailItems As Outlook.Items
Private Sub Application_Startup()
    Set GMailItems = Outlook.Application.Session.GetDefaultFolder(olFolderInbox).Items
End Sub

Private Sub GMailItems_ItemAdd(ByVal Item As Object)
    If Item.Class <> olMail Then Exit Sub
    FlagEmail_SpecificAttachments Item
End Sub

Sub FlagEmail_SpecificAttachments(Mail As Outlook.MailItem)
    Dim xAttachment As Outlook.Attachment
    Dim xExt As String
    Dim xFileName As String
    If Mail.Attachments.Count = 0 Then Exit Sub
    For Each xAttachment In Mail.Attachments
        xExt = SplitPath(xAttachment.FileName, 2)
        xFileName = SplitPath(xAttachment.FileName, 1)
        Select Case xExt
            Case "txt", "xlsx", "docx", "pdf"
                If InStr(LCase(xFileName), LCase("KTO")) > 0 Then
                    With Mail
                        .ReminderSet = True
                        .ReminderTime = Now + 1
                        .MarkAsTask olMarkTomorrow
                        .Save
                    End With
                End If
        End Select
    Next
End Sub

Public Function SplitPath(FullPath As String, ResultFlag As Integer) As String
Dim xSplitPos As Integer, xDotPos As Integer
xSplitPos = InStrRev(FullPath, "/")
xDotPos = InStrRev(FullPath, ".")
Select Case ResultFlag
    Case 0
        SplitPath = Left(FullPath, xSplitPos - 1)
    Case 1
        If xDotPos = 0 Then xDotPos = Len(FullPath) + 1
        SplitPath = Mid(FullPath, xSplitPos + 1, xDotPos - xSplitPos - 1)
    Case 2
        If xDotPos = 0 Then xDotPos = Len(FullPath)
        SplitPath = Mid(FullPath, xDotPos + 1)
    Case Else
    Err.Raise vbObjectError + 1, "SplitPath Function", "Invalid Parameter!"
End Select
End Function

ملاحظة: في الكود أعلاه، يمكنك تعديل امتداد الملف واسم ملف المرفق وفقًا لاحتياجاتك.

3. بعد ذلك، احفظ الكود وأعد تشغيل Outlook لتفعيله. الآن، عند استلام رسائل بريد إلكتروني تحتوي أسماء مرفقاتها على النص المحدَّد، سيقوم Outlook تلقائيًا بوضع علامة على هذه الرسائل للمتابعة. انظر لقطة الشاشة: