تقسيم مستند Word إلى ملفات متعددة حسب العناوين من المستوى 1 (دليل خطوة بخطوة)

عند العمل مع مستندات Word طويلة—مثل التقارير أو الكتب الدراسية أو الكتيبات أو وثائق المشاريع—قد تجد نفسك بحاجة إلى تقسيم الملف إلى أجزاء أصغر، كفصلٍ منفصل في كل ملف. وإذا كان مستندك يستخدم بالفعل العناوين من المستوى 1 كعناوين رئيسية للأقسام، فإن هذه المهمة تصبح أسهل بكثير. فيما يلي دليلٌ شامل حول كيفية تنفيذ ذلك بكفاءة.

• جهّز مستند Word الخاص بك
• الطريقة 1: تقسيم مستند Word حسب العناوين من المستوى 1 باستخدام ميزة المخطط التفصيلي
• الطريقة 2: تقسيم مستند Word حسب العنوان 1 باستخدام كود VBA
• الطريقة 3: تقسيم مستند Word حسب العنوان 1 باستخدام Kutools for Word
• الخاتمة

جهّز مستند Word الخاص بك

قبل تطبيق أي طريقة، تأكد من أن مستندك منظَّم بشكل صحيح؛ إذ لا يمكن لبرنامج Word التعرُّف على نقاط التقسيم إلا إذا تم تطبيق العناوين من المستوى 1 بالشكل الصحيح.

تطبيق الأنماط:

طبِّق أنماط العناوين بشكلٍ متسق، بحيث تستخدم العناوين من المستوى 1 نمطَ العنوان من المستوى 1، والعناوين من المستوى 2 نمطَ العنوان من المستوى 2، وهكذا دواليك.

حدد عنوانك، ثم انتقل إلى علامة التبويب «الصفحة الرئيسية»، وانقر فوق نمط العنوان من المستوى 1 في معرض الأنماط.

احفظ نسخة احتياطية من ملفك:

احفظ دائمًا نسخةً من مستندك الأصلي قبل البدء في عملية التقسيم، إذ قد يصعب التراجع عن بعض الطرق—مثل عرض المخطط التفصيلي.

الطريقة 1: تقسيم مستند Word حسب العناوين من المستوى 1 باستخدام ميزة المخطط التفصيلي

في الواقع، تجعل ميزة المخطط التفصيلي المدمجة في Word هذه المهمة في غاية السهولة، إذ تكتشف تلقائيًا أقسام العناوين من المستوى 1، مما يمكّنك من تنظيم هيكل المستند وتصدير كل فصل كملف منفصل—بدون الحاجة إلى إضافات أو خطوات معقدة.

1. افتح مستند Word، وانتقل إلى علامة التبويبعرض، ثم انقر فوقالمخطط التفصيلي، كما في لقطة الشاشة:
   
2. في علامة التبويبالمخطط التفصيليالتي تظهر، اضبط قائمةمستوى العرضالمنسدلة علىالمستوى 1. سيؤدي ذلك إلى طي كل شيء باستثناء عناوين المستوى 1.
   
3. بعد ذلك، اضغط علىCtrl + A لتحديد كل النص، ثم انقر فوقعرض المستندفي مجموعةالمستند الرئيسي.
   
4. واصل النقر على زرإنشاء. سيقوم Word الآن بإحاطة كل قسم بمربع رفيع.
   
5. انتقل إلىملف > حفظ باسم. اختر مجلدًا أو أنشئ مجلدًا جديدًا. سيقوم Word تلقائيًا بإنشاء ملفات منفصلة بامتداد.docx لكل عنوان من المستوى 1، باستخدام نص العنوان كاسم للملف. كما سيتم إنشاء مستند فهرس منفصل يحتوي على روابط تشعبية لجميع الملفات المنقسمة، مما يتيح لك فتح أي مستند بنقرة واحدة.
   

الطريقة 2: تقسيم مستند Word حسب العناوين من المستوى 1 باستخدام كود VBA

إذا كان مستندك طويلًا جدًا، فقد تؤدي طريقة المخطط التفصيلي أحيانًا إلى تشويش التنسيق. في المقابل، يُعد استخدام نص برمجي VBA حلاً أكثر نظافة وسرعة.

