دالة Excel CHOOSE

الوصف

بناء الجملة والوسائط

الاستخدام والأمثلة

• المثال 1 - الاستخدام الأساسي: استخدام دالةCHOOSE بمفردها لاختيار قيمة من وسيط القائمة
• المثال 2 – إرجاع نتائج مختلفة استنادًا إلى شروط متعددة
• المثال 3 – إرجاع نتائج محسوبة مختلفة استنادًا إلى الشروط
• المثال 4 – الاختيار العشوائي من قائمة
• المثال 5 – دمج دالتَيCHOOSE وVLOOKUP لـ قيمة العودة في أقصى عمود على اليسار
• المثال 6 – إرجاع يوم الأسبوع أو الشهر استنادًا إلى تاريخ معين
• المثال 7 – إرجاع تاريخ يوم العمل أو عطلة نهاية الأسبوع التالية استنادًا إلى اليوم الحالي

---

الوصف

تُرجع دالةCHOOSE قيمة من قائمة وسائط القيم استنادًا إلى رقم الفهرس المُعطى. على سبيل المثال، تُرجعCHOOSE(3,”Apple”,”Peach”,”Orange”) «البرتقال»، لأن رقم الفهرس هو 3، والبرتقال هو القيمة الثالثة في القائمة.

بناء الجملة والوسائط

بناء جملة الصيغة

CHOOSE()index_num, value1, [value2], …)

الوسائط

Index_num: مطلوب. أدخل قيمة رقمية تتراوح بين 1 و254 لتحديد الوسيط الذي سيتم اختيار قيمته. إذا كانت قيمةindex_num خارج هذا النطاق، تُرجع الدالةCHOOSE خطأً من النوع#VALUE!وإذا كانت القيمة عشرية، فسيتم تقريبها لأسفل إلى أقرب عدد صحيح قبل إدخالها في الصيغة. Value1:مطلوبة. أول قيمة في الصيغة، ويمكنك اختيارها. Value2:اختياري. القيمة الثانية وحتى القيمة 254 المتاحة للاختيار منها.

Value1, value2... يمكن أن تكون أرقامًا أو نصوصًا أو صيغًا أو مراجع خلايا أو أسماء معرفة.

قيمة العودة

تُرجع دالةCHOOSE قيمة من القائمة بناءً على الموضع المحدد.

الاستخدام والأمثلة

في هذا الجزء، سأعرض بعض الأمثلة البسيطة ولكن المعبّرة لتوضيح استخدام دالةCHOOSE.

المثال 1 - الاستخدام الأساسي: استخدام دالةCHOOSE بمفردها لاختيار قيمة من وسيط القائمة

الصيغة 1:

=CHOOSE(3,«a»,«b»,«c»,«d»)

القيمة المرجعة: c، وهي الوسيط الثالث بعدCHOOSE عندما يكون index_num يساوي 3.

ملاحظة: استخدم علامتي اقتباس مزدوجتين حول القيمة إذا كانت نصًا.

الصيغة2:

=CHOOSE(2,A1,A2,A3,A4)

القيمة المرجعة: Kate، وهي قيمة الخلية A2. وبما أن index_num يساوي 2، فإن A2 تمثّل القيمة الثانية في الدالة.CHOOSE.

الصيغة3:

=CHOOSE(4,8,9,7,6)

القيمة المرجعة: 6، وهو وسيط القائمة الرابع في الدالة.

---

المثال 2 – إرجاع نتائج مختلفة استنادًا إلى شروط متعددة

افترض أن لديك قائمة بالانحرافات لكل منتج والتي يجب تصنيفها استنادًا إلى شروط كما هو موضح في لقطة الشاشة أدناه.

عادةً، يمكنك استخدام دالة IF للتعامل مع ذلك، لكنني سأريك هنا كيف تستخدم دالةCHOOSE لحل هذه المشكلة بسهولة!

الصيغة:

=CHOOSE((B7>0)+(B7>1)+(B7>5),«Top»,«Middle»,«Bottom»)

الشرح:

(B7>0)+(B7>1)+(B7>5):رقم الفهرس (index_num)، B7 يساوي 2، وهو أكبر من 0 و1 وأقل من 5، لذا نحصل على النتيجة المتوسطة التالية:

