كيف يمكن تحويل مستندات Word دفعةً واحدة إلى ملف نصي (TXT)؟

تتناول هذه المقالة كيفية تحويل جميع مستندات Word الموجودة في مجلد معيّن دفعةً واحدة إلى ملفات نصية (TXT) منفصلة باستخدام Word.

تحويل مستندات Word دفعةً واحدة إلى ملف TXT باستخدام VBA

---

تحويل مستندات Word دفعةً واحدة إلى ملف TXT باستخدام VBA

يمكنك استخدام كود VBA أدناه لتحويل جميع مستندات Word الموجودة في مجلد معيّن إلى ملفات TXT دفعة واحدة. يُرجى اتباع الخطوات التالية:

1. في مستند Word، اضغط على مفاتيحAlt+F11 لفتح نافذةMicrosoft Visual Basic for Applications.

2. في نافذةMicrosoft Visual Basic for Applications، انقر علىInsert > Module، ثم انسخ الكود أدناه إلى نافذة الـ Module.

كود VBA: تحويل مستندات Word دفعةً واحدة إلى ملف TXT

Sub ConvertDocumentsToTxt()
'Updated by Extendoffice 20181123
    Dim xIndex As Long
    Dim xFolder As Variant
    Dim xFileStr As String
    Dim xFilePath As String
    Dim xDlg As FileDialog
    Dim xActPath As String
    Dim xDoc As Document
    Application.ScreenUpdating = False
    Set xDlg = Application.FileDialog(msoFileDialogFolderPicker)
    If xDlg.Show <> -1 Then Exit Sub
    xFolder = xDlg.SelectedItems(1)
    xFileStr = Dir(xFolder & "\*.doc")
    xActPath = ActiveDocument.Path
    While xFileStr <> ""
        xFilePath = xFolder & "\" & xFileStr
        If xFilePath <> xActPath Then
            Set xDoc = Documents.Open(xFilePath, AddToRecentFiles:=False, Visible:=False)
            xIndex = InStrRev(xFilePath, ".")
            Debug.Print Left(xFilePath, xIndex - 1) & ".txt"
            xDoc.SaveAs Left(xFilePath, xIndex - 1) & ".txt", FileFormat:=wdFormatText, AddToRecentFiles:=False
            xDoc.Close True
        End If
        xFileStr = Dir()
    Wend
    Application.ScreenUpdating = True
End Sub

3. اضغط على مفتاحF5 لتشغيل الكود.

4. في نافذةBrowse، حدد المجلد الذي يحتوي على مستندات Word التي تريد تحويلها إلى ملف TXT، ثم انقر على زرOK. راجع لقطة الشاشة:

بعد ذلك، ستلاحظ أن جميع المستندات في المجلد المحدد قد تم تحويلها دفعةً واحدة إلى ملفات TXT. راجع لقطة الشاشة: