كيفية حفظ رسائل البريد الإلكتروني في Outlook تلقائيًا على القرص الصلب؟

Author: Kelly Last Modified: 2025-08-06

لغرض النسخ الاحتياطي، أو أدلة العمل، أو لأغراض أخرى، قد ترغب في حفظ رسائل البريد الإلكتروني في Outlook على القرص الصلب. من السهل حفظ عدد قليل من الرسائل يدويًا عن طريق السحب من Outlook إلى القرص. ومع ذلك، هل تعرف كيفية حفظ كل بريد إلكتروني وارد تلقائيًا على القرص؟ سيقدم لك هذا المقال VBA للتعامل مع هذه المهمة في Outlook.

حفظ رسائل البريد الإلكتروني في Outlook تلقائيًا على القرص الصلب

حفظ رسائل البريد الإلكتروني في Outlook تلقائيًا على القرص الصلب

ستقدم هذه الطريقة VBA لحفظ كل بريد إلكتروني وارد في Outlook كملف HTML فردي في القرص المحدد. يرجى القيام بما يلي:

1. اضغط على مفتاحي "Alt" + "F11" لفتح نافذة Microsoft Visual Basic for Applications.

2. قم بتوسيع Project1، واضغط مرتين على "ThisOutlookSession" لفتحه، ثم ألصق الكود التالي لـ VBA في نافذة ThisOutlookSession. انظر لقطة الشاشة:

VBA: حفظ رسائل البريد الإلكتروني في Outlook كملفات HTML على القرص

Private WithEvents InboxItems As Outlook.Items
Sub Application_Startup()
    Dim xNameSpace As Outlook.NameSpace
    Set xNameSpace = Outlook.Application.Session
    Set InboxItems = xNameSpace.GetDefaultFolder(olFolderInbox).Items
End Sub

Private Sub InboxItems_ItemAdd(ByVal objItem As Object)
    Dim FSO
    Dim xMailItem As Outlook.MailItem
    Dim xFilePath As String
    Dim xRegEx
    Dim xFileName As String
    On Error Resume Next
    xFilePath = CreateObject("WScript.Shell").SpecialFolders(16)
    xFilePath = xFilePath & "\MyEmails"
    Set FSO = CreateObject("Scripting.FileSystemObject")
    If FSO.FolderExists(xFilePath) = False Then
        FSO.CreateFolder (xFilePath)
    End If
    Set xRegEx = CreateObject("vbscript.regexp")
    xRegEx.Global = True
    xRegEx.IgnoreCase = False
    xRegEx.Pattern = "\||\/|\<|\>|""|:|\*|\\|\?"
    If objItem.Class = olMail Then
        Set xMailItem = objItem
        xFileName = xRegEx.Replace(xMailItem.Subject, "")
        xMailItem.SaveAs xFilePath & "\" & xFileName & ".html", olHTML
    End If
    Exit Sub
End Sub

3. احفظ كود VBA، وأعد تشغيل Microsoft Outlook الخاص بك.

من الآن فصاعدًا، سيتم حفظ كل بريد إلكتروني وارد كملف HTML فردي في مجلد “MyEmails”.

ملاحظات:
(1) سيقوم هذا الكود VBA بإنشاء مجلد باسم “MyEmails” تحت مجلد المستندات. يمكنك العثور على الرسائل الإلكترونية التي تم حفظها تلقائيًا باستخدام هذا المسار للمجلد: C:\Users\اسم_المستخدم\Documents\MyEmails
(2) سيعمل هذا الكود VBA مع الرسائل المستلمة في مجلد صندوق الوارد الخاص بالحساب البريدي الافتراضي.