انتقل إلى المحتوى الرئيسي

كيفية تشغيل وحدات ماكرو متعددة من قائمة النقر بزر الماوس الأيمن في إكسيل؟

doc انقر بزر الماوس الأيمن فوق وحدات الماكرو 5

إذا كان هناك العديد من وحدات ماكرو vba في المصنف الخاص بك ، فيجب عليك فتح نافذة VBA ثم اختيار الماكرو عندما تحتاج إلى تشغيل التعليمات البرمجية. في هذه المقالة ، أود التحدث عن كيفية تشغيل وحدات الماكرو من قائمة النقر بزر الماوس الأيمن لجعل عملك أكثر كفاءة كما هو موضح في لقطة الشاشة اليسرى.

قم بتشغيل وحدات ماكرو متعددة من قائمة النقر بزر الماوس الأيمن باستخدام أكواد VBA


قم بتشغيل وحدات ماكرو متعددة من قائمة النقر بزر الماوس الأيمن باستخدام أكواد VBA

لتشغيل أكواد الماكرو داخل مصنف من قائمة النقر بزر الماوس الأيمن ، قد تساعدك الخطوات التالية ، يرجى القيام بذلك على النحو التالي:

1. ثقب أسفل ALT + F11 مفاتيح لفتح ميكروسوفت فيسوال باسيك للتطبيقات نافذة.

2. ثم ، انقر نقرًا مزدوجًا ThisWorkbook في اليسار قسم المشاريع ، ثم انسخ والصق رمز VBA أدناه في الوحدة النمطية الفارغة.

Private Sub Workbook_Open()
Run "LoadMacro"
End Sub
Private Sub Workbook_Activate()
Run "LoadMacro"
End Sub
Private Sub Workbook_Deactivate()
Run "ClearMacro"
End Sub
Private Sub Workbook_BeforeClose(Cancel As Boolean)
Run "ClearMacro"
ThisWorkbook.Save
End Sub

doc انقر بزر الماوس الأيمن فوق وحدات الماكرو 1

3. لا يزال في ميكروسوفت فيسوال باسيك للتطبيقات نافذة ، الرجاء الضغط إدراج > وحدة، والصق الكود التالي في هذه الوحدة.

Private Sub LoadMacro()
Dim xArrMenu As Variant
Dim xStrLine, xSreBtnName As String
Dim xObjCBCF, xObjCntrAll As CommandBarControl
Dim xObjCBCs As CommandBars
Dim xObjCBBtn As CommandBarButton
Dim xIntLine, xFNum As Integer
Dim xObjComponent As Object
Run "ClearMacro"
Set xObjCBCF = Application.CommandBars("Cell").Controls.Add(msoControlPopup, before:=1)
xObjCBCF.Caption = " Run Macro "
xObjCBCF.BeginGroup = False
For Each xObjComponent In ActiveWorkbook.VBProject.VBComponents
    If xObjComponent.Type = 1 Then
        For xIntLine = 1 To xObjComponent.CodeModule.CountOfLines
        xStrLine = xObjComponent.CodeModule.Lines(xIntLine, 1)
        xStrLine = Trim(xStrLine)
            If (InStr(xStrLine, "()") > 0) And (Left(xStrLine, 11) = "Private Sub" Or Left(xStrLine, 3) = "Sub") Then
            xSreBtnName = ""
            If "Private Sub" = Left(xStrLine, 11) Then
                xSreBtnName = Trim(Mid(xStrLine, 12, InStr(xStrLine, "()") - 12))
            ElseIf "Sub" = Left(xStrLine, 3) Then
               xSreBtnName = Trim(Mid(xStrLine, 4, InStr(xStrLine, "()") - 4))
            End If
            If xSreBtnName <> "" And xSreBtnName <> "RightClickReset" And xSreBtnName <> "LoadMacro" And xSreBtnName <> "ActionMacro" Then
                Set xObjCBBtn = xObjCBCF.Controls.Add
                With xObjCBBtn
                    .FaceId = 186
                    .Style = msoButtonIconAndCaption
                    .Caption = xSreBtnName
                    .OnAction = "ActionMacro"
                End With
            End If
            End If
        Next xIntLine
    End If
Next xObjComponent
End Sub
Private Sub ClearMacro()
On Error Resume Next
CommandBars("Cell").Controls(" Run Macro ").Delete
Err.Clear
CommandBars("Cell").Reset
End Sub
Private Sub ActionMacro()
On Error GoTo Err1
With Application
Run .CommandBars("Cell").Controls(1).Controls(.Caller(1)).Caption
End With
Exit Sub
Err1:
    MsgBox "Invalid"
End Sub

doc انقر بزر الماوس الأيمن فوق وحدات الماكرو 2

4. بعد لصق الرموز ، انقر فوق الأدوات > مراجع حسابات، و المراجع- VBAProject يتم عرض مربع الحوار ، ثم تحقق مايكروسوفت فيجوال باسيك للتطبيقات الموسعة 5.3 الخيار في المراجع المتاحة مربع القائمة ، انظر لقطة الشاشة:

doc انقر بزر الماوس الأيمن فوق وحدات الماكرو 3

5. ثم اضغط OK للخروج من مربع الحوار ، الآن ، يجب عليك حفظ هذا المصنف باسم مصنف Excel ممكن بماكرو التنسيق ، انظر لقطة الشاشة:

doc انقر بزر الماوس الأيمن فوق وحدات الماكرو 4

6. أخيرًا ، يرجى إعادة تشغيل المصنف للحصول على تأثير الرموز ، والآن ، عند النقر بزر الماوس الأيمن فوق خلية ، يتم إنشاء ملف تشغيل ماكرو يتم إدراج الخيار في قائمة النقر بزر الماوس الأيمن ، ويتم سرد كافة وحدات الماكرو في المصنف الخاص بك في القائمة الفرعية على النحو التالي لقطة الشاشة:

doc انقر بزر الماوس الأيمن فوق وحدات الماكرو 5

7. ثم يمكنك تشغيل الكود بمجرد النقر فوقه.


Comments (0)
No ratings yet. Be the first to rate!
There are no comments posted here yet
Please leave your comments in English
Posting as Guest
×
Rate this post:
0   Characters
Suggested Locations