كيف تُنشئ موعدًا باستخدام بيانات Excel؟

افترض أن لديك جدولًا يحتوي على بيانات المواعيد في ورقة عمل Excel كما هو موضح في لقطة الشاشة التالية، وتريد الآن استيراد هذه البيانات إلى تقويم Outlook. كيف يمكنك إنجاز هذه المهمة بسرعة؟

إنشاء مواعيد من بيانات Excel باستخدام كود VBA

---

إنشاء مواعيد من بيانات Excel باستخدام كود VBA

لإنشاء مواعيد من بيانات Excel، يمكنك تطبيق كود VBA التالي، يُرجى اتباع الخطوات التالية:

1. افتح Outlook، ثم اضغط مع الاستمرار على مفاتيحALT + F11 لفتح نافذةMicrosoft Visual Basic for Applications.

2. انقر فوقInsert > Module، ثم الصق الكود التالي في نافذةModule.

كود VBA: استيراد بيانات Excel إلى موعد:

Public Sub CreateOutlookApptz()
    Dim xAppointmentItem As Outlook.AppointmentItem
    Dim xNameSpace As Outlook.NameSpace
    Dim xCalendarFld As Outlook.MAPIFolder, xSubFolder As Outlook.MAPIFolder
    Dim xCalendarStr As String
    Dim I As Long
    Dim xFileDialog As FileDialog
    Dim xFilePath As String
    Dim xExcelApp As Excel.Application
    Dim xWb As Workbook
    Dim xWs As Worksheet
    On Error GoTo Err_Execute
    Set xExcelApp = New Excel.Application
    Set xFileDialog = xExcelApp.FileDialog(msoFileDialogFilePicker)
    With xFileDialog
        .Title = "Select a file"
        .Filters.Add "Microsoft Excel", "*.xlsx"
    End With
    If xFileDialog.Show = 0 Then Exit Sub
    xFilePath = xFileDialog.SelectedItems(1)
    Set xWb = xExcelApp.Workbooks.Open(xFilePath)
    Set xNameSpace = Outlook.Application.Session
    Set xCalendarFld = xNameSpace.GetDefaultFolder(olFolderCalendar)
    I = 2
    Set xWs = xWb.Worksheets.Item(1)
    xCalendarStr = xWb.Name
    If FolderExist(xCalendarFld, xCalendarStr) = False Then
        Set xSubFolder = xCalendarFld.Folders.Add(xCalendarStr, olFolderCalendar)
    Else
        Set xSubFolder = xCalendarFld.Folders(xCalendarStr)
    End If
    Do Until Trim(xWs.Cells(I, 1).Value) = ""
        Set xAppointmentItem = xSubFolder.Items.Add(olAppointmentItem)
        With xAppointmentItem
            .Start = xWs.Cells(I, 5) + xWs.Cells(I, 6)
            .End = xWs.Cells(I, 7) + xWs.Cells(I, 8)
            .Subject = xWs.Cells(I, 1)
            .Location = xWs.Cells(I, 2)
            .Body = xWs.Cells(I, 3)
            .BusyStatus = olBusy
            .ReminderMinutesBeforeStart = xWs.Cells(I, 9)
            .ReminderSet = True
            .Categories = xWs.Cells(I, 4)
            .Save
        End With
        I = I + 1
    Loop
    Set xAppointmentItem = Nothing
    Set olApp = Nothing
    xExcelApp.Quit
    Set xExcelApp = Nothing
    MsgBox "Import successfully!", vbInformation, "Kutools for Outlook"
    Exit Sub
Err_Execute:
    MsgBox "An error occurred - Exporting items to Calendar.", vbInformation, "Kutools for Outlook"
End Sub
Function FolderExist(CalFolder As Folder, FolderName As String) As Boolean
    Dim I As Integer
    Dim xSubFolder As Folder
    For I = 1 To CalFolder.Folders.Count
        Set xSubFolder = CalFolder.Folders.Item(I)
        If xSubFolder.Name = FolderName Then
            FolderExist = True
            Exit Function
        End If
    Next I
End Function

3. لا تزال في نافذةMicrosoft Visual Basic for Applications، انقر فوقTools > References للانتقال إلى مربع حوارReferences-Project1، ثم حدد خيارMicrosoft Excel Object Library من قائمةAvailable References. انظر لقطة الشاشة:

4. بعد ذلك، انقر فوق زرOK، ثم اضغط على مفتاحF5 لتشغيل هذا الكود. ستظهر نافذةSelect a file—يرجى تحديد ملف Excel الذي تريد استيراده إلى Outlook. انظر لقطة الشاشة:

5.ثم انقر فوقOK، وسيظهر مربع تنبيه كما يلي:

6. بعد ذلك، انقر فوقOK، وسيتم استيراد بيانات Excel إلى التقويم كما هو موضح في لقطة الشاشة التالية: