كيفية تغيير الوقت الافتراضي لتأخير الإرسال في Outlook؟

Author: Siluvia Last Modified: 2025-08-06

عند تمكين خيار تأخير الإرسال (خيار "لا تقم بالتسليم قبل" في لقطة الشاشة التالية) لبريد إلكتروني في Outlook، يتم ضبط وقت الإرسال على الساعة 5:00 مساءً بشكل افتراضي. لنفترض أنك تعمل في وقت متأخر من الليل ولا تريد للآخرين أن يعرفوا أنك تعمل لساعات إضافية. ستحتاج إلى تمكين خيار تأخير الإرسال لرسائلك الإلكترونية قبل إرسالها. بعد تمكين الخيار، ستحتاج إلى تغيير وقت الإرسال الافتراضي يدويًا. وإلا سيتم إرسال البريد الإلكتروني بعد الساعة 5:00 مساءً في اليوم التالي. هل هناك أي طريقة لتغيير هذا الوقت الافتراضي للإرسال؟

يوفر لك هذا البرنامج التعليمي كود VBA لمساعدتك على تغيير الوقت الافتراضي لخيار تأخير الإرسال في Outlook.

the steps of changing the default time for delay delivery in Outlook

تغيير الوقت الافتراضي لتأخير الإرسال في Outlook باستخدام كود VBA

يمكنك تطبيق الكود التالي لـ VBA لتغيير الوقت الافتراضي لخيار تأخير الإرسال في Outlook.

في الكود التالي لـ VBA:

يمكنك تحديد وقتيْن: "وقت تأخير الإرسال" و"وقت تمكين خيار تأخير الإرسال".

على سبيل المثال، إذا قمت بضبط وقت تأخير الإرسال على الساعة 07:30 صباحًا وضبط خيار تأخير الإرسال ليتم تمكينه تلقائيًا بعد الساعة 5:30 مساءً. عند إرسال بريد إلكتروني خلال الفترة من 07:30 صباحًا إلى 5:30 مساءً، سيتم إرسال البريد مباشرة. أما إذا تم إرسال بريد إلكتروني خلال الفترة من 5:30 مساءً إلى 07:30 صباحًا، فسيتم جدولته للإرسال بعد الساعة 07:30 صباحًا في اليوم التالي.

يرجى اختبار البرنامج النصي كما يلي.

1. قم بتشغيل Outlook الخاص بك، واضغط على مفتاحي "Alt" + "F11" معًا لفتح نافذة "Microsoft Visual Basic for Applications".

2. في نافذة "Microsoft Visual Basic for Applications"، انقر نقرًا مزدوجًا على "Project1" > "Microsoft Outlook Objects" > "ThisOutlookSession" لفتح نافذة "ThisOutlookSession (Code)", ثم قم بنسخ الكود التالي إلى هذه النافذة.

كود VBA: تغيير الوقت الافتراضي لتأخير الإرسال في Outlook

Private Sub Application_ItemSend(ByVal Item As Object, Cancel As Boolean)
'Updated by Extendoffice & EWP 20230602
  Const xDelayTime As String = "07:30:00"  'The delay delivery time of emails
  Const xCompareTime As String = "17:30:00" 'The time to enable the delay delivery option
  Dim xMail As Outlook.MailItem
  Dim xWeekday As Integer
  Dim xNowTime As String
  Dim xIsDelay As Boolean
  Dim xRet1 As Integer
  Dim xRet2 As Integer
  On Error GoTo xError
  If (Item.Class <> olMail) Then Exit Sub
  Set xMail = Item
  xWeekday = Weekday(Date, vbMonday)
  xNowTime = Format(Now, "hh:nn:ss")
  xIsDelay = False
  xRet1 = StrComp(xNowTime, xDelayTime)
  xRet2 = StrComp(xNowTime, xCompareTime)
  If xRet1 = xRet2 Then
    xIsDelay = True
  End If
  If (xRet1 = -1) And (xRet2 = -1) Then
    xMail.DeferredDeliveryTime = Date & " " & xDelayTime
  Else
    If ((xWeekday = 5) And xIsDelay) Or (xWeekday = 6) Or (xWeekday = 7) Then
      xMail.DeferredDeliveryTime = (Date + (5 - xWeekday + 3)) & " " & xDelayTime
    ElseIf xIsDelay Then
      xMail.DeferredDeliveryTime = (Date + 1) & " " & xDelayTime
    End If
  End If
Exit Sub
xError:
  MsgBox "ItemSend: " & Err.Description, , "Kutools for Outlook"
End Sub

ملاحظات:

1) يمكنك تغيير وقت التأخير والوقت الذي يتم فيه تمكين خيار تأخير الإرسال في الأسطر التالية.

"Const xDelayTime As String = "07:30:00""

"Const xCompareTime As String = "17:30:00""

2) عند إرسال بريد إلكتروني في عطلة نهاية الأسبوع، سيتم جدولته للإرسال بعد الساعة 07:30 صباحًا يوم الاثنين.

3. احفظ الكود واضغط على مفتاحي "Alt" + "Q" لإغلاق نافذة "Microsoft Visual Basic for Applications".

من الآن فصاعدًا، عند إرسال بريد إلكتروني خلال الفترة من 07:30 صباحًا إلى 5:30 مساءً، سيتم إرسال البريد مباشرة. أما إذا تم إرسال بريد إلكتروني خلال الفترة من 5:30 مساءً إلى 07:30 صباحًا، فسيتم جدولته للإرسال بعد الساعة 07:30 صباحًا في يوم العمل التالي.