=CHOOSE(True+Ture+False,«Top»,«Middle»,«Bottom»)

كما نعلم، True = 1، False = 0، لذا يمكن اعتبار الصيغة كما يلي:

=CHOOSE(1+1+0,«Top»,«Middle»,«Bottom»)

ثم

=CHOOSE(2,«Top»,«Middle»,«Bottom»)

النتيجة: متوسط

---

المثال 3 – إرجاع نتائج محسوبة مختلفة استنادًا إلى الشروط

افترض أنك بحاجة إلى حساب الخصومات لكل منتج استنادًا إلى الكمية والسعر كما هو موضح في لقطة الشاشة أدناه:

الصيغة:

=CHOOSE((B8>0)+(B8>100)+(B8>200)+(B8>300),B8*C8*0.1,B8*C8*0.2,B8*C8*0.3,B8*C8*0.5)

الشرح:

(B8>0)+(B8>100)+(B8>200)+(B8>300):رقم الفهرس (index_number)، B8 يساوي 102، وهو أكبر من 100 وأقل من 201، لذا في هذا الجزء، تكون النتيجة كما يلي:

=CHOOSE(true+true+false+false,B8*C8*0.1,B8*C8*0.2,B8*C8*0.3,B8*C8*0.5)

=CHOOSE(1+1+0+0,B8*C8*0.1,B8*C8*0.2,B8*C8*0.3,B8*C8*0.5)

ثم

=CHOOSE(2,B8*C8*0.1,B8*C8*0.2,B8*C8*0.3,B8*C8*0.5)

B8*C8*0.1,B8*C8*0.2,B8*C8*0.3,B8*C8*0.5:القيم التي يتم الاختيار منها، الخصم يساوي السعر × الكمية × نسبة الخصم، وبما أن index_num هنا هو 2، فإن الصيغة تختار B8*C8*0.2

النتائج: 102*2*0.2=40.8

---

المثال 4 – الاختيار العشوائي من قائمة

في Excel، قد تحتاج أحيانًا إلى اختيار قيمة عشوائية من قائمة معطاة، وهنا تأتي دالةCHOOSE لحل هذه المهمة بسلاسة!

اختيار قيمة واحدة عشوائيًا من قائمة:

الصيغة:

=CHOOSE(RANDBETWEEN(1,5),$D$2,$D$3,$D$4,$D$5,$D$6)

الشرح:

RANDBETWEEN(1,5):index_num، الحصول عشوائيًا على رقم بين 1 و5

$D$2،$D$3،$D$4،$D$5،$D$6:القائمة التي يتم الاختيار منها

---

المثال 5 – دمج دالتَيCHOOSE وVLOOKUP لـ قيمة العودة في أقصى عمود على اليسار

عادةً ما نستخدم دالة VLOOKUP =VLOOKUP (value, table, col_index, [range_lookup]) لإرجاع قيمة استنادًا إلى قيمة معطاة من نطاق جدول. ولكن عند استخدام دالةVLOOKUP، ستُرجع قيمة خطأ إذا كان عمود الإرجاع موجودًا على يسار عمود البحث، كما هو موضح في لقطة الشاشة أدناه:
في هذه الحالة، يمكنك دمج دالةCHOOSEباستخدام دالة VLOOKUP لحل المشكلة.الصيغة: =VLOOKUP(E1,CHOOSE({1,2},B1:B7,A1:A7),2,FALSE)
الشرح: CHOOSE({1,2},B1:B7,A1:A7):كوسائط نطاق الجدول في دالة VLOOKUP. يشير {1،2} إلى استخدام 1 أو 2 كوسيط index_num بناءً على قيمة col_index في دالة VLOOKUP. وبما أن col_index هنا يساوي 2، فإن دالةCHOOSE تُطبَّق كالتالي: CHOOSE(2, B1:B7,A1:A7)، ما يعني اختيار القيمة من النطاق A1:A7.

---

