الحصول على أول قيمة غير فارغة في عمود أو صف

للحصول على أول قيمة (أول خلية ليست فارغة، مع تجاهل الأخطاء) من نطاق يحتوي على عمود واحد أو صف واحد، يمكنك استخدام صيغة تستند إلى دالتي INDEX وMATCH. ومع ذلك، إذا كنت لا تريد تجاهل الأخطاء من النطاق الخاص بك، يمكنك إضافة دالة ISBLANK إلى الصيغة أعلاه.

الحصول على أول قيمة غير فارغة في عمود أو صف مع تجاهل الأخطاء
الحصول على أول قيمة غير فارغة في عمود أو صف بما في ذلك الأخطاء

الحصول على أول قيمة غير فارغة في عمود أو صف مع تجاهل الأخطاء

للحصول على أول قيمة غير فارغة في القائمة كما هو موضح أعلاه مع تجاهل الأخطاء، يمكنك استخدام دالة INDEX داخل دالة MATCH "INDEX((range<>0),0)" للعثور على الخلايا التي ليست فارغة. وبعد ذلك استخدم دالة MATCH لتحديد موقع أول خلية غير فارغة. سيتم بعد ذلك تمرير الموقع إلى الدالة INDEX الخارجية لاسترداد القيمة في هذا الموقع.

الصيغة العامة

=INDEX(range,MATCH(TRUE,INDEX((range<>0),0),0))

للحصول على أول قيمة غير فارغة في القائمة مع تجاهل الأخطاء، يرجى نسخ الصيغة أدناه أو إدخالها في الخلية E4، ثم الضغط على Enter للحصول على النتيجة:

=INDEX(B4:B15,MATCH(TRUE,INDEX((B4:B15<>0),0),0))

شرح الصيغة

=INDEX(B4:B15,MATCH(TRUE,INDEX((B4:B15<>0),0),0))

• INDEX((B4:B15<>0),0) : هذه الشريحة تقوم بتقييم كل قيمة في النطاق B4:B15. إذا كانت الخلية فارغة، ستعيد FALSE؛ إذا كانت الخلية تحتوي على خطأ، ستعيد الشريحة الخطأ نفسه؛ وإذا كانت الخلية تحتوي على رقم أو نص، ستعيد TRUE. وبما أن وسيطة row_num لهذه الصيغة INDEX هي 0، فإن الشريحة ستعيد مجموعة القيم الخاصة بالعمود بالكامل مثل هذا: {FALSE;#REF!;TRUE;TRUE;FALSE;FALSE;TRUE;FALSE;TRUE;TRUE;FALSE;TRUE}.
• MATCH(TRUE,MATCH(TRUE,INDEX((B4:B15<>0),0),0),0) = MATCH(TRUE,MATCH(TRUE,{FALSE;#REF!;TRUE;TRUE;FALSE;FALSE;TRUE;FALSE;TRUE;TRUE;FALSE;TRUE},0),0): تُجبر match_type 0 دالة MATCH على إرجاع موقع أول TRUE دقيق في المصفوفة. لذلك، ستعيد الدالة 3.
• INDEX(B4:B15,MATCH(TRUE,INDEX((B4:B15<>0),0),0)) = INDEX(B4:B15,3): بعد ذلك تعيد دالة INDEX القيمة الثالثة في النطاق B4:B15، وهي extendoffice.

الحصول على أول قيمة غير فارغة في عمود أو صف بما في ذلك الأخطاء

للحصول على أول قيمة غير فارغة في القائمة بما في ذلك الأخطاء، يمكنك ببساطة استخدام دالة ISBLANK للتحقق مما إذا كانت الخلايا في القائمة فارغة أم لا. بعد ذلك ستقوم INDEX بإرجاع أول قيمة غير فارغة بناءً على الموقع الذي قدمته MATCH.

الصيغة العامة

=INDEX(range,MATCH(FALSE,ISBLANK(range),0))

√ ملاحظة: هذه صيغة صفيف تتطلب منك الإدخال باستخدام Ctrl + Shift + Enter، باستثناء Excel 365 وExcel 2021.

للحصول على أول قيمة غير فارغة في القائمة بما في ذلك الأخطاء، يرجى نسخ الصيغة أدناه أو إدخالها في الخلية E7، والضغط على Ctrl + Shift + Enter للحصول على النتيجة:

=INDEX(B4:B15,MATCH(FALSE,ISBLANK(B4:B15),0))

شرح الصيغة

=INDEX(B4:B15,MATCH(FALSE,ISBLANK(B4:B15),0))

• ISBLANK(B4:B15): تقوم دالة ISBLANK بالتحقق مما إذا كانت الخلايا في النطاق B4:B15 فارغة أم لا. إذا كانت كذلك، ستعيد TRUE؛ وإذا لم تكن كذلك، ستعيد FALSE. لذلك، ستولد الدالة مصفوفة كالتالي: {TRUE;FALSE;FALSE;FALSE;TRUE;TRUE;FALSE;TRUE;FALSE;FALSE;TRUE;FALSE}.
• MATCH(FALSE,MATCH(FALSE, ISBLANK(B4:B15) ,0),0) = MATCH(FALSE,MATCH(FALSE, {TRUE;FALSE;FALSE;FALSE;TRUE;TRUE;FALSE;TRUE;FALSE;FALSE;TRUE;FALSE} ,0),0) : تُجبر match_type 0 دالة MATCH على إرجاع موقع أول FALSE دقيق في المصفوفة. لذلك، ستعيد الدالة 2.
• INDEX(B4:B15,MATCH(FALSE,ISBLANK(B4:B15),0)) = INDEX(B4:B15,2): بعد ذلك تعيد دالة INDEX القيمة الثانية في النطاق B4:B15، وهي #REF!.

الدوال ذات الصلة

الصيغ ذات الصلة