كيف ترد بشكلٍ طبيعي من مجلد الرسائل المرسلة في Outlook؟

عادةً، عند النقر على ميزة «رد» في مجلد الرسائل المرسلة لإرسال رسالة إضافية إلى الأشخاص الذين أرسلت إليهم سابقًا، يظهر عنوان بريدك الإلكتروني في حقل «إلى»، كما هو موضح في لقطة الشاشة التالية. وقد يكون ذلك مزعجًا، إذ يتعيّن عليك تغيير العنوان يدويًّا في كل مرة. فكيف يمكنك جعل Outlook يستخدم عنوان المستلم الأصلي بدلًا من عنوانك أنت؟

الرد بشكلٍ طبيعي من مجلد الرسائل المرسلة في Outlook باستخدام ميزة «رد على الكل»

الرد بشكلٍ طبيعي من مجلد الرسائل المرسلة في Outlook باستخدام كود VBA

---

الرد بشكلٍ طبيعي من مجلد الرسائل المرسلة في Outlook باستخدام ميزة «رد على الكل»

في Outlook، يمكن لميزةرد على الكلأن تساعدك في حل هذه المشكلة، يُرجى اتباع الخطوات التالية:

عندما تحتاج إلى الرد على البريد المرسَل لإرساله مجددًا مع الحفاظ على عنوان المستلم الأصلي، يُرجى النقر على زررد على الكل، وسيكون عنوان المستلم الأصلي موجودًا في حقلإلىكما هو موضح في لقطة الشاشة التالية:

---

الرد بشكلٍ طبيعي من مجلد الرسائل المرسلة في Outlook باستخدام كود VBA

أحيانًا قد تنسى استخدام ميزةرد على الكلعند الرد على رسالة من مجلد الرسائل المرسَلة. لحسن الحظ، يمكن للكود التالي المكتوب بلغة VBA أن يساعدك على الرد بشكلٍ طبيعي باستخدام ميزة «رد». اتبع الخطوات التالية:

1. اضغط مع الاستمرار على مفتاحَيALT + F11 لفتح نافذةMicrosoft Visual Basic for Applications.

2. في نافذةMicrosoft Visual Basic for Applications، انقر نقرًا مزدوجًا علىThisOutlookSession من جزءProject1 (VbaProject.OTM) لفتح الوحدة النمطية، ثم انسخ والصق الكود التالي في الوحدة النمطية الفارغة.

كود VBA: الرد بشكلٍ طبيعي من مجلد الرسائل المرسلة في Outlook:

Option Explicit
Private WithEvents GExplorer As Explorer
Private WithEvents GMailItem As MailItem
Private Sub Application_Startup()
    Set GExplorer = Application.ActiveExplorer
End Sub
Private Sub GExplorer_SelectionChange()
   On Error Resume Next
   Set GMailItem = GExplorer.Selection.Item(1)
End Sub
Private Sub GMailItem_Reply(ByVal Response As Object, Cancel As Boolean)
Dim xResponse As MailItem
Dim xRecipients As Outlook.Recipients
Dim xRecipient As Outlook.Recipient
Dim i As Integer
Dim xTo As String, xCC As String, xBCC As String, xName As String
On Error Resume Next
If Application.ActiveExplorer.CurrentFolder <> Session.GetDefaultFolder(olFolderSentMail) Then
    Exit Sub
End If
Cancel = True
Set xResponse = GMailItem.Reply
Set xRecipients = GMailItem.Recipients
For i = xRecipients.Count To 1 Step -1
    Set xRecipient = xRecipients.Item(i)
    xName = xRecipient.Name
    If Left(xName, 1) = "'" Then
        xName = Mid(xName, 2, Len(xRecipient.Name) - 2)
    End If
    Select Case xRecipient.Type
        Case olTo
            xTo = xName & ";" & xTo
        Case olCC
            xCC = xName & ";" & xCC
        Case olBCC
            xBCC = xName & ";" & xBCC
    End Select
Next
With xResponse
    .To = xTo
    .CC = xCC
    .BCC = xBCC
End With
xResponse.Recipients.ResolveAll
xResponse.Display
End Sub

3. بعد ذلك، احفظ الكود وأعد تشغيل Outlook لتفعيله. الآن، عند النقر علىردلإعادة إرسال بريد إلكتروني من مجلدالرسائل المرسلة، سيظهر عنوان المستلم الأصلي في حقل «إلى» كما ترغب.