المثال 6 – إرجاع يوم الأسبوع أو الشهر استنادًا إلى تاريخ معين
باستخدام دالةCHOOSE، يمكنك بسهولة إرجاع اسم يوم الأسبوع أو الشهر المقابل لتاريخ معيّن.
الصيغة 1:إرجاع يوم الأسبوع من تاريخ معين
=CHOOSE(WEEKDAY(),«Sunday»,«Monday»,«Tuesday»,«Wednesday»,«Thursday»,«Friday»,«Saturday») الشرح: WEEKDAY(): وسيط index_num الذي يُرجع رقم يوم الأسبوع للتاريخ المحدَّد؛ فمثلًا، إذا كانت WEEKDAY(A5) تُرجع 6، فإن index_num يصبح 6. «Sunday»,«Monday»,«Tuesday»,«Wednesday»,«Thursday»,«Friday»,«Saturday»:قائمة القيم الممكنة، وتبدأ بـ «الأحد» لأن الرقم 1 يتوافق مع يوم الأحد.الصيغة 2:إرجاع الشهر من تاريخ معين=CHOOSE(MONTH(),«Jan»,«Feb»,«Mar»,«Apr»,«May»,«Jun»,«Jul»,«Aug»,«Sep»,«Oct»,«Nov»,«Dec») الشرح: MONTH(): وسيط index_num الذي يُرجع رقم الشهر من التاريخ المعطى؛ فمثلًا، MONTH(A5) تُرجع القيمة 3.

---

المثال 7 – إرجاع تاريخ يوم العمل أو عطلة نهاية الأسبوع التالية استنادًا إلى اليوم الحاليفي عملك اليومي، قد تحتاج إلى تحديد تاريخ يوم العمل التالي أو عطلة نهاية الأسبوع القادمة بناءً على اليوم الحالي. وهنا تأتي دالةCHOOSE لتنقذ الموقف وتوفر لك الحل بسلاسة! على سبيل المثال، لو كان اليوم هو 20/12/2018 (الخميس)، وتحتاج إلى معرفة تاريخ يوم العمل التالي وعطلة نهاية الأسبوع التالية: الصيغة 1:الحصول على التاريخ الحالي=TODAY() النتيجة: 20/12/2018 الصيغة 2:الحصول على رقم يوم الأسبوع للتاريخ الحالي=WEEKDAY(TODAY()) النتيجة: 5 (بافتراض أن اليوم هو 20/12/2018) كما هو موضح في لقطة الشاشة أدناه، قائمة أرقام أيام الأسبوع: الصيغة 3:الحصول على يوم العمل التالي=TODAY()+CHOOSE(WEEKDAY(TODAY()),1,1,1,1,1,3,2) الشرح: Today():تُرجع التاريخ الحالي.WEEKDAY(TODAY()): وسيط index_num في دالةCHOOSE، ويُرجع رقم يوم الأسبوع للتاريخ الحالي؛ فمثلًا، الأحد = 1، الاثنين = 2، وهكذا. 1,1,1,1,1,3,2: قائمة القيم في دالةCHOOSE. فمثلًا، إذا أعادتWEEKDAY(TODAY()) القيمة 1 (الأحد)، تختار الدالة العنصر الأول من القائمة، لتصبح الصيغة=TODAY()+1، أي تضيف يومًا واحدًا لإرجاع يوم الاثنين التالي. أما إذا أعادت القيمة 6 (الجمعة)، فتختار العنصر السادس (وهو 3)، لأن الجمعة تبعد 3 أيام عن يوم الاثنين التالي. النتيجة (بافتراض أن اليوم هو 20/12/2018): =20/12/2018+CHOOSE(5,1,1,1,1,1,3,2) =20/12/2018+1 =21/12/2018 الصيغة 4:الحصول على عطلة نهاية الأسبوع التالية=TODAY()+CHOOSE(WEEKDAY(TODAY()),6,5,4,3,2,1,1) الشرح: 6,5,4,3,2,1,1: قائمة القيم في دالةCHOOSEفمثلًا، إذا أعادتWEEKDAY(TODAY()) القيمة 1 (الأحد)، تختار الدالة الرقم 6 من القائمة، لتصبح الصيغة=TODAY()+6، أي تضيف 6 أيام لتعيد تاريخ يوم السبت التالي. النتيجة: =20/12/2018+CHOOSE(5,6,5,4,3,2,1,1) =20/12/2018+2 =22/12/2018

---

ملف نموذجي