كيف يمكنني طباعة المهام حسب الفئة في Outlook؟

لدى Outlook العديد من فئات الألوان لمهامك، وترغب الآن في طباعة قوائم المهام مصنَّفة حسب الفئات، بحيث تظهر كل فئة في صفحة منفصلة. كيف يمكنك تنفيذ ذلك في Outlook؟

طباعة المهام حسب الفئات في صفحات مختلفة يدويًا واحدة تلو الأخرى

طباعة المهام حسب الفئات في صفحات مختلفة باستخدام كود VBA

---

طباعة المهام حسب الفئات في صفحات مختلفة يدويًا واحدة تلو الأخرى

في Outlook، يمكنك طباعة المهام يدويًا حسب الفئات المختلفة في صفحات منفصلة واحدة تلو الأخرى، يُرجى اتباع الخطوات التالية:

1. افتح Outlook، وانتقل إلى جزء المهام، ثم حدد مجلد المهام الذي تريد طباعته. بعد ذلك، اضغط علىCtrl + E لتفعيل خانةالبحث. ضمن تبويبالبحث، انقر على أيقونةمصنّفواختر فئة اللون التي تريد طباعتها، كما هو موضح في لقطة الشاشة:

2. بعد ذلك، ستظهر جميع المهام التي تحمل فئة اللون المحددة دفعة واحدة، كما هو موضح في لقطة الشاشة:

3. بعد ذلك، انقر علىملف > طباعةلطباعة قائمة المهام هذه، كما هو موضح في لقطة الشاشة التالية:

4. كرّر الخطوات السابقة لطباعة قوائم المهام الأخرى حسب فئات ألوانها، واحدة تلو الأخرى يدويًا.

---

طباعة المهام حسب الفئات في صفحات مختلفة باستخدام كود VBA

هناك كود VBA يمكنه مساعدتك على طباعة المهام حسب الفئة في صفحات مختلفة دفعة واحدة، يُرجى اتباع الخطوات التالية:

1. انتقل إلى جزءالمهاموحدد مجلد المهام الذي تريد طباعته.

2. بعد ذلك، اضغط باستمرار على مفتاحَيALT + F11 لفتح نافذةMicrosoft Visual Basic for Applications.

3. بعد ذلك، انقر علىإدراج > وحدة نمطية، ثم انسخ والصق الكود أدناه في وحدة النمط الفارغة التي تم فتحها:

كود VBA: طباعة المهام حسب الفئات في صفحات مختلفة:

Sub PrintTaskList_SpecificColorCategory()
    Dim xTaskItems As Outlook.Items
    Dim xTask As Outlook.TaskItem
    Dim xDictionary As Scripting.Dictionary
    Dim xCategoryArr As Variant, xCategory As Variant
    Dim xExcelApp As Excel.Application
    Dim xExcelWorkbook As Excel.Workbook
    Dim xExcelWorksheet As Excel.Worksheet
    Dim xSheet As Excel.Worksheet
    Dim xKey As Variant
    Dim xKeyStr As String
    Dim i As Long, xLastRow As Integer
    On Error Resume Next
    If Application.ActiveExplorer.CurrentFolder.DefaultItemType <> olTaskItem Then Exit Sub
    Set xTaskItems = Application.ActiveExplorer.CurrentFolder.Items
    Set xDictionary = New Scripting.Dictionary
    For Each xTask In xTaskItems
        xCategoryArr = Split(xTask.Categories, ",")
        For Each xCategory In xCategoryArr
            If xDictionary.Exists(Trim(xCategory)) = False Then
               xDictionary.Add Trim(xCategory), 0
            End If
        Next
    Next
    If xDictionary.Count = 0 Then
        MsgBox "The current Task doesn’t have any category", vbOKOnly + vbInformation, "Kutools for Outlook"
        Exit Sub
    End If
    Set xExcelApp = New Excel.Application
    Set xExcelWorkbook = xExcelApp.Workbooks.Add
    xExcelApp.Visible = True
    i = 0
    If xDictionary.Count > xExcelWorkbook.Sheets.Count Then
        xExcelWorkbook.Sheets.Add Count:=xDictionary.Count - xExcelWorkbook.Sheets.Count
    End If
    For Each xKey In xDictionary.Keys
        xKeyStr = CStr(xKey)
        i = i + 1
        Set xExcelWorksheet = xExcelWorkbook.Sheets(i)
        xExcelWorksheet.Name = xKeyStr
        With xExcelWorksheet
             .Range("A1") = xKeyStr
             .Range("A1").Font.Bold = True
             .Range("A1").Font.Size = 18
             .Range("A1", "C1").HorizontalAlignment = xlCenter
             .Range("A1", "C1").VerticalAlignment = xlCenter
             .Range("A1", "C1").Merge
             .Range("A2") = "Subject"
             .Range("A2").Font.Bold = True
             .Range("B2") = "Start Date"
             .Range("B2").Font.Bold = True
             .Range("C2") = "Due Date"
             .Range("C2").Font.Bold = True
        End With
        For Each xTask In xTaskItems
            If InStr(xTask.Categories, xKeyStr) > 0 Then
               xLastRow = xExcelWorksheet.UsedRange.Rows.Count + 1
               With xExcelWorksheet
                    .Range("A" & xLastRow) = xTask.Subject
                    .Range("B" & xLastRow) = xTask.StartDate
                    .Range("C" & xLastRow) = xTask.DueDate
               End With
            End If
        Next
        xExcelWorksheet.Columns("A:C").AutoFit
    Next
    For Each xSheet In xExcelWorkbook.Sheets
        xSheet.PrintOut
    Next
    xExcelWorkbook.Close False
    xExcelApp.Quit
End Sub

4. بعد ذلك، انقر علىأدوات > المراجعفي نافذةMicrosoft Visual Basic for Applications. ثم في مربع الحوار المنبثقالمراجع - المشروع1، حدد الخيارينMicrosoft Excel Object Library وMicrosoft Scripting Runtime من قائمةالمراجع المتاحة، كما هو موضح في لقطة الشاشة:

5. بعد ذلك، انقر على زرموافق، ثم اضغط على مفتاحF5 لتشغيل هذا الكود. وبعد انتهاء التنفيذ، سيتم طباعة قوائم المهام ذات الفئات المختلفة في صفحات منفصلة.