كيف يمكن الاحتفاظ بالفئة عند الرد على رسالة بريد إلكتروني أو إعادة توجيهها في Outlook؟

عادةً، عند الرد على رسالة بريد إلكتروني أو إعادة توجيهها بعد تصنيفها، تُزال الفئة تلقائيًا من الرسالة الصادرة. إذا كنت ترغب في الاحتفاظ بالفئة في رسائل البريد الصادرة عند الرد أو إعادة التوجيه، فتقدم لك هذه المقالة طريقة فعّالة لتحقيق ذلك.

الاحتفاظ بالفئة أثناء الرد على رسالة بريد إلكتروني أو إعادة توجيهها باستخدام كود VBA

---

الاحتفاظ بالفئة أثناء الرد على رسالة بريد إلكتروني أو إعادة توجيهها باستخدام كود VBA

1. اضغط باستمرار على مفتاحَيALT + F11 لفتح نافذةMicrosoft Visual Basic for Applications.

2. في نافذةMicrosoft Visual Basic for Applications، انقر مرتين علىThisOutlookSession من جزءProject1 (VbaProject.OTM) لفتح الوحدة النمطية، ثم انسخ والصق الكود التالي في الوحدة النمطية الفارغة.

كود VBA: الاحتفاظ بالفئة أثناء الرد على رسالة بريد إلكتروني أو إعادة توجيهها:

Private WithEvents GExplorer As Outlook.Explorer
Private WithEvents GInspectors As Outlook.Inspectors
Private WithEvents GMailItem As Outlook.MailItem
Private GCategories As String
Private Sub Application_Startup()
    Dim xApp As Outlook.Application
    Set xApp = Outlook.Application
    Set GExplorer = xApp.ActiveExplorer
    Set GInspectors = xApp.Inspectors
End Sub
Private Sub GExplorer_SelectionChange()
    On Error Resume Next
    If TypeName(GExplorer.Selection.Item(1)) <> "MailItem" Then Exit Sub
    Set GMailItem = GExplorer.Selection.Item(1)
    GCategories = GMailItem.Categories
End Sub
Private Sub GInspectors_NewInspector(ByVal Inspector As Inspector)
    On Error Resume Next
    If TypeName(Inspector.CurrentItem) <> "MailItem" Then Exit Sub
   Set GMailItem = Inspector.CurrentItem
    GCategories = GMailItem.Categories
End Sub
Private Sub GMailItem_Forward(ByVal Forward As Object, Cancel As Boolean)
    Call GetCategories(Forward)
End Sub
Private Sub GMailItem_Reply(ByVal Response As Object, Cancel As Boolean)
    Call GetCategories(Response)
End Sub
Private Sub GMailItem_ReplyAll(ByVal Response As Object, Cancel As Boolean)
    Call GetCategories(Response)
End Sub
Private Sub GetCategories(ByVal NewMail As Object)
    If NewMail.Class <> olMail Then Exit Sub
    NewMail.Categories = GCategories
End Sub

3. بعد ذلك، احفظ وأغلق نافذة الكود، ثم أغلق Outlook وأعد تشغيله. الآن، عند الرد على رسالة بريد إلكتروني تحتوي على فئة أو إعادة توجيهها، ستبقى الفئة في الرسالة الصادرة فيالرسائل المرسلة. انظر لقطة الشاشة: