Skip to main content

جمع القيم حسب رقم الأسبوع أو يوم الأسبوع في Excel

Author: Siluvia Last Modified: 2025-08-06

يوضح هذا البرنامج التعليمي الصيغ خطوة بخطوة لمساعدتك على جمع القيم ضمن نطاق معين بناءً على رقم الأسبوع المحدد أو يوم الأسبوع في Excel.

كيفية جمع القيم حسب رقم الأسبوع في Excel؟
كيفية جمع القيم حسب يوم الأسبوع في Excel؟

كيفية جمع القيم حسب رقم الأسبوع في Excel؟

كما هو موضح في لقطة الشاشة أدناه، لجمع القيم في عمود المبلغ استنادًا إلى التواريخ التي يقع فيها رقم أسبوع معين، نقدم صيغتين.

doc-sum-by-week-number-weekday-1

الصيغ العامة

=SUMIFS( value_range, helper_column_range, week_number)

=SUMPRODUCT(--(WEEKNUM(date_range+0,1)=week_number),value_range)

الوسائط

Value_range: النطاق الذي تريد جمع القيم فيه بناءً على رقم الأسبوع؛
Helper_column_range: النطاق الذي تم استخراج أرقام الأسابيع منه من التاريخ؛
Week_number: رقم الأسبوع المستخدم كمعيار لتجميع القيم.

كيفية استخدام هذه الصيغة؟

استخدام صيغة SUMIFS وعمود المساعدة

للاستخدام صيغة SUMIFS، يجب عليك أولاً تطبيق دالة WEEKNUM لإنشاء عمود مساعد لحساب أرقام الأسابيع المقابلة للتواريخ في عمود التاريخ.

=WEEKNUM (serial_num, [return_type])

تقوم دالة WEEKNUM بإرجاع رقم الأسبوع للتاريخ المعطى في السنة.

1. في هذه الحالة، أختار خلية (F5) بجانب أول قيمة في عمود المبلغ.

2. أدخل الصيغة أدناه فيها واضغط على مفتاح Enter للحصول على رقم الأسبوع للتاريخ الأول. حدد الخلية الناتجة ثم اسحب مقبض التعبئة التلقائي لأسفل للحصول على أرقام الأسابيع الأخرى. انظر لقطة الشاشة:

=WEEKNUM(C5)

doc-sum-by-week-number-weekday-2

3. حدد خلية لإظهار المجموع الكلي، وأدخل الصيغة أدناه فيها واضغط على مفتاح Enter. حدد هذه الخلية الناتجة، واسحب مقبض التعبئة التلقائي لأسفل للحصول على النتائج الأخرى.

=SUMIFS($E$5:$E$14, $F$5:$F$14, H6)

doc-sum-by-week-number-weekday-3

استخدام صيغة SUMPRODUCT

لا تحتاج إلى إنشاء عمود مساعد عند استخدام صيغة SUMPRODUCT لحل هذه المشكلة.

1. حدد خلية فارغة، وأدخل الصيغة أدناه فيها واضغط على مفتاح Enter.

=SUMPRODUCT(--(WEEKNUM($C$5:$C$14+0,1)=G6),$E$5:$E$14)

2. حدد الخلية الناتجة، واسحب مقبض التعبئة التلقائي لأسفل للحصول على النتائج الأخرى حسب احتياجاتك.

doc-sum-by-week-number-weekday-4

شرح الصيغة

=SUMIFS($E$5:$E$14, $F$5:$F$14, H6)

بعد حساب أرقام الأسابيع باستخدام دالة WEEKNUM، تقوم دالة SUMIFS بتجميع القيم في النطاق E5:E14 إذا كانت أرقام الأسابيع في العمود المساعد F5:F14 تتطابق مع الأسبوع المحدد في H6.

=SUMPRODUCT(--(WEEKNUM($C$5:$C$14+0,1)=G6),$E$5:$E$14)

WEEKNUM($C$5:$C$14+0,1): تقوم دالة WEEKNUM بحساب كل رقم أسبوع للتواريخ في النطاق C5:C14، وتُرجع مصفوفة مثل هذه: {1;1;5;6;6;9;11;11;13;14};
{1;1;5;6;6;9;11;11;13;14}=G6: هنا يتم مقارنة كل رقم أسبوع في المصفوفة برقم الأسبوع المحدد في G6، ويتم إرجاع مصفوفة جديدة: {TRUE;TRUE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE};
--{TRUE;TRUE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE}: يقوم هذان الرمزان السالبان بتحويل “TRUE” و “FALSE” إلى 1s و 0s. هنا ستحصل على مصفوفة جديدة كالتالي: {1;1;0;0;0;0;0;0;0;0};
{1;1;0;0;0;0;0;0;0;0},{1428;2010;2288;1831;2069;1728;1325;1469;1023;1100}: يتم ضرب كل زوج من الإدخالات في المصفوفات معًا وإرجاع {1428;2010;0;0;0;0;0;0;0;0};
SUMPRODUCT({1428;2010;0;0;0;0;0;0;0;0}): تقوم دالة SUMPRODUCT بجمع جميع الأرقام في المصفوفة وتُرجع النتيجة النهائية 1428+2010=3438.

