كيفية تعيين تواقيع مختلفة للردود وإعادة التوجيه في Outlook؟

عادةً ، يمكنك تعيين توقيعات مختلفة لحسابات مختلفة في Outlook الخاص بك ، ولكنك حاولت في أي وقت تطبيق توقيعات مختلفة للردود وإعادة التوجيه. هذا يعني أنه عند الرد على رسالة بريد إلكتروني ، يتم إدراج التوقيع 1 ، وعند إعادة توجيه بريد إلكتروني يتم تطبيق التوقيع 2. كيف يمكنك حل هذه المهمة في Outlook؟

قم بتعيين توقيعات مختلفة للردود وإعادة التوجيه باستخدام رمز VBA

---

قم بتعيين توقيعات مختلفة للردود وإعادة التوجيه باستخدام رمز VBA

يمكن أن يساعدك رمز VBA التالي في تعيين توقيعات مختلفة للردود وإعادة التوجيه ، يرجى القيام بالخطوات التالية واحدة تلو الأخرى:

1. اضغط باستمرار على ALT + F11 مفاتيح لفتح ميكروسوفت فيسوال باسيك للتطبيقات نافذة.

2. ثم اضغط إدراج > وحدة، انسخ والصق الكود أدناه في الوحدة الفارغة المفتوحة ، انظر لقطة الشاشة:

رمز فبا: تعيين توقيعات مختلفة للردود وإعادة التوجيه:

Public WithEvents GExplorer As Outlook.Explorer
Public WithEvents GMail As Outlook.MailItem
Public GFSO As Scripting.FileSystemObject
Public GTextStream As Scripting.TextStream
Public GText As String
Private Sub Application_Startup()
    Set GExplorer = Outlook.Application.ActiveExplorer
    Set GFSO = New Scripting.FileSystemObject
End Sub
Private Sub GExplorer_SelectionChange()
    Dim xItem As Object
    On Error Resume Next
    Set xItem = GExplorer.Selection.Item(1)
    If xItem.Class <> olMail Then Exit Sub
    Set GMail = xItem
End Sub
Private Sub GMail_Reply(ByVal Response As Object, Cancel As Boolean)
    InsertSignature Response, "Signature1.htm"   'change this signature name for replies
End Sub
Private Sub GMail_Forward(ByVal Forward As Object, Cancel As Boolean)
    InsertSignature Forward, " Signature2.htm"    'change this signature name for forwards
End Sub
Private Sub InsertSignature(Item As Object, SignName As String)
    Dim xSignatureFile As String
    Dim xMailItem As Outlook.MailItem
    xSignatureFile = CreateObject("WScript.Shell").SpecialFolders(5)
    xSignatureFile = xSignatureFile & "\Microsoft\Signatures\" & SignName
    Set GTextStream = GFSO.OpenTextFile(xSignatureFile)
    GText = ""
    GText = GTextStream.ReadAll
    If Item.Class <> olMail Then Exit Sub
    Set xMailItem = Item
    With xMailItem
        .Display
        .HTMLBody = .HTMLBody & "<br><br>" & GText
    End With
End Sub

ملاحظة: في الكود أعلاه ، Signature1 و Signature2 هما اسمي التوقيع اللذين تريد استخدامهما للرد وإعادة التوجيه. الرجاء تغيير الأسماء حسب حاجتك.

3. لا يزال في ميكروسوفت فيسوال باسيك للتطبيقات الإطار، انقر فوق الأدوات > المحلية للذهاب إلى المراجع - مشروع 1 مربع الحوار ، وتحقق وقت تشغيل البرمجة لـ Microsoft الخيار من المراجع المتاحة مربع القائمة ، انظر لقطة الشاشة:

4. ثم انقر فوق OK لإغلاق مربع الحوار ، من الآن فصاعدًا ، عند الرد على رسالة بريد إلكتروني ، سيتم إدراج Signature1 في الحال ، انظر لقطة الشاشة:

وعند إعادة توجيه رسالة ، سيتم إدراج Signature2 كما هو موضح في لقطة الشاشة التالية: