مجموع إذا كانت الخلايا تحتوي على أو تساوي x أو y في Excel

لتجميع الخلايا إذا كانت تحتوي على قيمة أو أخرى أو تساويها ، يوفر هذا البرنامج التعليمي صيغتين بالتفصيل للمساعدة في حل المشكلات.

كيفية جمع إذا كانت الخلايا تحتوي على إما x أو y في إكسيل؟
كيفية جمع إذا كانت الخلايا تساوي إما س أو ص في إكسيل؟

كيفية جمع إذا كانت الخلايا تحتوي على إما x أو y في إكسيل؟

كما هو موضح في لقطة الشاشة أدناه ، لتجميع الخلايا في العمود D إذا كانت الخلايا الموجودة في العمود C تحتوي إما على "تفاحة" أو "ليتشي" ، يمكنك تطبيق صيغة بناءً على وظائف SUMPRODUCT و ISNUMBER و SEARCH.

الصيغ العامة

=SUMPRODUCT(--((ISNUMBER(SEARCH("criteria1",rng1)) + ISNUMBER(SEARCH("criteria2",rng2)))>0),sum_rng)

الحجج

نطاق_المعايير 1: نطاق الخلايا الذي تريد تقييمه بواسطة criteria1 ؛

معايير_رانج 2: نطاق الخلايا الذي تريد تقييمه بواسطة criteria2 ؛

المعايير 1: المعايير المستخدمة لتحديد الخلايا في Criteria_rang1 التي سيتم إضافتها ؛

المعايير 2: المعايير المستخدمة لتحديد الخلايا في Criteria_rang2 التي سيتم إضافتها.

Sum_range: نطاق الخلايا المطلوب جمعها ؛

كيف تستخدم هذه الصيغة؟

حدد خلية فارغة ، وانسخ أو أدخل الصيغة أدناه واضغط على أدخل مفتاح للحصول على النتيجة.

=SUMPRODUCT(--((ISNUMBER(SEARCH(G4,C5:C12))+ISNUMBER(SEARCH(G5,C5:C12)))>0),D5:D12)

ملاحظة: في هذه الصيغة ، G4 و G5 هي الخلايا التي تحتوي على الشرطين. بدلاً من ذلك ، يمكنك كتابة القيم النصية الفعلية المحاطة بعلامات اقتباس مزدوجة مباشرةً.

=SUMPRODUCT(--((ISNUMBER(SEARCH("apple",C5:C12))+ISNUMBER(SEARCH("lychee",C5:C12)))>0),D5:D12)

شرح الصيغة

=SUMPRODUCT(--((ISNUMBER(SEARCH("apple",C5:C12))+ISNUMBER(SEARCH("lychee",C5:C12)))>0),D5:D12)

ISNUMBER (SEARCH ("apple"، C5: C12))