كيفية جمع القيم حسب يوم الأسبوع في Excel؟

كما هو موضح في لقطة الشاشة أدناه، لجمع القيم في عمود المبلغ حسب يوم الأسبوع المحدد في Excel، يمكنك تطبيق دالة SUMPRODUCT مع دالة WEEKDAY للقيام بذلك.

في هذه الحالة، بما أننا بحاجة إلى جمع المبلغ الإجمالي لكل يوم من أيام الأسبوع، قبل تطبيق الصيغة، نقوم بإنشاء عمود مساعد بالأرقام من 1 إلى 7 للإشارة إلى الاثنين حتى الأحد على التوالي.

doc-sum-by-week-number-weekday-6

الصيغة العامة

=SUMPRODUCT((WEEKDAY(date_range,2)=weekday_number)*value_range)

الوسائط

Date_range: نطاق التواريخ حيث تريد تقييم الأيام المحددة؛
Value_range: النطاق الذي تريد جمع القيم فيه بناءً على يوم الأسبوع؛
2: الرقم 2 يمثل الأرقام من 1 (الاثنين) إلى 7 (الأحد)؛
Weekday_number: رقم اليوم المستخدم كمعيار لتجميع القيم. يمكن أن يكون مرجع خلية أو رقم من 1 إلى 7.

كيفية استخدام هذه الصيغة؟

1. حدد خلية بجانب الخلية التي تحتوي على الرقم 1. هنا أختار I6.

2. انسخ أو أدخل الصيغة أدناه فيها واضغط على مفتاح Enter. حدد الخلية الناتجة، ثم اسحب مقبض التعبئة التلقائي لأسفل للحصول على النتائج لأيام الأسبوع الأخرى.

=SUMPRODUCT((WEEKDAY($C$5:$C$14,2)=H6)*$E$5:$E$14)

doc-sum-by-week-number-weekday-7

ملاحظة: إذا كنت بحاجة فقط إلى جمع القيم بناءً على يوم معين من أيام الأسبوع مثل الجمعة، يمكنك إدخال الرقم 5 مباشرة في الصيغة كما يلي.

=SUMPRODUCT((WEEKDAY($C$5:$C$14,2)=5)*$E$5:$E$14)

شرح الصيغة

=SUMPRODUCT((WEEKDAY($C$5:$C$14,2)=H6)*$E$5:$E$14)

WEEKDAY($C$5:$C$14,2): تقوم دالة WEEKDAY بإرجاع أرقام صحيحة من 1 إلى 7 لتمثيل أيام الأسبوع من الاثنين إلى الأحد في النطاق C5:C14: {5;7;1;3;6;7;1;5;5;6};
{5;7;1;3;6;7;1;5;5;6}=H6: هنا يتم مقارنة كل يوم من أيام الأسبوع في المصفوفة برقم اليوم المحدد في H6، ويتم إرجاع مصفوفة جديدة: {FALSE;FALSE;TRUE;FALSE;FALSE;FALSE;TRUE;FALSE;FALSE;FALSE};
{FALSE;FALSE;TRUE;FALSE;FALSE;FALSE;TRUE;FALSE;FALSE;FALSE}*$E$5:$E$14: هنا يتم تحويل TRUE و FALSE إلى 1s و 0s، ثم يتم ضربها في القيم الموجودة في E5:E14 لإرجاع المصفوفة: {0;0;2288;0;0;0;1325;0;0;0};
SUMPRODUCT{0;0;2288;0;0;0;1325;0;0;0}: تقوم دالة SUMPRODUCT بجمع جميع الأرقام في المصفوفة وتُرجع النتيجة النهائية 2288+1325=3613.

الوظائف ذات الصلة

دالة WEEKNUM في Excel
تقوم دالة SUMIFS في Excel بإرجاع رقم الأسبوع للتاريخ المعطى في السنة، والتي تبدأ في عد الأسابيع من 1 يناير.

دالة SUMPRODUCT في Excel
يمكن استخدام دالة SUMPRODUCT في Excel لضرب عمودين أو أكثر أو صفيفين معًا، ثم الحصول على مجموع المنتجات.

