Outlook: كيفية إعادة إرسال البريد الإلكتروني تلقائيًا في حال عدم وجود رد

عند إرسال بريد إلكتروني إلى زميلك أو شريكك التعاوني أو أي شخص آخر وتحتاج إلى ردٍّ عاجل، يمكنك تفعيل إعداد لإعادة إرسال البريد تلقائيًا إذا لم تستلم الرد قبل انتهاء الوقت المحدد.

استخدام التذكير وVBA لضبط إعادة الإرسال التلقائي في حال عدم وجود رد

---

استخدام التذكير وVBA لضبط إعادة الإرسال التلقائي في حال عدم وجود رد

الجزء 1: ضبط تذكير للإشعار بعد مرور وقت محدد

1. انقر بزر الماوس الأيمن على البريد الإلكتروني (من مجلد الرسائل المرسلة) الذي ترغب في إعادة إرساله في حال عدم تلقّي رد، ثم من القائمة المنبثقة، اختر «المتابعة» > «إضافة تذكير».

2. في مربع الحوار المنبثق «تخصيص»، اترك خانة الاختيار «تذكير» مفعّلة، ثم حدد من القائمتين المنسدلتين أدناه التاريخ والوقت اللذين ترغب في استلام الرد قبلهما. أو يمكنك إدخال التاريخ والوقت يدويًّا في الحقلين المخصصين لذلك. بعد الانتهاء، انقر «موافق».

الجزء 2: إدراج كود VBA لإعادة إرسال الرسائل الإلكترونية إذا لم يرد عليها خلال الوقت المحدد

3. اضغط مفاتيح «Alt» + "F11" لفتح نافذة «مايكروسوفت Visual Basic for Applications».

4. انقر مرتين على «ThisOutlookSession» في جزء «المشروع – Project1» لإنشاء نص برمجي فارغ، ثم انسخ والصق كود VBA أدناه في هذا النص الفارغ.

VBA: إعادة إرسال البريد الإلكتروني إذا لم يتم الرد عليه

Public WithEvents GInboxItems As Outlook.Items
'UpdatebyExtendoffice20220413
Private Sub Application_Startup()
  Dim xInboxFld As Folder
  Set xInboxFld = Application.Session.GetDefaultFolder(olFolderInbox)
  Set GInboxItems = xInboxFld.Items
End Sub

'Judge
Private Sub GInboxItems_ItemAdd(ByVal Item As Object)
  Dim xSentItems As Outlook.Items
  Dim xMail As MailItem
  Dim i As Long
  Dim xSubject As String
  Dim xItemSubject As String
  Dim xSendTime As String
  On Error Resume Next
  Set xSentItems = Application.Session.GetDefaultFolder(olFolderSentMail).Items
  If Item.Class <> olMail Then Exit Sub
  For i = xSentItems.Count To 1 Step -1
    If xSentItems.Item(i).Class = olMail Then
      Set xMail = xSentItems.Item(i)
      xSubject = LCase(xMail.Subject)
      xSendTime = xMail.SentOn
      xItemSubject = LCase(Item.Subject)
      If (xItemSubject = "re: " & xSubject) Or (InStr(xItemSubject, xSubject) > 0) Then
        If Item.SentOn > xSendTime Then
           With xMail
             .ClearTaskFlag
             .ReminderSet = False
             .Save
           End With
        End If
      End If
    End If
  Next i
End Sub

'Reminder
Private Sub Application_Reminder(ByVal Item As Object)
  Dim xPrompt As String
  Dim xResponse As Integer
  Dim xFollowUpMail As Outlook.MailItem
  Dim xRcp As Recipient
  On Error Resume Next
  'Resend
  If (Item.Class <> olMail) Then Exit Sub
  xPrompt = "You haven't yet received the reply of " & Chr(34) & Item.Subject & Chr(34) & " within your expected time. Do you want to send a follow-up notification email?"
  xResponse = MsgBox(xPrompt, vbYesNo + vbQuestion, "Kutools for Outlook")
  If xResponse = vbNo Then Exit Sub
  Set xFollowUpMail = Application.CreateItem(olMailItem)
  With xFollowUpMail
    For Each xRcp In Item.Recipients
      .Recipients.Add (xRcp.Address)
    Next
    .Recipients.ResolveAll
    .Subject = "Follow Up: " & Chr(34) & Item.Subject & Chr(34)
    .Body = "Please respond to my email " & Chr(34) & Item.Subject & Chr(34) & " as soon as possible"
    .Attachments.Add Item
    .Display
  End With
End Sub

5. احفظ الكود، ثم عُد إلى الواجهة الرئيسية وانقر «ملف» > «خيارات». في نافذة «خيارات Outlook»، انقر «مركز الثقة» في الجزء الأيسر، ثم انقر «إعدادات مركز الثقة» لفتح نافذة «مركز الثقة». بعد ذلك، انقر «إعدادات وحدات الماكرو» وتأكد من تحديد الخيار «تمكين جميع وحدات الماكرو (غير موصى به؛ قد يتم تشغيل أكواد خطيرة)» في القسم الأيمن. أخيرًا، انقر «موافق» > «موافق».

6. الآن، إذا لم يُجب عن البريد الإلكتروني الذي تم ضبط تذكير له عند حلول الوقت المحدد، فستظهر نافذة منبثقة لتذكيرك بما إذا كنت ترغب في إعادة إرسال بريد إلكتروني لإرسال الإشعار.

7. انقر «نعم»، وستظهر نافذة رسالة جديدة مرفقًا بها البريد السابق، حيث يمكنك تعديل النص ثم النقر على «إرسال» لإعادة إرساله.

8. انقر «لا»، وسيتم حذف التذكير.

ملاحظة: في حال تم الرد على البريد الإلكتروني قبل الموعد المحدد، سيقوم كود VBA تلقائيًا بإزالة التذكير.