> SEARCH ("apple"، C5: C12): تحدد الدالة SEARCH موضع الحرف الأول من "apple" في كل خلية من النطاق C5: C12 ، وتُرجع مصفوفة مثل هذه {#VALUE!؛ # VALUE!؛ 1؛ 9؛ 1؛ #VALUE !؛ #VALUE! ؛ 18}. تعني قيمة #VALUE! أن "apple" غير موجود في الخلية المقابلة ؛

> ISNUMBER ({# VALUE!؛ # VALUE!؛ 1؛ 9؛ 1؛ #VALUE!؛ # VALUE!؛ 18}): هنا تتحقق الدالة ISNUMBER مما إذا كانت القيمة المشار إليها في المصفوفة رقمية أم غير رقمية. إذا كانت معلمة القيمة رقمية ، فإنها ترجع "TRUE" ، وإذا لم تكن كذلك ، فإنها ترجع "FALSE". ثم ستحصل على مصفوفة جديدة {FALSE؛ FALSE؛ TRUE؛ TRUE؛ TRUE؛ FALSE؛ FALSE؛ TRUE}.

ISNUMBER (SEARCH ("lychee"، C5: C12)): شرح هذا الجزء هو نفسه كما ورد أعلاه. هنا ، تُرجع الدالة ISNUMBER أخيرًا مصفوفة مثل هذه {FALSE؛ FALSE؛ FALSE؛ TRUE؛ FALSE؛ FALSE؛ TRUE؛ TRUE}؛

{FALSE؛ FALSE؛ TRUE؛ TRUE؛ TRUE؛ FALSE؛ FALSE؛ TRUE} + {FALSE؛ FALSE؛ FALSE؛ TRUE؛ FALSE؛ FALSE؛ TRUE؛ TRUE}: ثم نضيف هذه المصفوفات معًا ، وتحول العملية الرياضية قيم TRUE و FALSE إلى 1s و 0s. أخيرًا نحصل على مصفوفة رقمية {0؛ 0؛ 1؛ 2؛ 1؛ 0؛ 1؛ 2}؛

({0;0;1;2;1;0;1;2}) > 0: يقارن كل رقم في المصفوفة بالرقم 0 ، ويرجع مصفوفة صواب وخطأ مثل هذا {FALSE؛ FALSE؛ TRUE؛ TRUE؛ TRUE؛ FALSE؛ TRUE؛ TRUE}؛

- ({FALSE؛ FALSE؛ TRUE؛ TRUE؛ TRUE؛ FALSE؛ TRUE؛ TRUE}): هاتان العلامتان الناقصتان تقومان بتحويل "TRUE" إلى 1 وتحويل "FALSE" إلى 0. هنا ستحصل على مصفوفة جديدة مثل {0؛ 0؛ 1؛ 1؛ 1؛ 0؛ 1؛ 1}؛

SUMPRODUCT({0;0;1;1;1;0;1;1},D5:D12) = SUMPRODUCT({0;0;1;1;1;0;1;1},{2000;1600;980;1200;600;900;150;300}): تضرب الدالة SUMPRODUCT المكونات المقابلة للمصفوفين وتُرجع المصفوفة كـ {0 ؛ 0 ؛ 980 ؛ 1200 ؛ 600 ؛ 0 ؛ 150 ؛ 300} ، ثم تجمع كل النتائج في المصفوفة وتُرجع أخيرًا 3230.

كيفية جمع إذا كانت الخلايا تساوي إما س أو ص في إكسيل؟

في القسم أعلاه ، قدمنا الصيغة لتجميع الخلايا إذا كانت تحتوي على قيمة واحدة أو أخرى. سيوضح هذا القسم كيفية إضافة وظيفتين SUMIF معًا لجمع الخلايا إذا كانت تساوي x أو y.

المثال أدناه هو جمع المبيعات إذا كان المنتج يساوي "تفاحة" أو "ليتشي".

صيغة عامة

=SUMIF(criteria_range1,"criteria1",sum_range)+SUMIF(criteria_range2,"criteria2",sum_range)

الحجج

نطاق_المعايير 1: نطاق الخلايا الذي تريد تقييمه بواسطة criteria1 ؛

معايير_رانج 2: نطاق الخلايا الذي تريد تقييمه بواسطة criteria2 ؛

المعايير 1: المعايير التي تحدد الخلايا في Criteria_rang1 التي سيتم إضافتها.

المعايير 2: المعايير التي تحدد الخلايا في Criteria_rang2 التي سيتم إضافتها.

Sum_range: نطاق الخلايا المطلوب جمعها ؛

كيف تستخدم هذه الصيغة؟

حدد خلية فارغة ، وانسخ أو أدخل الصيغة أدناه فيها واضغط على أدخل مفتاح للحصول على النتيجة.

=SUMIF(C5:C12,G4,D5:D12)+SUMIF(C5:C12,G5,D5:D12)

ملاحظة: تشير هذه الصيغة إلى خليتين G4 و G5 تحتويان على الشرطين. يمكنك كتابة القيم النصية مباشرةً داخل علامات اقتباس مزدوجة كمعايير في الصيغة.

=SUMIF(C5:C12,"apple",D5:D12)+SUMIF(C5:C12,"lychee",D5:D12)

شرح هذه الصيغة

=SUMIF(C5:C12,"apple",D5:D12)+SUMIF(C5:C12,"lychee",D5:D12)

تجمع الدالة SUMIF الأولى مبيعات "apple" ، بينما تجمع الدالة SUMIF الثانية مبيعات "lychee". ثم تضاف هاتان النتيجتان معًا للحصول على إجمالي المبيعات.

وظائف ذات الصلة

وظيفة Excel SUMPRODUCT
يمكن استخدام الدالة Excel SUMPRODUCT لمضاعفة عمودين أو أكثر من المصفوفات معًا ، ثم الحصول على مجموع المنتجات.

وظيفة Excel ISNUMBER
ترجع الدالة Excel ISNUMBER القيمة TRUE عندما تحتوي الخلية على رقم ، وتعيد FALSE إذا لم تكن كذلك.

وظيفة Excel SEARCH
يمكن أن تساعدك وظيفة Excel SEARCH في العثور على موضع حرف معين أو سلسلة فرعية من السلسلة النصية المحددة

وظيفة Excel SUMIFS
يمكن أن تساعد وظيفة Excel SUMIF في جمع قيم الخلايا بناءً على معايير متعددة.

الصيغ ذات الصلة

مجموع إذا كانت الخلايا تحتوي على علامة النجمة
لتجميع الخلايا التي تحتوي على علامة النجمة والتي تعتبر حرفًا حرفيًا وليس حرف بدل ، يشرح هذا البرنامج التعليمي صيغة تستند إلى وظيفة SUMIF والتيلدا (~).

مجموع إذا كانت الخلايا تحتوي على كل من x و y
يوضح هذا البرنامج التعليمي خطوة بخطوة كيفية جمع نطاق من الخلايا إذا كانت الخلايا المقابلة تحتوي على كل من x و y باستخدام وظيفة SUMIFS.

مجموع إذا كان التاريخ بين تاريخين
يوضح هذا البرنامج التعليمي كيفية جمع القيم ضمن نطاق تاريخ معين في Excel باستخدام صيغة تستند إلى دالة SUMIFS.

مجموع إذا كانت الخلايا تساوي أو لا تساوي قيمة معينة
يشرح هذا البرنامج التعليمي خطوة بخطوة صيغتين لتلخيص نطاق من الخلايا يساوي أو لا يساوي قيمة معينة بناءً على دالة SUMIF.

أفضل أدوات إنتاجية المكتب

كوتولس ل إكسيل - يساعدك على التميز من بين الحشود

هل ترغب في إكمال عملك اليومي بسرعة وبشكل مثالي؟ يوفر Kutools for Excel 300 ميزة متقدمة قوية (الجمع بين المصنفات ، والجمع حسب اللون ، ومحتويات الخلية المنقسمة ، وتحويل التاريخ ، وما إلى ذلك ...) وتوفير 80 ٪ من الوقت لك.

مصمم لسيناريوهات عمل 1500 ، يساعدك على حل 80٪ من مشاكل Excel.
قلل الآلاف من نقرات لوحة المفاتيح والماوس كل يوم ، وقم بإراحة عينيك ويديك المتعبة.
كن خبيرًا في برنامج Excel في 3 دقائق. لم تعد بحاجة إلى تذكر أي صيغ مؤلمة ورموز VBA.
نسخة تجريبية مجانية غير محدودة لمدة 30 يومًا. ضمان استرداد الأموال لمدة 60 يومًا. ترقية مجانية ودعم لمدة عامين.

التفاصيل تحميل

علامة تبويب Office - تمكين القراءة والتحرير المبوب في Microsoft Office (بما في ذلك Excel)

ثانية واحدة للتبديل بين عشرات المستندات المفتوحة!
قلل مئات النقرات بالماوس كل يوم ، وداعًا ليد الماوس.
يزيد من إنتاجيتك بنسبة 50٪ عند عرض مستندات متعددة وتحريرها.
يجلب علامات التبويب الفعالة إلى Office (بما في ذلك Excel) ، تمامًا مثل Chrome و Firefox و Internet Explorer الجديد.

لقطة شاشة لبرنامج Excel (مع تثبيت Office Tab)

التفاصيل تحميل

التعليقات (0)

لا يوجد تقييم. كن أول من يقيم!

لا توجد تعليقات منشورة هنا حتى الآن

اترك تعليقاتك

النشر كضيف

الدخول

الاسم (مطلوب)

البريد الإلكتروني (مطلوب)

قيم المنشور:

إعادة تعيين

0 الشخصيات

أنا أوافق على أحكام وشروط