دالة WEEKDAY في Excel
تقوم دالة EOMONTH في Excel بإرجاع عدد صحيح من 1 إلى 7 لتمثيل يوم الأسبوع للتاريخ المحدد في Excel.

الصيغ ذات الصلة

جمع القيم حسب الشهر (مع أو بدون السنة)
يوضح هذا البرنامج التعليمي صيغتين بالتفصيل لمساعدة جمع القيم حسب الشهر والسنة أو جمع القيم حسب الشهر مع تجاهل السنة في Excel.

جمع القيم حسب الأسبوع لتاريخ معين
يتحدث هذا البرنامج التعليمي عن كيفية جمع القيم حسب الأسبوع الذي يقع فيه تاريخ معين.

جمع كل n صف أو عمود في نطاق
يشرح هذا البرنامج التعليمي صيغتين تعتمدان على دالتي SUM و OFFSET لجمع كل n صف أو عمود في نطاق محدد في Excel.

جمع كل الصفوف أو الأعمدة nth في نطاق
يوضح لك هذا البرنامج التعليمي كيفية إنشاء صيغة تعتمد على دوال SUMPRODUCT و MOD و COLUMN لجمع كل الصفوف أو الأعمدة nth في نطاق في Excel.

أفضل أدوات إنتاجية للمكتب

Kutools لـ Excel - يساعدك على التميز عن الآخرين

🤖 مساعد Kutools AI: ثورة في تحليل البيانات بناءً على: تنفيذ ذكي   |  توليد الكود  |  إنشاء صيغ مخصصة  |  تحليل البيانات وإنشاء الرسوم البيانية  |  استدعاء وظائف Kutools…
الوظائف الشائعة: البحث، تمييز أو تحديد المكررات  |  حذف الصفوف الفارغة  |  دمج الأعمدة أو الخلايا دون فقدان البيانات  |  التقريب بدون صيغة ...
VLookup الفائق: معايير متعددة  |  قيم متعددة  |  عبر أوراق متعددة  |  مطابقة غامضة...
قائمة منسدلة متقدمة: قائمة منسدلة سهلة  |  قائمة منسدلة تعتمد على أخرى  |  قائمة منسدلة متعددة الخيارات...
مدير العمود: إضافة عدد معين من الأعمدة  |  نقل الأعمدة  |  تبديل حالة رؤية الأعمدة المخفية  |  مقارنة الأعمدة لتحديد نفس & الخلايا المختلفة ...
الميزات البارزة: التركيز على الشبكة  |  عرض التصميم  |  شريط الصيغ المحسن  |  إدارة المصنفات والأوراق | مكتبة النص التلقائي (النص التلقائي)  |  منتقي التاريخ  |  دمج بيانات الأوراق  |  تشفير/فك تشفير الخلايا  |  إرسال رسائل البريد الإلكتروني عبر القوائم  |  مرشح متقدم  |  تصفية خاصة (تصفية الخلايا بالخط العريض/المائل/المتوسط عليه خط...) ...
أفضل 15 مجموعة أدوات:  12 أداة نص (إضافة نص، حذف الأحرف ...)  |  50+ نوعاً من الرسوم البيانية (مخطط جانت ...)  |  40+ صيغة عملية (حساب العمر بناءً على تاريخ الميلاد ...)  |  19 أداة إدراج (إدراج رمز الاستجابة السريعة، إدراج صورة من المسار ...)  |  12 أداة تحويل (تحويل الأرقام إلى كلمات، تحويل العملة ...)  |  7 أدوات دمج وتقسيم (دمج متقدم للصفوف، تقسيم خلايا Excel ...)  |  ... والمزيد
استخدم Kutools بلغتك المفضلة – يدعم الإنجليزية، الإسبانية، الألمانية، الفرنسية، الصينية، وأكثر من 40 لغة أخرى!

Kutools لـ Excel يحتوي على أكثر من 300 ميزة، مما يضمن أن ما تحتاجه هو مجرد نقرة واحدة بعيدًا...

Office Tab - تمكين القراءة والتحرير باستخدام التبويبات في Microsoft Office (تتضمن Excel)

  • ثانية واحدة للتبديل بين العشرات من المستندات المفتوحة!
  • تقليل مئات النقرات بالماوس يوميًا، قل وداعًا لآلام اليد بسبب استخدام الماوس.
  • زيادة إنتاجيتك بنسبة 50% عند عرض وتحرير مستندات متعددة.
  • جلب التبويبات الفعالة إلى Office (تتضمن Excel)، تمامًا مثل Chrome و Edge و Firefox.