كيفية إضافة توقيعات مختلفة إلى حسابات بريد إلكتروني متعددة عند إنشاء بريد إلكتروني جديد في Outlook؟

Author: Amanda Li Last Modified: 2025-05-30

من البرنامج التعليمي: التوقيعات في البريد الإلكتروني في Outlook، يجب أن تعرف كيفية إنشاء توقيع في Outlook. ومع ذلك، بعد إنشاء توقيع جديد، سيتعين عليك إضافة التوقيع الذي تم إنشاؤه يدويًا إلى رسالة جديدة عن طريق تحديد التوقيع > التوقيع الذي تم إنشاؤه في نافذة الرسالة.

بالطبع يمكنك جعل Outlook يضيف توقيعًا تلقائيًا عند إنشاء رسالة جديدة عن طريق النقر على التوقيع > التوقيعات، واختيار توقيع لحساب بريد إلكتروني محدد كما هو موضح أدناه.

steps of adding different signatures to multiple email accounts when create a new email in Outlook

ومع ذلك، ماذا لو كان لديك العديد من حسابات البريد الإلكتروني وتريد إضافة توقيعات مختلفة لحساباتك المتعددة دفعة واحدة؟ في هذا البرنامج التعليمي، سأقدم طريقة VBA لمساعدتك على إنجاز هذه المهمة بسهولة.

إضافة توقيعات مختلفة إلى حسابات بريد إلكتروني متعددة عند إنشاء بريد إلكتروني جديد في Outlook

1. في Outlook الخاص بك، اضغط على مفتاح Alt + F11 لفتح نافذة Microsoft Visual Basic for Applications.

2. في نافذة Microsoft Visual Basic for Applications، انقر نقرًا مزدوجًا على ThisOutlookSession في الجزء Project، وانسخ الكود VBA أدناه في نافذة ThisOutlookSession (Code). انظر لقطة الشاشة:

كود VBA: إضافة توقيعات مختلفة إلى حسابات بريد إلكتروني متعددة عند إنشاء بريد إلكتروني جديد في Outlook - ThisOutlookSession

Public WithEvents GInspectors As Inspectors
Public WithEvents GExplorer As Explorer

Private Sub Application_Startup()
  Set GInspectors = Application.Inspectors
  Set GExplorer = Application.ActiveExplorer
End Sub

Private Sub GExplorer_InlineResponse(ByVal Item As Object)
‘Update by ExtendOffice
Dim xMail As MailItem
On Error Resume Next
EndTimer
If Item.Class = olMail Then
  Set xMail = Item
  Set GInspector = Nothing
  Set GInspector = xMail.GetInspector
  StartTimer
End If
End Sub

Private Sub GInspectors_NewInspector(ByVal Inspector As Inspector)
  On Error Resume Next
  EndTimer
  Set GInspector = Nothing
  Set GInspector = Inspector
  StartTimer
End Sub

3. في نافذة Microsoft Visual Basic for Applications، انقر على إدراج > وحدة. ثم انسخ الكود VBA التالي إلى نافذة الوحدة.

كود VBA: إضافة توقيعات مختلفة إلى حسابات بريد إلكتروني متعددة عند إنشاء بريد إلكتروني جديد في Outlook - وحدة

Public Declare PtrSafe Function SetTimer Lib "user32" (ByVal HWnd As Long, ByVal nIDEvent As Long, ByVal uElapse As Long, ByVal lpTimerFunc As LongPtr) As Long
Public Declare PtrSafe Function KillTimer Lib "user32" (ByVal HWnd As Long, ByVal nIDEvent As Long) As Long
Public TimerID As Long
Public GInspector As Inspector

Sub StartTimer()
  On Error Resume Next
  TimerID = SetTimer(0&, 0&, 1000&, AddressOf TimerProc)
End Sub

Sub EndTimer()
  On Error Resume Next
  KillTimer 0&, TimerID
End Sub

Sub TimerProc(ByVal HWnd As Long, ByVal uMsg As Long, ByVal nIDEvent As Long, ByVal dwTimer As Long)
  On Error Resume Next
  Call SetSignatureToAccount
  EndTimer