1. اضغط علىAlt + F11 لفتح نافذةVisual Basic for Applications.
2. انقر فوقإدراج>وحدة نمطية. انسخ والصق الكود التالي في الوحدة النمطية الفارغة:
   

   Sub SplitDocByHeading1()
       Dim StrTmplt As String
       Dim StrPath As String
       Dim StrFlNm As String
       Dim Rng As Range
       Dim i As Long
       Dim Doc As Document
       Dim fDialog As FileDialog
       Const StrNoChr As String = """*./\:?|"
       Application.ScreenUpdating = False
       Set fDialog = Application.FileDialog(msoFileDialogFolderPicker)
       With fDialog
           .Title = "Select a folder to save the split documents"
           .AllowMultiSelect = False
           If .Show <> -1 Then
               MsgBox "Operation cancelled.", vbInformation, "Split by Heading 1"
               Application.ScreenUpdating = True
               Exit Sub
           End If
           StrPath = .SelectedItems(1)
       End With
       If Right(StrPath, 1) <> "\" Then
           StrPath = StrPath & "\"
       End If
       With ActiveDocument
           StrTmplt = .AttachedTemplate.FullName
           With .Range
               With .Find
                   .ClearFormatting
                   .Replacement.ClearFormatting
                   .Text = ""
                   .Replacement.Text = ""
                   .Style = wdStyleHeading1
                   .Format = True
                   .Forward = True
                   .Wrap = wdFindStop
                   .Execute
               End With
               Do While .Find.Found
                   Set Rng = .Duplicate
                   StrFlNm = Split(Rng.Paragraphs(1).Range.Text, vbCr)(0)
                   For i = 1 To Len(StrNoChr)
                       StrFlNm = Replace(StrFlNm, Mid(StrNoChr, i, 1), "_")
                   Next i
                   StrFlNm = StrFlNm & ".docx"
                   Set Rng = Rng.GoTo(What:=wdGoToBookmark, Name:="\HeadingLevel")
                   Set Doc = Documents.Add(Template:=StrTmplt, Visible:=False)
                   With Doc
                       .Range.FormattedText = Rng.FormattedText
                       .SaveAs2 FileName:=StrPath & StrFlNm, _
                                FileFormat:=wdFormatXMLDocument, _
                                AddToRecentFiles:=False
                       .Close SaveChanges:=False
                   End With
                   .Collapse wdCollapseEnd
                   .Find.Execute
               Loop
           End With
       End With
       Set Doc = Nothing
       Set Rng = Nothing
       Application.ScreenUpdating = True
       MsgBox "Split completed successfully.", vbInformation, "Split by Heading 1"
   End Sub
   

3. اضغط علىF5 أو انقر فوقتشغيللتنفيذ الكود. بعد التنفيذ، ستظهر نافذة تطلب منك تحديد مجلد لحفظ الملفات المنقسمة. انظر لقطة الشاشة:
   
4. انقر فوقموافق، وسيُنشئ Word فورًا ملف .docx لكل قسم يتوافق مع عناوين المستوى 1. افتح المجلد لعرض الناتج.
   

الطريقة 3: تقسيم مستند Word حسب العناوين من المستوى 1 باستخدام Kutools for Word

على الرغم من أن أدوات Word المضمنة وVBA تتيح تقسيم المستندات، إلا أنها تتطلب خطوات متعددة ومهارات تقنية وقد تؤدي أحيانًا إلى فقدان التنسيق. أما Kutools for Word، فيقدّم حلاً أكثر نظافةً وكفاءةً بكثير: فباستخدام ميزة «تقسيم المستند»، يمكنك تقسيم ملفك بنقرة واحدة فقط—حسب العناوين من المستوى 1، أو فواصل الصفحات، أو فواصل المقاطع، أو حتى صفحة بصفحة—بدون أي برمجة أو تدخل يدوي أو خطر فقدان التنسيق. ويحافظ Kutools بدقة على الأنماط والتخطيط والصور والعناوين والتذييلات، مما يجعله الأداة المثالية لأي شخص يتعامل مع مستندات كبيرة.

بعد تنزيل وتثبيت Kutools for Word، يُرجى اتباع الخطوات التالية:

1. انتقل إلىKUTOOLS PLUS > تقسيم.
   
2. في مربع حوارتقسيم المستند، حدّد الخيارات التالية:

   2.1 اخترالعنوان 1من قائمةالتقسيم حسبالمنسدلة. (يمكنك أيضًا اختيار قواعد تقسيم أخرى، مثل فاصل الصفحات، فاصل المقطع، الصفحة، كل n صفحات، وغير ذلك.)

   2.2 حدد مجلدًا لحفظ ملفات التقسيم الجديدة.

   2.3 انقر على زرموافق.

   تلميح:يمكنك أيضًا إضافة بادئة إلى عنوان كل ملف مقسَّم بإدخال نص في مربعبادئة المستند.

   
   

النتيجة:
سيقوم Kutools فورًا بإنشاء عدة ملفات Word بناءً على هيكل العناوين من المستوى 1، مع الحفاظ الكامل على الرؤوس والتذييلات.

الخاتمة

مقالات ذات صلة: