فصل سلسلة النص عند حرف معيّن في خلية في Excel

يشرح هذا البرنامج التعليمي كيفية فصل سلسلة نصية عند حرف معيّن إلى أعمدة منفصلة في Excel.

كيف تفصل سلسلة نصية عند حرف معيّن داخل خلية في Excel؟

افترض أن لديك قائمة من السلاسل النصية في العمود B، كما في لقطة الشاشة أدناه، وترغب في فصل كل نص عند الحرف "-" ليظهر في ثلاثة أعمدة منفصلة. في هذه الحالة، ستساعدك الصيغ التالية.

الصيغ العامة

الصيغة العامة لفصل النص الأيسر

=LEFT(text_string,FIND(«Char», text_string)-1)

الصيغة العامة لفصل النص الأوسط

=MID(text_string, FIND(«Char», text_string) + 1, FIND(«Char», text_string,FIND(«Char», text_string)+1) - FIND(«Char», text_string) - 1)

الصيغة العامة لفصل النص الأيمن

=RIGHT(text_string,LEN(text_string) - FIND(«Char», text_string, FIND(«Char», text_string) + 1))

معالم الصيغ أعلاه

كيف يمكنك استخدام هذه الصيغ؟

أولاً، افصل سلسلة النص الأولى بناءً على حرف معيّن

1. حدد خلية فارغة لإظهار النتيجة—لقد اخترتُ هنا الخلية C3.

2. أدخل الصيغة التالية، ثم اضغط على مفتاحEnter، واسحب الخلية التي تحتوي على صيغة LEFT حتى نهاية الخلايا الأخرى لتطبيقها عليها.

=LEFT(B3,FIND("-",B3)-1)

ثانيًا، افصل سلسلة النص الأوسط بناءً على حرف معيّن

1. حدد خلية فارغة، مثل D3، لعرض النتيجة.

2. أدخل الصيغة التالية، ثم اضغط على مفتاحEnter. بعد ذلك، حدد خلية النتيجة واسحب مقبض التعبئة لأسفل لتطبيق الصيغة على الخلايا الأخرى.

=MID(B3, FIND("-",B3) + 1, FIND("-",B3,FIND("-",B3)+1) - FIND("-",B3) - 1)

أخيرًا، افصل سلسلة النص الأخيرة بناءً على حرف معيّن

1. حدد خلية فارغة مثل E3 لعرض النتيجة.

2. أدخل الصيغة التالية، ثم اضغط على مفتاحEnter. بعد ذلك، حدد خلية النتيجة واسحب مقبض التعبئة لأسفل لتطبيق الصيغة على الخلايا الأخرى.

=RIGHT(B3,LEN(B3) - FIND("-", B3, FIND("-", B3) + 1))

لقد تم الآن فصل سلسلة النص في كل خلية من العمود B إلى ثلاثة أجزاء.

نصائح: إذا كنت تريد فصل سلسلة نصية إلى جزأين فقط بناءً على حرف معيّن، فبعد استخدام صيغة LEFT أعلاه لاستخراج الجزء الأول، يمكنك تطبيق صيغة RIGHT التالية لاستخراج الجزء الثاني، كما هو موضح في لقطة الشاشة أدناه.

=RIGHT(B3,LEN(B3)-FIND("-",B3))

كيف تعمل هذه الصيغ؟

=LEFT(B3,FIND("-",B3)-1)

• FIND("-",B3)تُرجع دالة FIND الموقع الابتدائي للحرف "-" في سلسلة النص "KTE-Jan-359"، لتكون النتيجة 4.
• LEFT(B3,4-1): تستخرج دالة LEFT أول 3 أحرف (4−1=3) من الجهة اليسرى لسلسلة النص KTE-Jan-359، لتكون النتيجة هنا KTE.
  ملاحظة: نظرًا لأن أول حرف "-" يظهر في الموقع الرابع من سلسلة النص، فإنك تحتاج إلى طرح 1 لاستبعاده من الاستخراج.

=MID(B3, FIND("-",B3) + 1, FIND("-",B3,FIND("-",B3)+1) - FIND("-",B3) - 1)

• FIND("-",B3) + 1: تُرجع دالة FIND الموقع الابتدائي للحرف "-" في سلسلة النص KTE-Jan-359، وتكون النتيجة هنا هي 4.
  ملاحظة: نظرًا لأن أول ظهور للحرف "-" يكون في الموقع الرابع من سلسلة النص، فإنك تحتاج إلى إضافة 1 إلى الرقم 4 لاستخراج النص الذي يليه، ليصبح الناتج النهائي 4+1=5.
• FIND("-",B3,FIND("-",B3)+1)كما هو موضح أدناه: `FIND("-"، "KTE-Jan-359"، 4+1)` — تقوم دالة FIND بإيجاد موضع الحرف "-" بدءًا من الحرف الخامس في النص "KTE-Jan-359"، وتعيد النتيجة **8**.
• MID(B3, 5, 8 - 4 - 1)تعني الدالة MID(KTE-Jan-359،5،3) أن الدالة تستخرج 3 أحرف بدءًا من الحرف الخامس في النص "KTE-Jan-359"، لتُنتج الناتج «Jan».

=RIGHT(B3,LEN(B3) - FIND("-", B3, FIND("-", B3) + 1))

• LEN(B3)تحسب دالة LEN الطول الكلي لسلسلة النص "KTE-Jan-359" وتعيد النتيجة 11.
• FIND("-",B3,FIND("-",B3)+1)تقوم دالة FIND بالبحث عن موضع الحرف "-" بدءًا من الحرف الخامس في النص "KTE-Jan-359"، وتعيد النتيجة 8.
• RIGHT(B3,11 - 8))تستخرج دالة RIGHT 3 أحرف (11 ناقص 8) من الجهة اليمنى لـ KTE-Jan-359، والنتيجة هنا هي 359.

الدوال ذات الصلة

الصيغ ذات الصلة