End Sub

Sub SetSignatureToAccount()
‘Update by ExtendOffice
Dim xMail As MailItem
Dim xSignatureFile, xSignaturePath As String
Dim xSubject As String
Dim xDoc As Document
Dim xAccount As Account
Dim xIsNew As Boolean
Dim xInspector As Inspector
Const PR_SMTP_ADDRESS As String = "http://schemas.microsoft.com/mapi/proptag/0x39FE001E"
On Error Resume Next
xSignaturePath = CreateObject("WScript.Shell").SpecialFolders(5) + "\Microsoft\Signatures\"
xSubject = GInspector.Caption
Set xDoc = GInspector.WordEditor
xIsNew = False
Set xMail = GInspector.CurrentItem
Select Case xMail.Parent.Parent
  Case "name1@example.com" 'Replace the email address in double quotes
    If VBA.InStr(xSubject, "RE: ") = 1 Then
      Exit Sub
    ElseIf VBA.InStr(xSubject, "FW: ") = 1 Then
      Exit Sub
    Else
      xSignatureFile = xSignaturePath & "Signature1.htm" 'Replace "Signature1" with your actual signature name
      xIsNew = True
    End If
  Case "name2@example.com" 'Replace the email address in double quotes
    If VBA.InStr(xSubject, "RE: ") Then
      Exit Sub
    ElseIf VBA.InStr(xSubject, "FW: ") Then
      Exit Sub
    Else
      xSignatureFile = xSignaturePath & "Signature2.htm" 'Replace "Signature2" with your actual signature name
      xIsNew = True
    End If
  'Add more Cases for more email accounts
End Select
If xIsNew = True Then
  With xDoc.Application.Selection
    .WholeStory
    .EndKey
    .InsertParagraphAfter
    .MoveDown Unit:=wdLine, Count:=1
    .InsertFile FileName:=xSignatureFile, Link:=False, Attachment:=False
  End With
Else
  With xDoc.Application.Selection
    .MoveRight Unit:=wdCharacter, Count:=1
    .HomeKey Emptyparam, Emptyparam
    .InsertFile FileName:=xSignatureFile, Link:=False, Attachment:=False
  End With
End If
Set xDoc = Nothing
Set GInspector = Nothing
Set xMail = Nothing
End Sub

ملاحظة:

1) يجب استبدال name1@example.com وname2@example.com في الصفوف 39 و48 بعناوين بريدك الإلكتروني الفعلية.
2) يجب استبدال Signature1 وSignature2 في الصفوف 45 و54 بأسماء التوقيعات الفعلية الخاصة بك.
3) باستخدام كود VBA أعلاه، يمكننا إضافة توقيعات إلى حسابي بريد إلكتروني. إذا كان لديك المزيد من الحسابات، استبدل الصف 57 من الكود بالمزيد من الحالات:

حالة "name@example.com"
إذا كانت VBA.InStr(xSubject, "RE: ") = 1 إذن
خروج فرعي
وإلا إذا كانت VBA.InStr(xSubject, "FW: ") = 1 إذن
خروج فرعي
وإلا
xSignatureFile = xSignaturePath & "Signature.htm"
xIsNew = True
نهاية إذا

4. في نافذة Microsoft Visual Basic for Applications، انقر على أدوات > مراجع، وتحقق من المربع بجانب مكتبة كائنات Microsoft Word 16.0، واضغط على موافق.

5. أعد تشغيل Outlook، واحفظ أكواد VBA.

6. الآن، عندما تقوم بإنشاء رسالة جديدة باستخدام حساب بريد إلكتروني قمت بإعداد توقيع له، سيتم إضافة التوقيع المقابل تلقائيًا.

ملاحظة: إذا وجدت أنه تم إضافة توقيعين عند إنشاء رسالة جديدة باستخدام حساب بريد إلكتروني، يرجى النقر على التوقيع > التوقيعات في نافذة الرسالة. في قسم اختيار التوقيع الافتراضي، حدد حساب البريد الإلكتروني الذي يحتوي على توقيعين، واختر (لا شيء) من قائمة القائمة المنسدلة للرسائل الجديدة.