كيف يمكن استيراد أعياد الميلاد من Excel إلى تقويم Outlook؟

إذا كانت لديك قائمة طويلة من تواريخ أعياد الميلاد في ورقة عمل، وترغب الآن في استيرادها إلى تقويم Outlook كأحداث، فكيف يمكنك إنجاز هذه المهمة بسرعة باستخدام بعض الطرق الفعّالة؟

---

استيراد أعياد الميلاد من Excel إلى تقويم Outlook باستخدام كود VBA

بشكلٍ عام، لا توجد طريقة مباشرة لاستيراد أعياد الميلاد إلى تقويم Outlook. ولحل هذه المشكلة، سأقوم بإنشاء كود VBA خاص بذلك. يُرجى اتباع الخطوات التالية:

1. افتح ورقة العمل التي تحتوي على أعياد الميلاد التي تريد استيرادها إلى Outlook، ثم اضغط مع الاستمرار على مفاتيحALT + F11 لفتح نافذةMicrosoft Visual Basic for Applications.

2. انقر علىInsert > Module، ثم الصق الكود التالي في نافذة الـ Module.

كود VBA: استيراد أعياد الميلاد إلى تقويم Outlook

Sub ImportBirthdaysToCalendar()
'Updateby ExtendOffice
Dim xWs As Excel.Worksheet
Dim xRng As Range
Dim xOlApp As Outlook.Application
Dim xCalendarFld As Outlook.Folder
Dim xAppointmentItem As Outlook.AppointmentItem
Dim xRecurrencePattern As Outlook.RecurrencePattern
Dim xRow As Integer
On Error Resume Next
Set xWs = ThisWorkbook.ActiveSheet
Set xRng = Application.InputBox("Please select the data range (only two columns):", "Kutools for Excel", , , , , , 8)
If xRng Is Nothing Then Exit Sub
If xRng.Columns.Count <> 2 Then
  MsgBox "You can only select two columns", vbOKOnly + vbCritical, "Kutools for Excel"
  Exit Sub
End If
Set xOlApp = CreateObject("Outlook.Application")
Set xCalendarFld = xOlApp.Session.GetDefaultFolder(olFolderCalendar)
For xRow = 1 To xRng.Rows.Count
  Set xAppointmentItem = xCalendarFld.Items.Add("IPM.Appointment")
  With xAppointmentItem
    .Subject = xRng.Cells(xRow, 1) & Chr(39) & "s Birthday"
    .AllDayEvent = True
    .Start = xRng.Cells(xRow, 2)
    Set xRecurrencePattern = .GetRecurrencePattern
    xRecurrencePattern.RecurrenceType = olRecursYearly
    .Save
  End With
Next
Set xWs = Nothing
Set xCalendarFld = Nothing
Set xOlApp = Nothing
End Sub

3. بينما لا تزال في نافذةMicrosoft Visual Basic for Applications، انقر علىTools > References. في مربع الحوار المنبثقReferences – VBAProject، حدد خيارMicrosoft Outlook 16.0 Object Library من قائمةAvailable References، كما هو موضح في لقطة الشاشة:

4. بعد ذلك، انقر علىOK لإغلاق مربع الحوار هذا. الآن، اضغط على مفتاحF5 لتشغيل هذا الكود، وسيظهر مربع تحذير يطلب منك تحديد عمودي الاسم وعيد الميلاد، كما هو موضح في لقطة الشاشة:

5. بعد ذلك، انقر على زرOK، وسيتم استيراد أعياد الميلاد دفعة واحدة إلى تقويم Outlook. يمكنك فتح Outlook لعرض النتيجة، كما هو موضح في لقطة الشاشة: